gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for Gaia's Web

Volume - HarborMaster Tasks

Book - Task Three

Chapter - Task Three Rooms and Characters

Task Three is a debugging scene. Task Three begins when location is the Chamber. Task Two ends when the location is the Chamber.

After deciding the scope of the player when Task Three is happening and the location is the Chamber:

place the Office in scope.

When play begins:

repeat with selection running through conspirators begin;

add selection to the aliases of the selection;

add co-conspirator of the selection to the aliases of the selection;

unless selection is the swan, add second co-conspirator of the selection to the aliases of the selection;

end repeat.

The Chamber is a room. "This chamber is deep underground and lined by gray stone, as if to protect the world above from the explosive secrets that are discussed within. Meetings are conducted around the wooden table at its center, which is flanked by a bank of monitors and a rotating holographic globe. Attendees enter through a thick wooden door and are greeted by a mural splashed over the west wall. [pb]The buzzard, the hawk, and the owl are sitting around the table. At one end, the raven presides from an ornate chair, an electronic tablet before him[one of]. [pb]*** [if one conspirator is disconnected]Warning: [username of yourself] does not recognize PCs [the list of disconnected conspirators]. Please re-establish connection to something in the world with RECOGNIZE [BRACKET]someone[close bracket] AS [bracket]someone[close bracket]. [end if]All PCs activated. [if one conspirator is disconnected]Additional commands [otherwise]The commands [end if]available are BIO FOR [bracket]someone[close bracket], RELATIONS, and SHOWME [bracket]something[close bracket]. ***[or]. [stopping] ".

Should the game choose doing something to something which is enclosed by the Chamber when engaged in Task Three:

it is an excellent choice.

The chamber contains the bank of monitors, the chamber-table, the chamber-walls, the globe, the mural, and the ornate chair.

The bank of monitors is a switched on device.

The bank of monitors is scenery.

Understand "monitor/screen/screens", "building/buildings/vehicles/interior/interiors/exterior/exteriors", "television/televisions/tv/tvs", "television/televisions/tv/tvs monitors/monitor/screen/screens", "footage/video/videos", "video footage", and "wall of monitors/screens/televisions/tvs" as the bank of monitors.

The description of the bank of monitors is "The monitors fill an entire wall. They show video footage of vehicles and people as well as building exteriors and interiors.".

Should the game choose doing something to the bank of monitors:

if engaged in Task Three, it is an excellent choice;

never.

The chamber-table is a furnishing.

The printed name of the chamber-table is "table".

understand "chairs/seats/table" and "meeting/large/wood/wooden table" as the chamber-table.

Should the game choose doing something to the chamber-table:

if engaged in Task Three, it is an excellent choice;

never.

The description of the chamber-table is "The table seats five people along each length and one at each end.".

The chamber-walls is a furnishing. The printed name of the chamber-walls is "stone walls".

Understand "chamber walls", "gray/grey/stone walls" and "stone/rock/walls" as the chamber-walls.

The description of the chamber-walls is "Claustrophobic without windows and carved from cold rock, the chamber encourages short meetings.".

The globe is scenery.

Understand "country/countries/land/sea/seas/ocean/oceans/water", "land/water area/mass/region", "earth", "hologram", "earth/globe/world hologram", "holographic/rotating/spinning earth/globe/world", and "world" as the globe.

Understand "china", "great wall" and "great wall of china" as the globe when the addressee is the buzzard.

Understand "russia", "snowglobe", "snow/snowflakes" and "kremlin" as the globe when the addressee is the eagle.

Understand "africa", "desert/sand", "green/lush jungle", and "jungle" as the globe when the addressee is the hawk.

Understand "england/europe" and "castle" as the globe when the addressee is the owl.

Understand "americas/america/usa", "american flag", "bald eagle", and "flag/stripes" as the globe when the addressee is the raven.

The description of the globe is "[if the addressee is the swan]The globe fills one end of the chamber. It rotates slowly, with subtle changes in direction. It flickers off occasionally and re-appears with a different rotation, forcing you to see the earth from different perspectives[otherwise if the addressee is the buzzard]The globe sprouts a Great Wall that extends around the equator to encircle the earth. Banded, it spins from east to west[otherwise if the addressee is the eagle]The globe has transformed into a snow globe, with snowflakes shimmering around the Kremlin[otherwise if the addressee is the hawk]The globe rotates with one side showing barren desert and the other lush green jungle[otherwise if the addressee is the owl]Castle walls have formed around the earth, which continues to spin within its confines[otherwise if the addressee is the raven]A bald eagle flies around the rotating earth, sprinkling stars and laying down the stripes of the American flag over the land and sea[end if].".

The mural is scenery.

Understand "painting/picture" and "mailbox/pole/zork" as the mural.

The description of the mural is "The wall is painted black with white cartoon letters spelling out 'ZORK.' A wooden door opens from the 'O,' revealing a dark interior. A mailbox pole bisects the 'O' and 'R.' Its planted into a patch of grass and tilted so that the mailbox itself covers the 'R' and 'K.'".

The ornate chair is a furnishing.

Understand "gold-flecked chair/seat", "gold/golden chair/seat", "padding", "padded/red chair/seat", and "blood/deep red chair/seat" as the ornate chair.

The description of the ornate chair is "It's the only chair with padding, a dark red, and wood flecked with gold.".

Should the game choose doing something to the ornate chair:

if Task Three is happening, it is an excellent choice;

never.

The raven carries a switched on computer called the raven's tablet.

The raven's tablet has a list of things called the raven's agenda.

Understand "electronic tablet", "ipad", and "raven's computer/laptop" as the raven's tablet.

The description of the raven's tablet is "He doesn't let anyone touch it, or see what he is doing on it.".

Should the game choose doing something to the raven's tablet:

if Task Three is happening, it is an excellent choice;

never.

Chamber-door is east of Chamber and down from Bud's cellar. The chamber-door is a closed locked door.

The printed name of chamber-door is "chamber door".

Understand "chamber/wood/wooden door", "door", and "windowless door" as chamber-door.

The description of the chamber-door is "The door is windowless, heavy, and closed. It is never left open or unlocked.".

Should the game choose doing something to the chamber-door:

if Task Three is happening, it is an excellent choice;

never.

All conspirators are in the Chamber.

The buzzard disguises Chin Lee.

Understand "Chin/Lee/MoneyClip" and "Chin Lee" as Chin Lee when the buzzard is disconnected.

Understand "Chin/Lee/MoneyClip" and "Chin Lee" as the buzzard when the buzzard is connected.

The buzzard wears the buzzard's mask. Understand "Chin's/Lee's/buzzard [disguise]" and "[disguise] of the/-- Chin/Lee/buzzard" as the buzzard's mask.

The buzzard is responsible for NPC characteristics.

The real name of Chin is "James Whang". The DOB of Chin is "09/22/1972". The residence of Chin is "2236 Wangfujing St. Beijing, Hebei, China". The email of Chin is "CLee55@sotfc.com".

The pic of Chin is "Picture of James Whang: A narrow-faced man with sandy brown hair, hazel eyes, and thin lips.".

The eagle disguises Olga Burlenko.

The eagle has a list of things called favorite drinks.

Understand "Olga/Burlenko/LuckySeven" and "olga burlenko" as Olga Burlenko when the eagle is disconnected.

Understand "Olga/Burlenko/LuckySeven" and "olga burlenko" as the eagle when the eagle is connected.

The eagle wears the eagle's mask. Understand "Olga's/Burlenko's/eagle [disguise]" and "[disguise] of the/-- Olga/Burlenko/eagle" as the eagle's mask.

The eagle is responsible for Resource Management.

The real name of Olga is "Valentina Stutikoff". The DOB of Olga is "11/01/1981". The residence of Olga is "254 Ulitsa Rubinshteyna, St. Petersburg, Russia". The email of Olga is "puckbunny@sotfc.com".

The pic of Olga is "Picture of Valentina Stutikoff: Chubby-cheeked woman with auburn hair, green eyes, and a bright smile.".

The hawk disguises Yaphet Kalotto.

Understand "yaphet/kalotto/everyman" and "yaphet kalotto" as the hawk when the hawk is connected.

Understand "yaphet/kalotto/everyman" and "yaphet kalotto" as Yaphet Kalotto when the hawk is disconnected.

The hawk wears the hawk's mask. Understand "Yaphet's/Kalotto's/hawk [disguise]" and "[disguise] of the/-- Yaphet/Kalotto/hawk" as the hawk's mask.

The hawk is responsible for World Modeling.

The real name of Yaphet is "Fordondo Alambo". The DOB of Yaphet is "01/08/1979". The residence of Yaphet is "340 Cavendish Rd. YEOVILLE, South Africa". The email of Yaphet is "Kalotto2@sotfc.com".

The pic of Yaphet is "Picture of Fordondo Alambo: Bald-headed man with big brown eyes and no discernable chin.".

The owl disguises Fiona Campbell.

Understand "fiona/campbell/needlepoint" and "fiona campbell" as the owl when the owl is connected.

Understand "fiona/campbell/needlepoint" and "fiona campbell" as Fiona Campbell when the owl is disconnected.

The owl wears the owl's mask. Understand "Fiona's/Campbell's/owl [disguise]" and "[disguise] of the/-- Fiona/Campbell/owl" as the owl's mask.

The owl is responsible for Titan Management.

The real name of Fiona is "Riley Scott". The DOB of Fiona is "10/05/1991". The residence of Fiona is "27 Berwick St. Soho, London, UK". The email of Fiona is "whalesong@sotfc.com".

The pic of Fiona is "Picture of Riley Scott: A woman with curly blond hair, wide blue eyes, and a crooked nose that looks like it could have been broken.".

The raven disguises Richard Tuttle.

The raven can be connected or disconnected. The raven is disconnected.

Understand "Richard/Tuttle/laserlight" and "richard tuttle" as Richard Tuttle when the raven is disconnected.

Understand "Richard/Tuttle/laserlight" and "richard tuttle" as the raven when the raven is connected.

Understand "richard's/tuttle's/raven [disguise]" and "[disguise] of the/-- richard/tuttle/raven" as the raven's mask.

The raven is responsible for Player Characteristics.

Understand "blackbird" and "crow" as the raven.

Raven's drink is an alcoholic drink that varies.

The raven is disconnected.

The real name of Richard is "Kevin Bland". The DOB of Richard is "02/22/1988". The residence of Richard is "1105 Rideout Lane, Point Pleasant, WV, USA". The email of Richard is "engineer1988@sotfc.com".

The pic of Richard is "Picture of Kevin Bland: A man with short black hair, thick eyebrows, and a long thin nose.".

Understand "bird" as a conspirator.

The description of a conspirator is usually "[Our] hair is [hair color of the item described], [our] eyes [eye color of the item described]. [if item described is short][We] [hold] [ourselves] straight to compensate for [our] height[otherwise if item described is average][We] [stand] with confidence but not dominance[otherwise][Our] height attains a lofty air, but [we] still [come] across as down-to-earth[end if], bound in a [weight of item described] frame. Like [if the item described is refined and item described is female]a ballerina[otherwise if the item described is bold]a bull[otherwise if the item described is clumsy]an unwary child[otherwise]a surgeon's hand[end if], [our] movements are [movement of item described][if item described wears a mask]. [Description of a random mask worn by the item described][otherwise].[end if][if the item described is the swan and the player is the swan] In the pocket of your jeans is an invitation.[end if]".

The description of a mask is usually "[The item described] [if item described is swan's mask]is really just a bunch of white feathers over the cheeks and around the eyes[otherwise if the item described is the buzzard's mask]has a crooked beak and dirty gray feathers that cover the entire face[otherwise if the item described is the eagle's mask]covers the cheeks in fine white feathers, and its beak is short and sharp[otherwise if the item described is the hawk's mask]covers the entire face in wide brown feathers and hides the nose under a small hooked beak[otherwise if the item described is the raven's mask]surrounds the eyes in a flurry of black feathers[otherwise if the item described is the owl's mask]plasters the face in tan and white feathers, which are smoothed into large circles around the eyes[end if].".

Chapter - Task Three Rules

Yourself can be investigating relations.

Carry out showing relations when location is the Chamber:

now player is investigating relations;

say "Manipulation relates various people to one sector.";

say "The buzzard manipulates Finance.";

say "The eagle manipulates Alien and Paranormal.";

say "The hawk manipulates Culture.";

say "The owl manipulates health.";

say "The raven manipulates science and Technology. [pb]";

say "Boozing relates various people to various alcoholic drinks.";

say "The raven drinks [raven's drink].";

say "The eagle drinks [favorite drinks of the eagle].";

if turns taken is 2, say "[lb]>The raven reads his tablet.".

Turns taken is initially 0.

Every turn when engaged in Task Three and turns taken is 1:

if player is not investigating relations, say ">The raven says: Before bringing in our guest of honor, I'll ask each of you to summarize our 'family' connections. [pb]>The raven checks his tablet.".

Every turn when engaged in Task Three and turns taken is 2:

now the addressee is the buzzard;

say ">The raven says: Let's start with our buzzard. [pb]The equator of the globe bulges outward, forming a great wall.".

To say possible error message for (talker - a person):

if talker is disconnected, say "[pb]*** Warning: [Username of yourself] does not recognize PC [the talker]. *** [pb]".

Every turn when engaged in Task Three and turns taken is 3:

now the addressee is the eagle;

say ">The buzzard [possible error message for the buzzard]says: Show me the money, man! Project Humpty Dumpty is well under way, financial aid is being withdrawn from the uncooperatives, destabilization and re-organization should follow.".

Every turn when engaged in Task Three and turns taken is 4:

now the addressee is the eagle;

say ">The raven says: And you, eagle? [pb]The globe explodes into a flurry of snowflakes, and the Kremlin emerges.".

Every turn when engaged in Task Three and turns taken is 5:

say ">The eagle [possible error message for the eagle]says: We're trying to squash and discredit the studies on the Illuminati DNA, but we'll probably have to forge medical records for several of the British monarchy and other world leaders. So far we've also been able to hide what was found in the remains of the Chelyabinsk meteor, and we're tracking down all the pieces we can.".

Every turn when engaged in Task Three and turns taken is 6:

now the addressee is the hawk;

say ">The raven says: Hawk? [pb]The globe flickers, showing contours in intense leafy green and sandy brown.".

Every turn when engaged in Task Three and turns taken is 7:

say ">The hawk [possible error message for the hawk]says: We've decided to turn our attention away from the usual race and religious slander [mdash] real world events are brewing enough hate [mdash] and focus on ... lighter issues. Like giving film awards to aging white male actors. Although we're still supporting doping in major sports and the skewing of judges['] scores in major events.".

Every turn when engaged in Task Three and turns taken is 8:

now the addressee is the owl;

say ">The raven says: Good. And you, owl? [pb]The globe rotates south, skimming over blue water and traveling north.".

Every turn when engaged in Task Three and turns taken is 9:

say ">The owl [possible error message for the owl]says: We're continuing to keep the effective cancer treatments under wraps. We're testing our Project Rainbow chemicals for various interested parties. We're conducting extensive field studies. There will be a worldwide epidemic of people with bizarre medical symptoms of unknown etiology, but a diagnosis of mass psychogenic disorder should hide all of them.".

Every turn when engaged in Task Three and turns taken is 10:

now the addressee is the raven;

say ">The raven says: Good job everyone. And me? [pb]The globe spins rapidly and stops on the Americas.".

Every turn when engaged in Task Three and turns taken is 11:

now the addressee is the swan;

now the swan is conscious;

say ">The raven says: We're continuing to hide and slow progress in clean energy research for Big Oil, and we don't want cold fusion and EM Drive technology to get out just yet. And of course we are helping the NSA and their surveillance efforts; we're continuing to experiment with computer simulations and games with real-world components. [pb]The raven taps on his tablet.".

Every turn when engaged in Task Three and turns taken is 12:

move swan to Chamber;

say ">The raven says: Let's welcome our newest member. She's ready. [pb]The swan opens the door and enters the Chamber. [pb]>The raven says: Welcome to Gaia. We're really impressed with your work on the methods to hide characters from players. The induction process has already begun, and you should see a change in your PC's awareness.".

Every turn when engaged in Task Three and turns taken is 13:

if the sidebar is g-present, close the sidebar;

now sidebar is disallowing toggling;

say ">The swan says: Thank you, everyone. [pb]>The swan says (to the raven): We have a problem. An unauthorized titan took over my PC and followed me on the last test. [username of yourself]. I don't know how much about us has been revealed or whether [username of yourself] is logged on and watching us now. [pb]>The raven types on his tablet. [pb]Press any key.";

wait for any key;

clear the screen;

say "Your webcam switches on, and you appear on the computer screen. HarborMaster's alarm sounds, and it shows the message: '*** Resources activated ... acquiring targets ... ' Addresses of your residence and those of family and friends. 'Target locked ... target locked ... ' [pb]Press a key.";

wait for any key;

clear the screen;

say "Webcam footage on the screen shows a man in a raven mask sitting at his computer. He speaks. 'Looks like we got our wires crossed somehow. You seemed to have picked up the wrong suitcase, as it were, and peeked inside.' He frowns and shakes his head. 'I guess we'll find out whether working for FromChaos has taught you how to stay out of its clutches.' [pb]The raven sips from a mug. He cocks his thumb at you, his finger the gun barrel. He shoots you. 'In the meantime, you might find this ... insightful.' He winks at you and taps on his keyboard. [pb]Downloading Egg Hunt. Done. [pb]Do you want to play a game? [pb]";

if the player consents begin;

now the player is the bunny;

try looking;

otherwise;

say "You don't have time for the raven's games right now. You fear a much larger [mdash] and real [mdash] game is about to begin.";

say thank the player;

end if.

Last every turn when location is the Chamber:

increment turns taken.