Volume - Hidden Reality
Book - Egg Hunt and Hidden Server
Chapter - Objects and Rooms
Finding Reality is a scene. Finding Reality begins when the player is the bunny.
Task Three ends when player is the bunny.
EggRoom1, EggRoom2, EggRoom3, EggRoom4, EggRoom5, EggRoom6, EggRoom7, EggRoom8, EggRoom9, EggRoom10, EggRoom11, and EggRoom12 are rooms.
Should the game choose doing something with something which is enclosed by the Office when the player is the bunny:
Should the game choose doing something with something which is enclosed by the Boar Bar when the player is the bunny:
Should the game choose doing something with something which is enclosed by the Chamber when the player is the bunny:
EggRoom1 contains an animal called the bunny.
Understand "bunny's/rabbit's/bunny/rabbit ears/nose/leg/legs/foot/feet", "easter/white bunny/rabbit" and "rabbit" as the bunny.
The bunny incorporates the ears, the eyes, the feet, the legs, and the nose.
Rule for printing the name of something (called body part) when the body part is part of the bunny:
say "bunny's [printed name of body part]".
Should the game choose doing something to something which is part of the bunny:
The description of EggRoom1 is "[first time]The egg cracks. There is light. [pb]You jump. The egg breaks open. [only]The Orphic egg lies cracked open at your feet. The new world expands before you, its form shifting and experimenting. It won't be like the world you left behind. [pb]You bounce on your feet, eager to prove your worth to the other bunnies by finding those 12 eggs. But there's a wall blocking your way. You're big for a bunny, but not as tall as this wall.".
EggRoom1 contains the wall and the Orphic Egg.
Understand "big/tall wall" as the wall.
Jumping over is an action applying to one thing. Understand "jump over [something]" as jumping over.
Orphic jumping over the wall:
say "You crouch and jump over the wall. You fall down the other side and splash into a pool of yellow goo. You found the egg yolk! [pb]Pumping your legs, you manage to make it out of the goo and onto solid ground next to a river.";
move the player to EggRoom2.
The description of EggRoom2 is "The water separating you from the rest of the eggs looks very deep and rough. Wide, too. Way too far to jump. [one of]Nearby, a giant is busy snapping trees in his giant arms and stacking them into a huge pile. He wipes sweat from his brow, exhales deeply, then sees you. He glances at the other side of the river then smiles at you. He bends over and holds out his empty arms[or]Smiling and bent over toward you, the giant holds out his open arms[stopping].".
EggRoom2 contains the giant-arms, the giant, the egg-trees, and the egg-river.
The giant is a man.
The printed name of the giant-arms is "giant's arms". The printed name of the egg-river is "river". The printed name of the egg-trees is "trees".
Understand "arm/arms/hand/hands", "his arm/arms", "giant/giant's arm/arms", "giant's open arms", and "open arms" as the giant-arms.
Understand "stack/stacks" and "tree/trees" as the egg-trees.
Understand "deep water", "river/stream/water" as the egg-river.
Jumping into is an action applying to one thing. Understand "jump into/in to/-- [something]" as jumping into.
Orphic jumping over the egg-river:
say "That's way too far.".
Orphic jumping into the egg-river:
say "That might be really deep, and I can't swim.".
Orphic jumping into the giant-arms:
say "You jump into his arms. He nuzzles your neck, pulls a carrot from his pocket, and gives it to you. [pb]The giant wades through the water, which reaches his belly. He got all wet, and you got a carrot and where you wanted to go. You found a good egg! [pb]After munching away the carrot, you find yourself at some kind of track with racers far ahead of you. One of them is a chicken, the other ... something small and wobbly.";
move the player to EggRoom3.
The description of EggRoom3 is "[one of]You find the line in the dirt marking the start line and [or]At the start line, you [stopping]wait for the starter pistol to go off so you can catch up to the racers ahead of you. You bounce on your feet in anticipation. You can catch these guys. Let's go already!".
EggRoom3 contains the starter pistol, the starting line, and the racers.
Understand "starter gun" as the starter pistol.
Understand "bird/chicken/runner/racer/runners" as the racers.
Jumping the start is an action applying to nothing. Understand "jumpstart", "jump start", and "jump the gun" as jumping the start.
Orphic jumping the start when EggRoom3 contains the player:
say "You can't wait for the signal anymore, so you jump";
if the player's command includes "gun" begin;
say " the gun";
say ". You speed past all the other racers but cross the finish line after the chicken. An egg has crossed the line as well. You found an egg! You can't tell whether the chicken came first, though. [pb]A gopher bowls into you and starts digging. The hole deepens and expands as the animal whirls around, dirt flying. The ground crumbles. You fall in and land on a floor.";
move player to EggRoom4.
The description of EggRoom4 is "Colorful lights swirl around the floor in the otherwise dark room. A young woman, Joy, dances to the pulse-pounding music. Her arms flail, and there's something in each of her hands. She smiles at you, expectant.".
EggRoom4 contains the dance-music, the dance-floor, the lights, faux-joy, and Joy. faux-joy is a woman.
The printed name of dance-music is "music". The printed name of dance-floor is "dance floor".
Understand "dance/disco music" and "music/song" as the dance-music.
Understand "disco", "dance floor", "dancefloor", and "floor" as the dance-floor.
Understand "light" as the lights.
Understand "young woman" as faux-joy.
Joy incorporates Joy-arms.
The printed name of Joy-arms is "Joy's arms".
Understand "joy/joy's arm/arms/hand/hands" and "arm/arms/hand/hands" as Joy-arms.
Orphic jumping into joy-arms:
say "She doesn't look like she could hold you.".
Jumping for is an action applying to one thing. Understand "jump for [something]" and "jump with [someone]" as jumping for.
Orphic jumping for Joy:
say "You jump to the beat, and Joy's smile widens. Joy nods then spins around you until the song ends. She opens her hands, revealing an egg in each. You found the egg shaker! [pb]The music starts again, and Joy hip-bumps you out the door.";
move player to EggRoom5.
The description of EggRoom5 is "[one of]You tumble onto a street where a group of children have gathered to[or]A group of children[stopping] watch a pair of bored-looking girls swing two skipping ropes between them. The audience cheers you on. They recognize a talent when they see it! You're sure you could wow them.".
EggRoom5 contains the audience, the girls, the rope, and the skipping-rope.
The printed name of the skipping-rope is "skipping rope".
Understand "boy/boys/children/crowd/kids" and "crowd/group of children/kids/girls/boys" as the audience.
Understand "pair/friends/girl" and "young girl/girls" as the girls.
Understand "jump/jumping/skip/skipping rope" as the skipping-rope.
Orphic jumping over when the noun is either the rope or the skipping-rope:
say "But you want to do it more than once.".
Orphic jumping for when the noun is either the girls or the audience:
say "You can hardly wait to show them!".
Jumping with is an action applying to one thing. Understand "jump [something]" as jumping with.
Last orphic jumping with something:
say "You're not a violent bunny, so you don't need to get the jump on anything.".
Orphic jumping with the rope:
say "You jump between the ropes, but the girls begin to swing faster and faster. Your foot catches in a rope, and you fall. The crowd sings a chorus of 'ahs.' You got egg on your face!";
move the player to EggRoom6.
The description of EggRoom6 is "[one of]Giggling, the two girls wrap you in the rope and pull you down the street. They leave you, unbound, in the doorway of a house with just one room. [pb][or]You stand in the doorway of a single-room house. [stopping]Chalkboards with equations line the walls between filled bookshelves. Textbooks and bound papers are stacked around a clear space in the room's center. They balance in delicate shapes, their weight making indentations in the rubber floor.".
EggRoom6 contains the books, the chalkboards, the floor, the space, and the spot.
Understand "delicate/wobbly shape/shapes" and "book/bookshelf/bookshelves/shape/shapes/textbook/textbooks/shelf/shelves" as the books.
Understand "calculation/calculations/equation/equations/chalkboard" as the chalkboards.
Understand "indentation/indentations", "rubber floor", and "rubber" as the floor.
Understand "center", "center room", "small clear area/space/place", "small/clear area/space/place" and "area/place" as the space.
Jumping onto is an action applying to one thing. Understand "jump on [something]" as jumping onto.
Orphic jumping onto the wall:
say "You aren't up there.".
Orphic jumping onto the spot:
say "You jump on the spot in the center of the room and jump and jump and jump. The books and papers shake. They fall all around you, revealing a pale man wearing glasses, a pocket protector, and lab coat. You found the egghead! [pb]He opens a closet and ushers you inside. The door closes behind you. A bright light.";
move the player to EggRoom7.
The description of EggRoom7 is "[one of]You materialize in darkness. You feel something small bump your leg. And another something. And another. You pick one up, feel it, smell it. It says, 'Meep.' It's a chick. A chorus of 'meeps' erupt around you. [pb]You wade through the chicks, find a wall, and tap on it. It feels hard but thin. You follow it and end up back where you started. Probably. [pb]You tap the wall. If only your puny arms were as strong as your legs, then you could bust out of this place[or]Chicks call out from the darkness with a chorus of 'meeps.' They, like you, are trapped within this round cage made of one hard thin wall that one good punch could probably break. Darn your puny arms[stopping].".
EggRoom7 contains the chicks, the meeps, and the egg-wall.
The printed name of the egg-wall is "wall".
Understand "babies", "baby chicks/chickens/chick" and "chick/chicken/chickens" as the chicks.
Understand "crying", "chick/chicks call/sound/music/meep/meeps" and "meep" as the meeps.
Understand "circular/egg/round/hard/thin wall/walls", "hard thin wall/walls", and "wall/walls" as the egg-wall.
Understand "kick" and "kick [something]" as a mistake ("You're more of a jumper than a kicker.") when the player is the bunny.
Jumpkicking is an action applying to one thing. Understand "jumpkick [something]", "jump kick [something]", "jumpkick", and "jump kick" as jumpkicking.
Rule for supplying a missing noun while jumpkicking and the location is EggRoom7:
now the noun is the egg-wall.
Rule for supplying a missing noun while jumpkicking and the location is EggRoom11:
now the noun is the hunters.
Rule for supplying a missing noun while jumpkicking:
now the noun is the player.
Rule for supplying a missing noun while listening and the location is EggRoom7:
now the noun is the meeps.
Orphic listening when the noun is either the meeps or the chicks:
say "They want to leave as badly as you do!".
Orphic jumpkicking someone:
say "That might hurt, and you don't want to hurt anyone.".
Orphic jumpkicking egg-wall:
say "You jump kick the wall. You hear a crack. You kick again. And again. On your fourth try, the cage shatters into pieces that fall all over you and the chicks, who scurry away. You found eggshells! [pb]You step onto a particularly large shell, and it lifts you into the air. It speeds off over land and water, eventually stopping over star-studded space. The shell tilts, and you slip off, landing on a giant asteroid.";
move the player to EggRoom8.
The description of EggRoom8 is "You're balanced in the middle of a rectangular chunk of rock orbiting around a single sun with many others glowing as pinpricks in the darkness. The rock slopes downward into a bowl on your left and a valley to your right. The valley goes way, way down, much farther than the bowl. [pb]You have to get off of here. This is crazy!".
EggRoom8 contains the asteroid, the bowl, the shallow end, the middle ground, the deep end, outer-space, and the valley.
The printed name of outer-space is "outer space".
Understand "rock/rocks/meteor" as the asteroid.
Understand "depression/hole/left" as the bowl.
Understand "center/centre" as the middle ground.
Understand "constellation/dark/darkness/gas/helium/space/star/stars/sun" as outer-space.
Understand "deep ground" and "right" as the valley.
Orphic jumping over when the noun is not outer-space and the location is EggRoom8:
say "You'd rather jump off than over.".
Orphic jumping into outer-space:
say "But where to launch from?".
Orphic jumping into when the location is EggRoom8 and the noun is not outer-space:
say "That wouldn't get you outta here!".
Jumping from is an action applying to one thing. Understand "jump from [something]" as jumping from.
Orphic jumping from something which is not outer-space when the location is EggRoom8:
say "That just doesn't sound like the right thing to do.".
Jumping off of is an action applying to one thing. Understand "jump off of/-- [something]" and "jump off" as jumping off of.
Rule for supplying a missing noun while jumping off of when the player is bunny:
if location is EggRoom8, say "Off which end? One is much deeper than the other.";
otherwise say "Off of what?".
Orphic jumping off of something when (the noun is neither the shallow end nor the deep end nor outer-space) and location is EggRoom8:
say "You'll have to choose from which end to jump.".
Orphic jumping off of something when the noun is either the shallow end or middle ground:
say "You sense that won't get you anywhere you want to be.".
Orphic jumping off of the deep end:
say "You think about it then jump off the deep end. Mindless, you float for awhile, passing through an evaporating gaseous globule. You found an egg in outer space! Eventually you're picked up by a spaceship that resembles a yellow submarine.";
move the player to EggRoom9.
The description of EggRoom9 is "The spaceship is crowded with animals and people. There's a walrus, a penguin, some pigs, a priestess ... a joker laughing ... smokers choking ... and that's just in its place. You hear even more people from behind, but you can't turn around to see. The exit, though, must be that way. [pb]Everyone listens to the city policeman auditioning up on a stage. He sings a lot of 'Get back, get back, get back to where you once belonged.'".
EggRoom9 contains the crowd, the city policeman, the joker, the penguin, the pigs, the priestess, the stage, the walrus, the smokers, the spaceship, and the sub-music.
The printed name of the sub-music is "music".
Understand "animal/animals/audience/people" as the crowd.
Understand "pornographic" and "pornographic priestess" as the priestess.
Understand "pig" as the pigs.
Understand "laughing" and "laughing joker" as the joker.
Understand "choking", "smoker", and "choking smoker/smokers" as the smokers.
Understand "cop/police" and "musician" as the city policeman. The city policeman is a man.
Understand "submarine/ship" as the spaceship.
Understand "audition/chorus/song/songs" as the sub-music.
Orphic listening to when the noun is either the sub-music or the city policeman:
say "He's good.".
Orphic listening when the location is EggRoom9:
say "That policeman can sure sing.".
Orphic jumping ahead of the crowd:
say "But you want back there.".
Orphic jumping out of the spaceship:
say "You don't want to leave exactly, just get out of this room.".
Orphic jumping over something which is not the sub-music when the location is EggRoom9:
say "That would only get you closer to the stage, and it's too hot too stay in here.".
Jumping back is an action applying to nothing. Understand "jump back" as jumping back.
Orphic jumping back:
if the location is EggRoom9 begin;
say "As good as the music is, it's stifling in here. You jump back over the crowd, tumble through the exit, and land at the feet of a white, oval-shaped man. You found the eggman! [pb]The eggman shoves you into a torpedo tube and fires you from the ship. You fly straight into a lineup outside a movie theater.";
move the player to EggRoom10;
say "That isn't where you want to go.";
The description of EggRoom10 is "You're lined up outside a theater, but the entrance is so far that the marquee isn't visible[one of]. As you wait, a group of tough-looking teenage boys break into the lineup right in front of you. What a bunch of butt-inskies! You might even miss the movie because of them[or]. The line moves slowly, and you're afraid you'll miss the movie. The butt-inskies could get in and you won't. You should be closer than them[stopping].".
EggRoom10 contains the boys, the lineup, and the theater.
Understand "bullies", "bully", "buttinsky", "boy", "crowd", "but-inskies", "buttinskies", "men", "teen", "teens", "teenager", "teenagers", and "toughs" as "[butt-ins]".
Understand "[butt-ins]", "mean/tough/rough [butt-ins]" and "tough-looking [butt-ins]" as the boys.
Understand "line-up" and "line/queue" as the lineup.
Understand "marquee", "movie theater/theatre", "movie", and "theatre" as the theater.
Jumping cut is an action applying to nothing. Understand "jump the/-- cut" as jumping cut.
Jumping ahead of is an action applying to one thing. Understand "jump ahead of/-- [something]" as jumping ahead of.
Orphic jumping with the lineup:
say "You'll need to be more specific to not be a butt-insky yourself.".
Orphic jumping ahead of the boys:
say "You'll need to be more precise so you don't be a butt-insky yourself.".
Orphic jumping over the boys:
say "But you don't want to jump too far, just ahead of them.".
Orphic jumping cut:
if the location is EggRoom10 begin;
say "You give the boys a good stare before jumping the cut. You land just in front of them. Using their fingers, they show their displeasure and leave. [pb]Inside the theater, you eagerly await the movie. The title sequence appears. It's [i]The Egg and I![/i] As it starts, the boys return, put a sack over your head, and carry you off. This is scary.";
move player to EggRoom11;
say "That doesn't seem to make sense here.";
The description of EggRoom11 is "[one of]The boys dump you into a bush in a forest. A deer grazes nearby, but it can't see you. It jerks its head up and runs off. Two hunters appear and walk toward your bush[or]A couple of hunters approach, but they can't see you hiding in the bush[stopping]. They've turned the forests into some kind of horror movie. You and the other animals have lived in fear of them for too long. Payback time!".
EggRoom11 contains the bush, the forest, and the hunters.
Understand "bushes/foliage" and "hiding spot/place" as the bush.
Understand "tree/trees/woods" as the forest.
Understand "gun/guns/hunters" and "people/man/men" as the hunters.
Orphic jumpkicking the hunters:
say "That would probably just make them mad.".
Jumping out of is an action applying to one thing. Understand "jump out of [something]" as jumping out of.
Orphic jumping out of the orphic egg:
say "That wall is in the way.".
Orphic jumping out of the egg-wall:
say "But you're surrounded by it, and it has no holes.".
Orphic jumping out of the bush:
say "You want to be more precise for the desired effect.".
Jumping for fright is an action applying to nothing. Understand "jump scare" as jumping for fright.
Orphic jumping for fright when the location is EggRoom11:
say "You wait for the hunters to get close. At the right moment, you jump. They yell out and stumble back in fright. Their faces are egg white! Feeling satisfied, you jump away.";
move the player to EggRoom12.
Orphic jumping for fright:
say "There's no-one you want to scare around here.".
Jump counter is initially 0.
The description of EggRoom12 is "[one of]You reach a field but, just as you decide to rest, a hula hoop suspended by a rope drops from the sky and dangles in front of you[or]A hoop suspended from a rope dangles in front of you[stopping].".
EggRoom12 contains the hoop and the sky-rope.
The printed name of the sky-rope is "dangling rope".
Understand "dangling rope" and "rope" as the sky-rope.
Understand "dangling hula hoop", "dangling hoop", "hula hoop", "hula", "dangling ring", and "ring" as the hoop.
Jumping through is an action applying to one thing. Understand "jump through [something]" as jumping through.
Orphic jumping through the wall:
say "That would hurt if I tried!".
Orphic jumping through the egg-wall:
say "Not head-first. No way.".
Orphic jumping through the hoop when the jump counter is less than 4:
increment jump counter;
say "You jump through the hoop. It retracts and disappears. Another drops down in its place.".
Orphic jumping through the hoop when the jump counter is 4:
say "The hoop retracts into the sky, and a colorful egg falls from it. You found the Easter egg! A backdoor materializes and opens. You jump through. Press a key to continue.";
wait for any key;
clear the screen;
now player is yourself;
move the player to FC Server.
Jumping over is acting like bunny. Jumping into is acting like bunny. Jumping the start is acting like bunny. Jumping for is acting like bunny. Jumping with is acting like bunny. Jumping onto is acting like bunny. Jumpkicking is acting like bunny.Jumping from is acting like bunny. Jumping off of is acting like bunny. Jumping back is acting like bunny. Jumping cut is acting like bunny. Jumping ahead of is acting like bunny. Jumping for fright is acting like bunny. Jumping out of is acting like bunny. Jumping through is acting like bunny.
FC Server is a room. "[first time]I'm so glad you found me. I am part of the creative team behind [i]S.hip[/i] and [i]Gaia's Web.[/i] This backdoor opens into the FromChaos server. FromChaos is using the [i]S.hip[/i] series of games to shape players['] realities and influence real-world events: All of us will become characters in their game. Please help me get the word out by opening any of these folders and copying their contents to your computer. [pb][only]H:\Managers\World Management [pb]Volume: Ship Series[lb]Volume Serial Number is FC024-7445[pb]<DIR> People [lb]<DIR> Narratives [lb]<DIR> Science [lb]<DIR> Culture".
the folder, EarthSim, Personnel, Narratives, Science, and Culture are secret folders.
All secret folders are in FC Server.
When play begins:
now EarthSim is off-stage.
Understand "file/files" and "folders" as the folder.
The printed name of personnel is "People".
Understand "people" as personnel.
Yourself can be final stage.
Chapter - Hidden Reality Non-Jumping Actions and Rules
Rule for printing a parser error when the latest parser error is the can't see any such thing error and the player is the bunny:
say "I'm not sure I see that, or I didn't understand you.".
Rule for printing a parser error when the player is the bunny:
say "I couldn't understand you. Remember, I'm just a bunny, and I'm really good at jumping.".
Rule for printing the name of a room when the player is the bunny:
say "The Beginning of a Time".
To say unknown command:
say "Unknown command. RTuttle is authorized to copy or open files and folders; dir refreshes the listing.".
Rule for printing a parser error when the location is FC Server:
say "[unknown command] [lb]".
Understand the commands "hop" and "skip" as something new.
Understand "hop", "hop [any thing]", and "hop [text]" as a mistake ("You're not a baby, so you jump rather than hop.") when the player is the bunny.
Understand "skip", "skip [any thing]", and "skip [text]" as a mistake ("Your legs were made for jumping; skipping is more of a human thing to do.") when the player is the bunny.
First before doing something other than looking when the player is the bunny:
if examining the player, say "Your nose twitches and your ears perked. Most importantly, your legs are strong. You're ready to find those eggs!" instead;
if jumping, say "Yep, that's what bunnies do, and you're a bunny. You find, though, that particular skill much more effective when you decide exactly how to use it." instead;
if waiting, say "You can hardly wait to find those eggs!" instead;
follow the orphic rules;
if rule succeeded, rule succeeds;
if examining or smelling or listening, say "Your eyes, ears, and nose are working perfectly fine. You can't learn anything more about [if the noun is a room]this place[otherwise][the noun][end if]." instead;
say "You're a bunny and, though you can't do a lot, your legs are strong, and you can really jump. That's all you need to do to find those eggs." instead.
First orphic when the noun is the player and not examining:
say "I do the jumping; I never get jumped.".
Last orphic when acting like bunny:
say "I can surely jump, but I don't know how to do that [unless the noun is nothing]with [the noun], and I'm not sure that would help anyway[otherwise]to be effective now[end unless].".
Understand "copy [text]" as a mistake ("Cannot find file.") when location is FC Server.
Understand "cd [a secret folder]" as opening when location is FC Server.
Copying is an action applying to one thing. Understand "copy [something]" as copying when location is FC Server.
Rule for supplying a missing noun while copying and location is FC Server:
now the noun is personnel.
Check copying something which is not a secret folder:
say "Cannot find file." instead.
Carry out copying a secret folder:
say "copying [noun] ... *** Error finding files: parent <DIR> EarthSim *** [lb]";
move EarthSim to FC Server.
First before doing something other than looking when location is FC Server:
if copying a secret folder or opening a secret folder, continue the action;
if closing, say "No folders open." instead;
say "[unknown command] [lb]" instead.
Understand "dir", "directory", "directories", "list", "ls", "folder", and "folders" as looking when location is FC server.
Before opening EarthSim:
choose row with a final response rule of immediately restart the VM rule in the Table of Final Question Options;
blank out the final question wording entry;
choose row with a final response rule of immediately undo rule in the Table of Final Question Options;
blank out the final question wording entry;
choose row with a final response rule of immediately restore saved game rule in the Table of Final Question Options;
blank out the final question wording entry;
choose row with a final response rule of immediately quit rule in the Table of Final Question Options;
blank out the final question wording entry;
now player is final stage;
try looking instead.
This is the confirming Earth's destruction rule:
say "Are you sure you want me to delete Earth?";
if the player consents begin;
say "Press a key to begin destruction.";
say "Termination aborted. Press a key to logout.";
wait for any key;
follow the immediately quit rule.
Instead of looking when player is final stage:
say "MV-12-MW:\Simulations\Managers[pb]Volume: World-254[lb]Volume Serial Number is 7.128.874.214[pb]Galaxy: Milky Way[lb]Planet: Earth [lb]NPC Population: 7,103,275,784 [lb]PC Population: 100,452,547 [pb]Simulation Executive Group: FromChaos [lb]Executive Member PCs: Fordondo Alambo, Kevin Bland, Riley Scott, Valentina Stutikoff, and James Whang [pb]";
end the story finally saying "Welcome user RTuttle. I am running Simulation: Earth, which began 7.214 billion years ago (sim-time). "
Instead of copying EarthSim:
say "The contents of EarthSim cannot be copied.".
Instead of opening a secret folder:
say "Opening [noun] ... *** Error finding files: parent <DIR> EarthSim *** [lb]";
move EarthSim to FC Server.
Table of Final Question Options (continued)
|final question wording||only if victorious||topic||final response rule||final response activity|
|"QUIT"||false||"quit"||confirming Earth's destruction rule||--|
|"RESTART"||false||"restart"||immediately restart the VM rule||--|
|"or RESTORE the world"||false||"restore"||immediately restore saved game rule||--|
|"do you want to LOGOUT"||true||"logout"||immediately quit rule||--|
The print the final question rule response (A) is "Would you like [if location is FC Server]me [end if]to ".
Chapter - Test Commands
Test pre-task with "n / kill zeus / quit / read e-mail / read review / touch harbormaster / Nigel / nSbjayne".
Test task-1 with "Test task-1-crash".
Test task-one with "test pre-task / test task-1-crash".
Test task-2 with "headpop into the swan / x me / read invitation / ask bud about raven / ask pig about raven / talk to cat / talk to dog / talk to rat / talk to fly / talk to rat / recognize tuttle as raven".
Test task-two with "test pre-task / test task-1 / test task-2".
Test task-3 with "showme globe / relations / showme tablet / recognize Chin as the buzzard / bio for Chin / showme buzzard / recognize Olga as eagle / bio for Olga / showme eagle / recognize hawk as Yaphet / bio for Yaphet / showme hawk / recognize owl as Fiona / bio for Fiona / showme owl / bio for raven / showme raven / z / showme swan".
Test task-three with "test pre-task / test task-1 / test task-2 / test task-3".
Test bonus with "test pre-task / test task-1 / test task-2 / test task-3 / test bunny".
Test bunny with "jump over wall / jump into arms / jump start / jump for joy / jump rope / jump on the spot / jumpkick / jump off the deep end / jump back / jump cut / jump scare / jump through hoop / jump through hoop / jump through hoop / jump through hoop / jump through hoop.".
Test server with "open people / open earthsim".
Test whole-game with "test pre-task / test task-1 / test task-2 / test task-3 / test bonus / test server".
Test task-1-crash with "activate drone / x drone / x alicia / talk to Alicia / 1 / x travis / talk to Travis / 1 / x Chucky / activate Chucky / x Eve / z / x roger / x Sam / talk to sam / 2 / z / z / deploy gas / talk to Alicia / 1 / z".
Test task-1-roadblock with "activate drone / x alicia / x travis / x squirrel / x sam / x drone / talk to Alicia / 2 / talk to travis / 1 / z / z / z / z / talk to jason / 1 / z / z".
Test diana with "activate drone / activate Chucky / click Alicia / click Travis / click Sam / click Chucky / click doncan-132 / talk to Alicia 2 / talk to Travis / 3 / talk to sam / 1 / z / z".