gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for Sequitur

Volume -World Descriptors and Mechanics

Book - Things, Values, Variables

Chapter - General

A thing is either examined or unexamined. A thing is usually unexamined.

A thing can be marked for manipulation. A thing can be on-screen.

Understand the printed name property as describing a thing.

[We make these backdrops instead of actions so that the player can use the READ action on them. Still, it might be better just to incorporate "read" in the relevant action understanding lines instead of making backdrops.]

Contents is a kind of backdrop. About author, manipulators, the help, the hints, and walkthrough are contents.

About author is everywhere. Manipulators is everywhere. Help is everywhere. hints is everywhere. Walkthrough is everywhere.

Understand "author", "about the author", and "writer" as about author.

The description of about author is "Nigel Jayne, or more correctly the guy using that pseudonym, has a PhD in Pharmacology and Toxicology, earned after five years of getting pregnant guinea pigs drunk. Losing his eyesight shortly after graduation forced a change in his career plan, and he now occasionally writes scientific and medical literature. Nigel

enjoyed graphical-text hybrids such as the [b]Space Quest[/b] and [b]King's Quest[/b] series more than the strictly text-based games in his youth, but he was totally absorbed into the worlds of Choose-Your-Own-Adventure books. [fiction title] is his first text adventure, and he has since written another, [b][i]A Fly on the Wall[/i][/b] [fixed letter spacing]http://www.nigeljayne.ca[variable letter spacing].".

Understand "other commands", "guidance", "guide", "instruction", "manual", "sequitur manual", "command", "commands", and "command list" as the help.

Understand "about the authors", "acknowledgements", "authors", "credits", "credit", and "writers" as manipulators.

Understand "hint" as hints.

Understand "opinion", "an opinion", "her opinion", "Jenny's opinion", "Jennifer's opinion", "solution", "solutions", "timeline", "Jenny's walkthrough", "Jennifer's walkthrough", and "walkthru" as walkthrough.

A dextrus is a kind of value. Left and right are dextruses. Understand "backward", "backwards", and "back" as left. Understand "forward", "forwards", and "ahead" as right.

Duration is a kind of value. 3:59 specifies a duration.

Status is a kind of value. Primary objective and secondary objective are statuses. A status can be sequenced. A status can be solved.

Replacer is a kind of value. trak and groove are replacers. Understand "track" as trak. Understand "slot" and "position" as groove.

[Replacers are used in "after reading a command" rules to remove unnecessary uses of "slot" or "track" in the player's commands.]

A team is a kind of value. Anaheim Ducks, Boston Bruins, Buffalo Sabres, Pittsburgh Penguins, San Jose Sharks, Florida Panthers, Denver Nuggets, Minnesota Timberwolves, New Orleans Hornets, and Phoenix Suns are teams.

A team can be hockey or basketball. A team is usually hockey. Denver Nuggets, Minnesota Timberwolves, New Orleans Hornets, and Phoenix Suns are basketball.

A team is either home or away. A team is usually home.

A team has some text called just-team. The just-team of Anaheim Ducks is "Ducks". The just-team of Florida Panthers is "Panthers". The just-team of Boston Bruins is "Bruins". The just-team of Buffalo Sabres is "Sabres". The just-team of Pittsburgh Penguins is "Penguins". The just-team of San Jose Sharks is "Sharks". The just-team of Minnesota Timberwolves is "Timberwolves". The just-team of New Orleans Hornets is "Hornets". The just-team of Denver Nuggets is "Nuggets". The just-team of Phoenix Suns is "Suns".

A team has a number called netted. The netted of a team is usually 0.

[Stalling actions are those that don't activate the Sequitur program.]

Attacking is stalling. Consulting is stalling. Eating is stalling. Kissing is stalling. Listening is stalling. Saying yes is stalling. Saying no is stalling. Thinking is stalling. Waiting is stalling.

Removal point is initially zero. [Used to determine which tracks should be removed from the Sequence.]

Ticker tracker is initially 0. [Used to time when Cochone needs to check the sports scores.]

temporary playlist and temporary favorites list and temporary position list are lists of things that vary.

Continuous play is initially false. [Indicates when the player plays multiple tracks.]

Already speaking is initially false. Unquoting is initially false. Capitalization is initially false.

Section - The Songs

A candidate song is a kind of thing that is proper-named. Some candidate songs are defined by the Table of Songs. Understand the short-name property as describing a candidate song. Understand the number-name property as describing a candidate song when the location contains a candidate song.

A candidate song can be favored. Burton, Jacques, Powell, and Filter are favored.

All candidate songs are in the Workstation.

Table of Songs

Candidate SongPrinted NameShort-name (text)Number-name (a number)
Courtney"Courtney Barnett""Avant Gardener"1
Yosi"Yosi Horikawa""Wandering"2
Jacques"Jacques Dutronc""Il Est Cinq Heures Paris S'eveille"3
Burton"The Animals""House of the Rising Sun"4
sfa"Super Furry Animals""Venus and Serena"5
Powell"Chris Powell""Hot Dog"6
filter"The Golden Filter""Solid Gold"7
Fang"Red Fang""Wires"8

Understand "Animals", "house", and "rising son" as Burton.

The description of Burton is "'Do you even need to ask?' Cochone says. [pb]'No, I guess not. [i]The Animals,[/i] right? Okay, I'll make sure we have a lot of that. But I'm picking [i]The Golden Filter[/i] to bring us into this decade with some great synth sound.' [pb]'A [']synth['] is a kind of guitar, right?'".

Understand "Barnett" as Courtney.

The description of Courtney is "Cochone shrugs. 'Okay. I'll take the first one. [']Avant Gardener.['] [pb]Jenny considers Cochone then tightens her lips. 'Hmm. Probably not the best choice given your ... condition. You won't appreciate Courtney if you don't listen to her, and I think you need to focus your mind on the case.' [pb]'Right.' [i]You wanted the music,[/i] Cochone thinks.".

Understand "french", "french song", "french music", "il", and "Dutronc" as Jacques.

The description of Jacques is "'How about the French one?' Cochone says. 'I don't hear much of that.' [pb]'Tres bien, Monsieur,' Jenny says. 'Un petit peu. We'll add Jacques. And how about some novelty, too? [']Hot Dog.['] Her smile widens. [pb]'Hot. Dog.'".

Understand "Chris Powell" as Powell.

The description of Powell is "Cochone raises an eyebrow. '[']Hot Dog?['] No question. I'll take that.' [pb]Jenny giggles. 'Okay, we'll go with a little bit of that, but we do need to get serious sometime. We'll add Jacques, too. For some French.' [pb]'Très bien.'".

Understand "red" as Fang.

The description of Fang is "Unable to concentrate and uninterested anyway, Cochone scans through the list and settles onto the last song. 'What about that last one, [i]Red Fang[/i]? Everyone likes vampires.' [pb]'[']Wires?['] Well ... If Happy Jack bothers you, then hard rock is probably not a good choice.' [pb]'Why don't you choose.'".

Understand "Super", "furry", "Super Furry", "Venus and Serena", "Serena", and "Venus" as sfa.

The description of SFA is "'I have two daughters,' Cochone says. 'How about [']Venus and Serena?[']' [pb]Jenny scrunches her face. 'Not sure that's the right father-daughter song for you.' [pb]'Right. You choose.'".

Understand "the golden", "Golden", and "golden filter" as Filter.

The description of Filter is "'How can we go wrong with a song called [']Solid Gold,[']' Cochone says. [pb]Jenny's smile widens. 'I never would have taken you for an electronica kind of guy.' [pb]'Huh. Me either.' [pb]'Don't worry, I'll make sure we get a good mix of both [i]The Golden Filter[/i] and something a little more your speed, like [i]The Animals[/i].' [pb]'Great. Sounds fun,' Cochone grumbles.".

Understand "Horikawa" as Yosi.

The description of Yosi is "'[']Wandering,['] Cochone says. 'I've heard that one. It's instrumental, right? I like the sound of that.' [pb]Jenny looks at Cochone. She purses her lips. 'Hmmm. I don't think I want to encourage your mind to start wandering today. It looks as if you'll need all your strength for the case. I'll pick the songs.' [pb]'Why ask me then?' Cochone mumbles.".

A music genre is a kind of thing that is fixed in place. classic, dance, foreign, instrumental, novelty, hard rock, and tinnitis are music genres.

Understand "buzzing", "buzz", "ringing", "ring", "ringing ears", and "ringing in my/Cochone's ears" as tinnitis.

All music genres are in Workstation.

Being-researched is a thing that varies.

Current music is initially classic.

Song cue is initially 0.

Investigation is a scene. Investigation begins when Workstation does not contain a candidate song. Investigation ends when the Workstation does not contain the player.

When Investigation begins:

now the time of day is 11:30 am; [We never state this time during the game, but we do use it for timed events, and a time just before lunch seems like a more appropriate starting point than is 9:00 am for this situation.]

Jenny inquires about the case at 11:34 am.

Section - Prologue Rules

After reading a command when the location contains a candidate song and the player's command matches "[a number]" and (the number understood is less than one or the number understood is greater than eight):

say "Cochone refocuses his eyes on the screen, and the lines of text resolve into eight songs. [lb]";

reject the player's command.

After reading a command when the player's command does not match "[a candidate song]" and location contains a candidate song:

if the accessible text of the player's command matches the regular expression "^\d\s" begin;

say "Cochone's vision blurs, and he can't be sure that he hasn't mismatched the numbers and songs they represent. He blinks and looks again. [pb]'C'mon, please?' Jenny says. [pb]";

try looking;

reject the player's command;

end if;

if the player's command includes "pick/choose/select/click", cut the matched text;

unless the player's command matches "[a number]" or player is queried or the player's command matches "x/examine [a person]" or the player's command matches "listen to [a number]" or the player's command matches "listen to [a candidate song]" or the player's command matches "cover/look/listen/wait/z/quit/restart/restore" begin;

unless player is dismissive begin;

if the accessible text of the player's command matches the regular expression "^y$|^yes$|^(say yes)$" begin;

say "'Gotcha the first time,' Jenny says. ";

otherwise;

say "'We agreed that we can't start without music,' Jenny says. [pb][i]Well, maybe you can't,[/i] Cochone thinks. [pb]";

end if;

now the player is dismissive;

end unless;

say "'Just pick one.' [pb]";

reject the player's command;

end unless.

Check examining a candidate song:

now every candidate song is off-stage.

Carry out examining sfa:

if the player is dismissive, rule succeeds.

After examining a candidate song when the noun is either Jacques or Powell:

say "'I'm sure you'll also appreciate [i]The Animals,[/i] so we'll add lots of them. But we need newer stuff, too. An equal measure of solid gold music from [i]The Golden Filter[/i] is called for. [rpo]";

continue the action.

After examining a candidate song when the noun is either Burton or Filter:

say "'I think we should also add something a little different. There's a reason I included ['][Jacques]['] and ['][Powell].['] You'll like them, I'm sure.' [rpo]";

continue the action.

After examining a not favored candidate song:

say "Jenny turns the laptop back to face her. 'Let's see. I'm sure you like [i]The Animals,[/i] so we'll add lots of them. We also need something modern.' She considers. 'We'll take solid gold synth from [i]The Golden Filter[/i]. And a little French culture wouldn't hurt. Jacques Dutronc. And to help lighten the mood , we'll add [']Hot Dog.['] [rpo]";

continue the action.

After examining a candidate song:

say "She taps some keys on the laptop, and ";

if player is not dismissive begin;

say "'[short-name of noun][unless noun is Burton],[end unless]'[unless noun is Burton] presumably,[end unless]";

otherwise;

say "music";

end if;

say " begins to play. She nods at the computer behind Cochone. 'Let's get to work. Open the [fiction title] program.' [pb]Cochone clicks on the icon, and [fiction title] loads the footage from the crime scene: [pb]";

carry out the printing the banner text activity;

try looking.

Chapter - Characters and Rooms

Workstation and Office are rooms. Stephen Cochone is a man in Workstation. Understand "detective", "cop", "Detective Steve/stephen/steven", "Steve/steven/stephen", "Steve/steven/stephen Cochone/cochon", "cochon/cochone", "Mr piggy/pigy/piggie/pigie", "piggy/pigy/piggie/pigie", and "pig" as Stephen Cochone.

The printed name of Cochone is "Cochone". The player is Cochone.

Cochone can be distracted. Cochone can be aware of different chains. Cochone can be vigilant of footage. Cochone can be remembering search. Cochone can be listening to the Who. Cochone is either considerate, reconsiderate, dismissive, or hesitant. Cochone is considerate. Cochone can be awaiting information. Cochone can be scoreboard watching. Cochone can be queried.

Cochone can be discussing wieners. Cochone is either waiting for lunch, thinking about lunch, having hot dogs, skipping lunch, or satiated. Cochone is thinking about lunch.

Jennifer Lincks is a woman in Workstation. Understand "coworker", "Jenny Lincks", "friend", "lady gaga", "gaga", "partner", "programmer", "teacher", "teach", "Marie", "Curie", "Marie Curie", and "tutor" as Jennifer.

The printed name of Jennifer is "Jenny".

Jennifer can be explaining the manual. Jennifer can be having lunch.

Nigel Jayne is a man. He is in Office.

Nigel can be waiting for lunch request.

Cochone wears the stain. Understand "coffee", "coffee stain", "coffee crotch", and "crotch" as the stain.

The description of the stain is "[i]Instead of smearing that cat all over the road this morning,[/i] Cochone thinks, [i]I spill my coffee.[/i] [lb]".

The description of Cochone is "Stephen Cochone scrambled out of bed this morning and rushed to the toilet to vomit. That was fortunate; he slept through the alarm, but he still had time for a quick shower and a splash of cologne. He was going to work with a young woman today, after all. If it wasn't for Jenny, he would have probably called in sick. His queasy stomach has settled, but his head pounds, and he has difficulty focusing his itchy eyes. [pb]Mornings like these were supposed to have ended when he had graduated from college and swore off the booze. That was the year his father, a vice cop, drove head-on into a truck, killing himself and his wife, Stephen's mother. They had just stumbled away from their wedding anniversary celebration at the bar where, twenty years previous, Stephen's father had stuffed dollar bills in his future wife's g-string. Perhaps alcohol abstinence has prevented some of the physical decline associated with age and detective work in a large city; Stephen looks generally the same as he did during his college years, despite a few creases around the eyes and gray hairs that appeared during and after the divorce, when his ex decided to take his daughters to New York with her.".

The description of Workstation is "[first time][b]case AU1319602014[/b][only] [pb][b]Sequence:[/b] [sequence listing][pb][b]Tracks (CP = cell phone; SR = sound recorder; BR = video recorder):[/b] [lb] [track listing][pb][b]Common Commands:[/b] CUT [bracket]a track[close bracket] | OPEN [bracket]a slot[close bracket] | PLAY [bracket]a track[close bracket] or SEQUENCE or PLAYLIST | PUT [bracket]a track[close bracket] IN [bracket]a slot or playlist[close bracket] | PUT [bracket]a track[close bracket] AFTER or BEHIND [bracket]a slot or track[close bracket] | SWITCH [bracket]a track[close bracket] WITH [bracket]a track[close bracket] | HELP (for a full list of commands) | HINT (for Jenny's advice) | LOOK or L (to refresh the screen)[pb]Your playlist[if favorites list is {}] is empty. [otherwise]: [play listing][end if][one of][or][lb][stopping]".

Jennifer wears the dogs and a bracelet. Understand "dog bracelet", "dogs bracelet", "dog jewelry", "silver dog/dogs", "silver bracelet" and "jewelry" as the bracelet.

Understand "great dane", "dane", "great danes", "danes", "chas", "chaz", "chazz", "dog", "puppy", and "puppies" as dogs.

Does the player mean doing something with the frankfurters:

if eating, it is very likely;

if examining and Cochone is having hot dogs, it is very likely;

it is very unlikely.

The description of Jennifer is "[if location contains a candidate song]Jenny cradles her laptop on her legs, a silver bracelet hanging from one wrist[otherwise]Cochone glances at Jenny. Her fingers dance over the laptop, her bracelet jiggling around one wrist[end if] [if Jennifer is having lunch]. Her lunch, a bagel, is sitting on the desk behind her[end if]. Her cane leans against the wall and next to the window, which looks out into the quiet hallway. [pb]Jenny is stuck in a wheelchair that is a bit too small for her lanky body. Cochone has pieced together parts of her story from gossip and hearsay. She hasn't always needed the wheels and cane. She had walked the beat when she joined the force, but her career path had veered off course after her drunken boyfriend found her in his house with another guy. His response was bone shattering. Jenny was smart enough to leave Mr. Fists and join the IT department, advancing it into the 21st century with innovation that would make NASA envious. [pb]Cochone thinks that Jenny doesn't look like a computer geek. She is slim, and she wears a stylish sleeveless shirt and skirt, which shows off most of her tanned legs. Her hair also exudes fashion and flash: long, copper, and curled at the bottom. And there's her rack, too. But she isn't pretty. Her facial features are pinched, and her lips are reddened to a shade that even vice cops would consider excessive."

The Workstation contains Happy Jack, the case, the cane, the computer, the frankfurters, the footage, the internet, Kiku, Marco, the notebook, playlist, the radio, and the Sequence.

Understand "graduation gift", "gift", "present", "graduation present", "Jack", "birthday bear", "birthday hat", "cymbal", "cymbals", "dancing bear" and "toy bear" as Happy Jack.

The description of Happy Jack is "Happy Jack is a fat brown bear with a colorful pointed cap on his head. He threatens Cochone with a glassy stare and the two cymbals strapped to his paws.[first time] [i]Why couldn't he have a squeeze box?[/i] Cochone thinks. [i]A really quiet one.[/i][only]".

Understand "case AU1319602014" and "AU1319602014" as the case.

Understand "monitor", "program", "screen", "sequitur", "sequitur program/software", and "software" as the computer.

Understand "eric", "erik", "mr fists", "husband", "boyfriend", "ex boyfriend", "ex-boyfriend", "chair", "wheelchair", and "wheels" as the cane.

Understand "evidence", "recording", "recordings", and "track" as the footage.

The footage can be intractable. The footage is intractable.

Understand "facebook", "Google", "search engine", "web", "wikipedia", and "yahoo" as the internet.

Does the player mean consulting the internet about text:

it is very likely.

Does the player mean doing something to the internet:

if stalling, it is very likely;

it is unlikely.

Understand "casebook", "notepad", "notes", and "note" as the notebook.

The notebook can be noted upon.

The notebook has an external file called text file. The file of Player's Observations is called "notebook". The text file of the notebook is the file of Player's Observations.

Playlist is a container.

Understand "my", "Cochone's", "Stephen's", "Steve's", and "detective's" as "[sc]".

Understand "[sc] playlist", "[sc] favorites/favourites", "favorites", "favourites", "[sc] music", and "music list" as playlist.

The printed name of playlist is "your playlist".

The playlist can be intractable. The playlist is intractable.

Understand "ipod", "itunes", "laptop", "music" and "song" as radio.

Understand "chains", "chain", "cd", "movie", "position", "positions", "sequences", "slots", and "slot" as the sequence.

The Sequence can be intractable. The Sequence is intractable.

The playlist, the sequence, and the footage are on-screen.

The summary is a device in Workstation. Understand "short description", "short descriptions", "abstract", "abstracts", and "summaries" as the summary.

A destination is a kind of thing. the church, the hospital, the house, the prison, the injured squirrel, and the water are destinations. All destinations are in Workstation.

Understand "Saint Maria's/Maria", "St Maria's/Maria", "Saint Maria's/Maria church", and "st maria's/Maria church" as church.

Understand "mont", "mont helene's/helene", "mont helene's/helene hospital", "mont hospital", "helene hospital", and "helene's hospital" as the hospital.

Understand "house of the rising sun", "rising sun", "brothel", "whorehouse", "mansion", "lab", "kiku's house", and "laboratory" as house.

Understand "jail", "Sangoro prison/jail", "correctional facility", and "sangoro" as prison.

Understand "leaf", "leaves", "bird", "birdbath", "bath", "ash trees", "ash", "tree", and "bird bath" as water.

Understand "squirrel", "squirrel with bum leg", "disabled/handicapped squirrel", and "hurt squirrel" as injured squirrel.

Does the player mean discussing water with someone when Time Lapse is examined or Backyard is examined:

it is very likely.

There is the band and the cream cheese bagel. Frankfurters and bagel are fixed in place and edible.

Bites remaining is initially eight. Hot dog length is initially eight.

Understand "cola", "coke", "pop", "dogs", "dog", "mustard", "pickle", "pickles", "relish", "chien chaud", "frank", "franks", "frankfurter", "hot dog", "hot dogs", "sausages", "wiener", and "wieners" as frankfurters. Understand "chien chaud" as the frankfurters when the location does not contain the band.

The description of frankfurters is "[if Cochone is satiated]Nothing left of the hot dogs but dirty napkins and mustard-soaked wrappers[otherwise if Cochone is having hot dogs]The fat wieners are slathered in mustard, with long pickle slices nestled in the relish. Cochone washes down each bite with a swig from the cola can[otherwise if Cochone is waiting for lunch][i]Nigel shouldn't be too long with those hot dogs,[/i] Cochone thinks[otherwise]Cochone hasn't eaten yet today, and two fat hot dogs sound good for lunch[end if]."

Understand "artists", "Chien chaud", "chat froid", "chien", "chaud", "chat", and "froid" as the band.

The printed name of the band is "Chien Chaud Chat Froid".

The band can be researched.

The description of the band is "Formed in 2009, Chien Chaud Chat Froid, [mdash] literally 'Dog Hot, Cat Cold' [mdash] has drawn from other bands like Dresden Dolls, LCD Soundsystem, Sleigh Bells, The Golden Filter, and Heart to produce an alternative dance sound all their own, with a nod to the blues-drenched soul of its New Orleans roots. Chien consists of three University of New Orleans graduates: Neo (vocals, guitar, percussion), Xeno (vocals, guitar), and Argo (keyboard, percussion). They released their first studio-produced album, [i]Iridium Kills,[/i] in 2012, which features the singles 'Lead Pipe' and a cover of Sweet's 'Love is Like Oxygen.' A second album, [i]White Phosphorous[/i] is scheduled for release in October. It features the single 'Nitro,' which is available from the band's website as a free download. The trio is currently producing a short movie to accompany their sophomore release. [pb]Chien Chaud Chat Froid live shows are raucous, flashy affairs with extravagant lighting and costumes ... ".

Understand "bottled water", "bottle", "jalepeno", "peppers", "jalepeno pepper/peppers", "water", "water bottle", and "bottle of water" as bagel.

The description of the bagel is "A layer of cream cheese spotted with jalepeno peppers covers each half of the bagel. The water must be used to put the fire out.".

Understand "asian", "asian girl", "girl", and "japanese girl" as Kiku.

Does the player mean researching with something about Kiku:

it is very likely.

Understand "Marko" as Marco. Understand "Marco Narbudada" and "Narbudada" as Marco when the item described is researched.

Marco can be unassociated with prison. Marco can be researched.

The description of Marco is "From Marco's mugshot, it appears as though his family probably mixed with a Caucasian somewhere in his past. He has an aquiline nose that matches his predatory, hawkish stare. He spent ten years in prison, between 1985 and 1995, for robbery. He is on the terrorist watchlist for his connections with the Tunisian terrorist group Ansar al-Sharia.".

Does the player mean researching with something about Marco:

it is very likely.

Section - The Subjects

A subject is a kind of person. Argo, Neo, Nickell, Salt, and Xeno are subjects.

A subject is either researchable or unresearchable. A subject is usually unresearchable. A subject can be researched.

All subjects are in Workstation.

A subject has some text called pseudonym. The pseudonym of Argo is "Shrapnel". The pseudonym of Neo is "Blue". The pseudonym of Nickell is "Pink". The pseudonym of Salt is "Veggie". The pseudonym of Xeno is "Foxy".

Neo and Xeno are female.

A subject has some text called feature. The feature of Argo is "with a face so full of metal piercings that he could have kissed a live grenade". The feature of Nickell is "wearing a Pink Floyd shirt". The feature of Neo is "with short blue hair". The feature of Salt is "with a 'Meat is Murder' t-shirt". The feature of Xeno is "with short gold hair and pointed features".

A subject is either unidentified, pseudonymized, or identified. A subject is unidentified.

Rule for printing the name of a subject (called target):

if target is unidentified begin;

say "[if capitalization is true]A[otherwise]a[end if][if target is Xeno]n[end if] ";

if target is female begin;

say "[if target is Xeno]attractive [end if]woman";

otherwise;

say "man";

end if;

say " [feature of target]";

if capitalization is true, now capitalization is false;

now target is pseudonymized;

otherwise;

say "[if the target is identified][printed name of target][otherwise][pseudonym of target][end if]";

end if.

Understand "shrapnel", "Sydney/Sidney", "patineau", and "sidney/sydney patineau" as Argo.

The description of Argo is "With a keyboard at one hand and mouse at the other, Argo (Sidney Patineau) produces the funky electronic vibes of Chien Chaud Chat Froid and designs album artwork. He is also co-owner, with his brother, of the Metallic Ink tattoo and piercing shop in downtown New Orleans. Born November 1 1991 in New Orleans, he studied music and visual arts at university where he met Neo ... . In an accompanying photo, a blond-haired guy stares defiantly at the camera. He isn't punctured with the metal jewelry like he is in the video footage and, without it, He could pass for a high schooler.".

Understand "blue", "Penelope/Penny/Penney", "gibson", and "Penelope/penny/penney gibson" as Neo.

The description of Neo is "Neo (Penelope Gibson) grew up with a guitar in her arms and a microphone at her mouth. Born January 22 1991 in New Orleans and daughter of a Protestant minister father and librarian mother, she sang in her church choir before majoring in music at the University of New Orleans. While there, she met Sidney Patineau, and the two began performing on campus and at local bars under the name Chien Chaud Chat Froid.

Neo is an active member of PETA ... . Cochone skips ahead to a photo of a girl with spikey, dark blue hair. Her wide eyes, accentuated with eyeliner, are cobalt blue. Her bulbous nose complements the quirky look which, Cochone admits to himself, works well for her.".

Understand "foxy", "Veronica Cartwright", "veronica", and "cartwright" as Xeno.

The description of Xeno is "Xeno (Veronica Cartwright), born June 11 1990, finished top of her class in high school before leaving her Baton Rouge home for New Orleans. At UNO, she majored in science and volunteered for the campus radio station, hosting a popular weekend show. She joined the band Chien Chaud Chat Froid after founding members Argo and Neo (at the time known as Sid and Penny) heard her performing in a club with her older sister, lead vocalist for the electropop group Fish Go Glub. She writes most of Chien's music ... . Cochone is drawn to an image of a woman with short gold hair and small features, her red lips parted in a smile and revealing bone-white teeth.".

Understand "pink", "Jakob/Jacob" and "Jacob/Jakob Nickell" as Nickell.

The description of Nickell is "Along with his wife, Sandra, Jakob Nickell (born May 11 1981) runs the [i]Spydersound[/i] music studio in New Orleans. Both having degrees in audio production, They have produced albums for local jazz and blues musicians, and Sandra has recorded two of her own. More recently, they have expanded into radio and television, with some of their work being broadcast nationally. [i]Spydersound[/i] is a state-of-the-art music studio with over five years of experience ... . Cochone glances at Nickell's photo. Nickell is a tall skinny guy with lots of black hair and big ears. [i]Or maybe I'm imagining the Dumbo-look,[/i] Cochone thinks.".

Understand "veggie", "veggy", "Dylan" and "dylan salt" as Salt.

The description of Salt is "Dylan Salt, born December 3 1982 in New York, studied film in college and has gone on to direct and produce music videos for bands such as Carbonites and The Bunch of Turkeys, including three songs from their gold-certified album [i]A Through Z.[/i] He has also directed commercials for Nike and many others. 'Francis Ford Coppola really got it right in the seventies,' he said in a recent interview. 'Not just [i]The Godfather,[/i] though. He really captured the paranoia of the decade in [i]The Conversation.[/i]' He also cites David Fincher as a major influence ... . A photo of Salt shows a brown-haired guy winking at the camera. His shirt reads 'Strangeways, Here We Come.'".

Section - The Tracks

A track is a kind of thing that is fixed in place and on-screen. A track is either A-side or B-side. A track is usually A-side.

Substitution track is initially zero. [Substitution track is used to represent the track specified in the inserting tracks relatively action, which handles three nouns by storing the third in this variable.]

A track has some text called label. The label of a track is usually "". Understand the label property as describing a track.

Being-labelled is a track that varies. Being-summarized is a track that varies.

A track has some text called short-description. The short-description of a track is usually "".

A track has a replacer. The replacer of a track is always trak. Understand the replacer property as referring to a track.

A track has a number called number-name. Understand the number-name property as describing a track.

Some tracks in the Workstation are Defined by the Table of Album Tracks. Understand the source property as describing a track. Understand the duration property as describing a track.

Track list is a list of tracks that varies. Primary chain is a list of tracks that varies. Secondary chain is a list of tracks that varies.

Intellectual links is a list of tracks that varies. [These are tracks that the player has established as linked.]

Favorites list is a list of tracks that varies. The favorites list is {}.

A track can be explained. [These have been linked to the appropriate track but, because some tracks are continuous, simply being linked isn't always enough to be explained.]

A track can be story-important. A track is usually story-important. [These are part of the long chain]

A track can be continuous. [Continuous tracks are run through the "recalling a link" activity when a third relevant track has been placed in the Sequence. For other tracks, just linking two tracks is enough to tell the player that a link has been made. Part of the rationale for this is to discourage players from simply placing tracks mindlessly until notified that a link has been made.]

Placeholder is a privately-named thing in Workstation. The printed name of pllaceholder is "empty".

Rule for printing the name of a track (called target) while asking which do you mean:

say "Track [number-name of target], [printed name of target]".

Rule for printing the name of a track (called target):

unless unquoting is true, say "'";

say appropriate name for target;

if unquoting is true and stripping tag info is false, say " ([source of target]; [duration of target])";

unless unquoting is true, say "'".

Does the player mean doing something with a track:

if conversing, it is unlikely;

if researching with something about, it is unlikely;

it is likely.

[The rule below is useful when the player refers to Track 1 and the I6 parser is running multiple actions (e.g., the player has typed "put 2, 5, 1 in playlist."]

Does the player mean doing something with a numero uno thing:

if stalling, it is very unlikely;

it is very likely.

[We need these because the DTPM rules need to be specific for second nouns.]

Does the player mean exchanging something for a track:

it is very likely.

Does the player mean excising something from a track:

it is very likely.

Does the player mean excising something through a track:

it is very likely.

Does the player mean inserting something relatively left of a track:

it is very likely.

Does the player mean inserting something relatively right of a track:

it is very likely.

Does the player mean inserting something to a track:

it is very likely.

Does the player mean playing something through a track:

it is very likely.

Does the player mean reversing something through a track:

it is very likely.

[The order we list the tracks is important. They should be listed in sequence because the track list variable is randomized, and this way we can still make a list of tracks in order.]

Table of Album Tracks

TrackSource (text)Duration
Backyard"CP1"04:25
Dead Animals"CP1"03:12
Time Lapse"VR2"120:00
Sound Test"SR"00:21
Squirrel Trap"CP2"06:11
Kitchen"VR1"05:22
Diary"VR1"00:30
Chrysanthemum"CP2"04:01
Locked-door"CP1"03:52
Google"CP3"00:00
Basement"VR1"07:33
Motorboat"SR"120:00
Fight"CP2"07:46
Escape"CP1"08:02
Torching"CP2"00:17

Backyard, Dead Animals, Time Lapse, Kitchen, Diary, Chrysanthemum, Fight, Escape, and Torching are continuous.

The printed name of Locked-door is "Locked Door".

Section - Positions

Position is a kind of container that is fixed in place, transparent, and on-screen. A-slot, B, C, D, E, F, G, H, I, and J are positions. The printed name of A-slot is "A". [We need to use a-slot because the source won't accept "A" as a name of a thing.]

Understand "a slot/position", "a", "1st", and "first" as a-slot. Understand "v slot/position", "2nd" and "second" as B. Understand "c slot/position", "3rd" and "third" as C. Understand "d slot/position", "4th" and "fourth" as D. Understand "e slot/position", "5th" and "fifth" as E. Understand "f slot/position", "6th" and "sixth" as F. Understand "g slot/position", "7th" and "seventh" as G. Understand "h slot/position", "8th" and "eighth" as H. Understand "i slot/position", "9th" and "ninth" as I. Understand "j slot/position", "10th" and "tenth" as J.

Substitution slot is a thing that varies. [We set this to placeholder in some cases, so it can't always be a position. It is used for inserting relatively actions that need a third noun substitution.]

A position has a replacer. The replacer of a position is always groove. Understand the replacer property as referring to a position.

A position has a number called number-name.

All positions are in Workstation.

Position list is a list of things that varies.

Chapter - Definitions and Relations

Definition: a thing is involved if the current action involves it and it is not the player.

Definition: a thing (called target) is numero uno if target is a track and the number-name of target is one. [We need this because the game doesn't recognize "1" as the first track when it is the noun in actions with two tokens.]

Definition: a thing is positioned rather than unpositioned if it is in a position.

Definition: a container is empty rather than full if it does not contain a track.

Linkage relates one track to one track. The verb to link means the linkage relation.

[A track links to another when one follows the other and they are next to each other in the Sequence, but they are still considered "linked" when they are removed.]

Matchup relates one team to another. The verb to play means the matchup relation.

Replication relates various tracks to each other. The verb to replicate means the replication relation. [Replicated tracks have common things within them, such as a person, chair, or table. We want to use different indicators of these when the player has seen them already in another track. For instance, seeing a chair in, say, track three will print "a chair," but seeing the same chair again in track fifteen will print "the chair."]

Reincarnation relates various tracks to various subjects. The verb to record means the reincarnation relation. [We use this to relate a track to the people that are featured in it. Unlike the "revelation" relation, this one is used even if only a name is mentioned in the track.]

Revelation relates various tracks to various subjects. The verb to reveal means the revelation relation. [A track reveals a subject when it describes a person and identifies him or her by name.]