gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for Gaia's Web

Volume - HarborMaster Tasks

Book - Task Two

Chapter - Task Two Rooms and Characters

Task Two is a debugging scene. Task Two begins when location is the Boar Bar.

First after reading a command when the location is the Boar Bar for the first time:

disable saving of undo state.

After deciding the scope of the player during Task Two:

if the location is the Office, place the Boar Bar in scope;

if the location is Boar Bar, place the Office in scope.

The Calydonian Boar Bar is a room. "The bar is buried underground, as if its proprietor, Bud, doesn't want people to find him. And if they do, the damp cold is likely to hasten their exit. The television hanging from the wall next to the bar counter glows as bright as the lights, and it is so loud that you wonder if Bud actually wants anyone to try to order a drink from him. He knows his stuff, though, given the well-stocked shelves behind him. [pb]Except for Bud, everyone wears a mask. A dog and a cat are sitting at one table. A rat, the waitress, is sitting on a barstool. With a drink in hand, a fly hovers [unless cat has spoken of raven or dog has spoken of raven or pig has spoken of raven]around her[otherwise]between you and the waitress[end unless][if location contains pig]. A pig watches everyone from the doorway, the stairs behind him leading up and down[end if][if player is yourself]. The swan watches the stairs[end if].".

Should the game choose doing something with something which is enclosed by the Boar Bar when engaged in Task Two:

it is a good choice.

The printed name of the Bar is "The Calydonian Boar".

Before looking when the location is the Boar Bar for the first time:

say "PC the swan of [set link 18]Eve Martin[end link] detected and inactive. Locating resources ... none found. [HarborMaster] sidebar updated to testing commands[if sidebar is g-unpresent and the sidebar is allowing toggling]; use SIDEBAR ON or SIDEBAR OFF to toggle it[end if]. [pb]";

say "[b]Transcript of Eve Martin (as the swan)[/b] [pb]>Raven, ";

if Eve is crashed by squirrel, say "A squirrel took out Roger's car! We're okay. ";

say "[if Roger is gassed]There's some trees. I think we can lose them in there[otherwise]We're trying to hide in some trees[end if]. I'm sure I'll pass the test. [pb]The raven says (to the swan): Good luck. I'll send the vulture for you when we're ready. [pb]The raven leaves the bar through the east door.".

All alcoholic drinks are in Boar Bar.

An alcoholic drink has a number called sippiness.

Some alcoholic drinks are defined by the Table of Booze.

Table of Booze

Alcoholic DrinkSippiness
Agent Orange6
American Sour5
Black Russian4
Bloody Mary8
Blue Star7
Brass Monkey6
Bull Shot5
Bushwacker6
Cosmopolitan8
Elephant's Ear6
Fluffy Critter5
Fuzzy Navel6
Gin Rikki6
Grasshopper7
Gunfire5
Harvey Wallbanger8
Hurricane6
Kahlua8
Long Island Ice Tea9
Manhattan8
Margarita8
Mudslide7
Pink Squirrel6
Rusty Nail7
Screwdriver4
Singapore Sling8
Slippery Nipple7
Snakebite7
Strawberry Mule6
Yellow Bird6
Wild Turkey3
Zombie4

The description of an alcoholic drink is "[if the item described is carried]It looks as you had hoped[otherwise]Bud prepares and presents each without flourish[end if].".

Rule for printing the name of a conspirator (called target) when showing attributes for an alcoholic drink:

say "[co-conspirator of the target]".

Should the game choose doing something to an alcoholic drink:

if engaged in Task Two begin;

if drinking or taking, it is a good choice;

if giving something to a person, it is a good choice;

end if;

never.

The beer, Bourbon, Martini, the red wine, scotch, tequila, vodka, and the white wine are alcoholic drinks.

The sippiness of the beer is 8. The sippiness of Bourbon is 5. The sippiness of Martini is 7. The sippiness of the red wine is 8. The sippiness of Tequila is 6. The sippiness of scotch is 5. The sippiness of vodka is 4. The sippiness of the white wine is 8.

A boozer is a kind of person.

Andrew hicock, Brian Flanagan, Coral Gershwin, Doug Kaufman, Jordan Mooney, Bonnie Clyde, Rowdy Patrick, Michael Curtiz, Oliver Wilson, Shelley Hacker, Robert Niskin, Dean Martin, Robert Kennedy, and Joanne Wilcox are boozers.

When play begins:

let choice be a random number between 1 and the number of rows in the Table of Booze;

choose row choice in the Table of Booze;

now raven's drink is Alcoholic Drink entry;

now the drinkers of Alcoholic Drink entry is {Richard Tuttle};

let patrons be the list of boozers;

let drinks be a list of things;

now drinks is the list of alcoholic drinks;

remove Raven's drink from drinks;

repeat with counter running from 1 to the number of entries in patrons begin;

now choice is a random number between 1 and the number of entries in drinks;

add entry counter in patrons to the drinkers of entry choice in drinks;

remove entry choice from drinks;

end repeat;

add a random alcoholic drink to the favorite drinks of the eagle;

add Olga Burlenko to the drinkers of entry 1 in the favorite drinks of the eagle;

now the favorite drinks of the fly is the preferred 4 drinks of the fly;

now the favorite drinks of the rat is the preferred 5 drinks of the rat;

now the favorite drinks of the swan is the preferred 1 drink of the swan;

repeat with talker running through conspirators begin;

unless talker is the swan begin;

unless the talker is the raven, add Eve Martin to the things spoken about of the talker;

add the pig to the things spoken about of the talker;

end unless;

if the talker is the raven begin;

add the list of co-conspirators to the things spoken about of the raven;

add the list of co-conspirators to the raven's agenda of the raven's tablet;

end if;

if the talker is the owl, add Project Rainbow to the things spoken about of the talker;

if the talker is the buzzard, add Project Humpty Dumpty to the things spoken about of the talker;

end repeat;

remove Richard from the things spoken about of the raven.

Project Humpty Dumpty and Project Rainbow are things.

To decide which list of things is the/-- preferred (total - a number) drink/drinks of/-- (imbiber - a person):

let drink list be a list of things;

let potential drinks be the list of alcoholic drinks;

while the number of entries in drink list is less than total begin;

let choice be a random number between 1 and the number of entries in potential drinks;

let booze be entry choice in potential drinks;

unless booze is raven's drink begin;

add booze to drink list, if absent;

add imbiber to drinkers of booze, if absent;

end unless;

end while;

decide on drink list.

A furnishing is a kind of thing. A furnishing is scenery.

Some furnishings are defined by the Table of Bud's Stuff.

Table of Bud's Stuff

FurnishingDescription
Bud's tv"It shows a hockey game between a team with a duck bill on their jerseys and another with what looks like a penguin."
the barstools"Wooden and uncomfortable. A bit like Bud himself."
the counter"Bud keeps the counter clean and clear of any clutter, like napkins or free snacks."

Bud's tv, the barstools, and the counter are in the Boar Bar.

The Boar bar contains the alcohol and the Cologne.

Should the game suggest entering the barstools when engaged in Task Two:

it is a good suggestion.

Understand "alcoholic drink/drinks", "booze", "bottle/bottles", "drink/drinks/hooch", and "liquor" as the alcohol. The printed name of the alcohol is "booze".

The description of the alcohol is "Bud keeps his bar well-stocked.".

Should the game choose doing something to the alcohol:

never.

Understand "Bud's television", "bar television/tv", "big-screen tv/television", "big/large screen tv/television", "large-screen tv/television", "large/big tv/television", "hockey/sports game", "game", "play-by-play/commentary", "play by play", and "television/tv" as Bud's tv.

Should the game choose doing something to Bud's tv when engaged in Task Two:

it is a good choice.

Understand "barstool/stool/stools" and "chair/chairs" as the barstools.

Understand "bar" as the counter.

Understand "musk/pheromone", "raven/raven's cologne/musk/odor/pheromone/scent", and "odor/scent/smell" as the cologne.

The description of the cologne is "The raven's cologne lingers, smelling as if you had been sprayed with a pheromone.".

Understand "budweiser", "coors", "guinness", and "molson" as the beer.

Should the game choose doing something to the red wine when comparing the red wine against the white wine:

it is a good choice.

Bud, The cat, the dog, the fly, the pig, and the rat are people in the Boar Bar. The cat and rat are female.

Bud, The cat, the dog, the fly, the pig, and the rat are npc.

Should the game choose doing something with an npc person when engaged in Task Two:

it is a good choice.

A person can be blocked from player. [For NPCs that the player tries to control.]

Bud is bartender.

Understand "bartender", "bar tender", and "buddy" as Bud.

The description of Bud is "With his bald head, wide forehead, small eyes, and black beard, Bud looks like he should be wearing a loincloth and hunting the wildlife with a giant club.".

The cat is retiree.

The cat can be crying.

The cat wears the cat's mask. Understand "cat [disguise]" and "[disguise] of the/-- cat" as the cat's mask.

Understand "black cat/kitten/kitten", "dog's wife", "kitten/kitty", "pussycat", "tissue/purse/kleenex", and "whisker/whiskers/wife" as the cat.

The description of the cat is "[if the item described is crying]The diminutive lady is hunched over and dabbing her eyes with a tissue, the whiskers on her black cat mask twitching[otherwise]The woman in the black cat mask could be mistaken for a child if it weren't for her gray hair[end if].".

The dog is retiree.

The dog wears the dog's mask. Understand "dog [disguise]" and "[disguise] of the/-- dog" as the dog's mask.

Understand "cat's husband", "husband", and "puppy" as the dog.

The description of the dog is "[if the cat is crying]The dog rests his hand on the shoulder of the cat sitting next to him. His [otherwise]The [end if]dog mask is of a generic brown dog with floppy ears and big jowls[unless the cat is crying]. The man in the mask sits next to a cat, and a beer rests on the table in front of him[end if].".

The fly is pilot.

The fly has a number called drunkenness. The drunkenness of the fly is 0.

The fly has a list of things called favorite drinks.

The fly wears the fly's mask. Understand "fly [disguise]" and "[disguise] of the/-- fly" as the fly's mask.

Understand "bar fly", "barfly", "eye/eyes" and "black fly" as the fly.

The sober talk list is a list of people that varies. [To track who the fly has talked to before he gets drunk. His conversation topics change depending on his drunkenness.]

The description of the fly is "He reminds you of a fruit fly: all black and with big red eyes. He seems to be keeping an eye on you, but it's hard to tell exactly what he's looking at. [if drunkenness of the item described is greater than 10]He is unsteady on his feet, and his head bobs[otherwise if the drunkenness of the item described is greater than 5]He wobbles a bit on his feet[otherwise][pb]He raises his drink to you[first time]. [pb]Okay. So maybe he is watching you[only][end if].".

The pig is law enforcement.

The pig wears the pig's mask. Understand "pig [disguise]" and "[disguise] of the/-- pig" as the pig's mask.

Understand "fat man" as the pig.

Understand "cop/detective/officer", and "police officer" as the pig when the rat has spoken of the pig.

The description of the pig is "The pig wears one of the few full face masks you've seen tonight. It's chubby cheeks, snout, and dark hollow eyes give it a sinister appearance, but it's hard to take too seriously when the guy wearing it is this fat. He hasn't moved from the doorway since you've arrived.".

The rat is exotic dancer.

The rat wears the rat's mask. Understand "rat [disguise]" and "[disguise] of the/-- rat" as the rat's mask.

Understand "barmaid", "gray nose", "nose", and "waitress" as the rat.

The rat has a list of things called favorite drinks.

The description of the rat is "The waitress wears a long gray rat nose with prickly whiskers and a black tip. It doesn't fit the tall blond woman at all.".

The swan can be raven-asking.

The addressee is the swan.

The swan has a list of things called favorite drinks.

The swan wears the swan's mask. Understand "Eve's/Eve/Martin's/martin/swan [disguise]", "[disguise] of the/-- swan/eve/martin", and "Eve Martin's [disguise]" as the swan's mask.

Understand "eve/martin" and "eve martin" as the swan when engaged in Task Two or engaged in Task Three.

Understand "feather/feathers" and "white feather/feathers/swan" as the swan.

Understand "pc" as the swan when the player is the swan.

The swan incorporates a container called the pocket. The pocket contains the invitation.

Understand "animal/cartoon card", "cartoon/farm animal/animals", "card/invite" as the invitation.

The description of the invitation is "Its cover says 'We're planning a wild party' above a group of cartoon animals. The message within reads, 'Be at the Calydonian Boar at 8:00 pm on the 28th of June.' It's signed 'G.'".

Understand "jeans/pants" as the pocket.

The description of the pocket is "Your pocket holds the invitation.".

Chapter - Task Two Conversation

First conversation rule for someone who is not the pig when Boar Bar contains the pig and the conversationalist is not Bud and the noun is the raven:

say "'Can you tell me anything about the raven?' you say. [pb][The conversationalist] glances at the imposing pig standing in the doorway. [if the conversationalist is female]She[otherwise]He[end if] lowers h[if the conversationalist is female]er[otherwise]is[end if] head down then shakes it.";

rule fails.

First conversation rule for someone when conversationalist has spoken about the noun and the noun is the swan:

say "You're sure [the second noun] has nothing important on you.".

First conversation rule for someone when conversationalist has spoken about the noun and the noun is a person:

say "'Anything more you can tell me about [the noun]?' you say. [pb]";

if the conversationalist is:

-- Bud: say "'I've said my piece.'";

-- cat: say "'I told you what I know, dear.'";

-- dog: say "'No, nothing.'";

-- fly: say "[if drunkenness of the fly is greater than 14]'Not that I can think of. Not that I can. Think, that is[otherwise if the drunkenness of the fly is greater than 6]You aren't getting any more out of me.' He burps. 'Besides that[otherwise]'Not a word[end if].'";

-- pig: say "'I won't say any more.'";

-- rat: say "'There's nothing more to say, as far as I know.'".

A conversation rule for someone when a furnishing has been spoken generally about and the noun is a furnishing:

say "[The conversationalist] has already shared h[if the conversationalist is male]is[otherwise]er[end if] opinion on [if the conversationalist is Bud]his[otherwise]Bud's[end if] sense of interior design.";

rule fails.

A conversation rule for someone when the noun is an alcoholic drink and an alcoholic drink has been spoken generally about and the conversationalist is neither Bud nor the rat:

say "You remember [the conversationalist] wasn't interested in a drink the first time you asked.";

rule fails.

A conversation rule for someone when the noun is an alcoholic drink and the conversationalist is neither Bud nor the rat:

say "'Can I get you a drink?' you say. '[Noun]?' [pb]";

if the conversationalist is:

-- cat: say "'I haven't had a drink in over 40 years, my dear. I just drink water.' She frowns. 'But not from here.'";

-- dog: say "'I'm not finished my beer, thanks.'";

-- fly: say "'Usually I would, but I'm trying to cut down.' He sips his drink and winks. 'Starting tomorrow.'";

-- pig: say "'No. Not tonight.'".

A conversation rule for Bud when the noun is a person and the noun is not the raven:

if the noun is:

-- the cat: say "'What do you know about the cat over there?' [pb]Bud shrugs. 'Don't know her. Haven't talked to her.'";

-- the dog: say "'Do you know the guy in the dog mask?' you say. [pb]'He drinks beer. That's all I know. That's all I need to know.'";

-- the fly: say "'Do a good business with the fly, it looks like,' you say. [pb]'I always do a good business. I know my business good, too.'";

-- the pig: say "'Do you know the pig?' you say. [pb]'He doesn't drink. At least not yet. That's all you need to know.'";

-- the rat: say "'Nice to see your waitress getting into the act,' you say. 'With the mask.' [pb]Bud looks surprised. 'Waitress? Oh yeah. Good lass.'";

-- the swan: say "'What do you think of the mask?' you say. [pb]Bud shrugs. 'Better than some of them.'".

A conversation rule for Bud when the noun is the raven:

say "'Can you tell me anything about the raven?' you say. [pb]Bud stares at you. 'Nope.'";

now investigating raven is true.

A conversation rule for Bud:

if the noun is a furnishing begin;

say "'Nice decor,' you say. [pb]Bud shrugs. 'It's me.'";

otherwise;

say "You don't think Bud knows much about things outside his domain.";

rule fails;

end if.

A conversation rule for cat when the noun is an NPC person:

if the noun is:

-- Bud: say "'Do you know anything about Bud that I should know?' you say. [pb]The cat shrugs. 'I haven't talked to him. I'm sure he's a nice enough fellow.'";

-- cat: say "'What can you tell me about yourself,' you say. [pb]'Oh, don't bother with me. I'm not that interesting.'";

-- dog: say "'Is that your husband?' you say, indicating the dog sitting next to her. [pb]'Yes. For 48 years.' She smiles. ";

-- fly: say "'Have you met the fly?' you say. [pb]'Poor dear. Drinks a little too much, I think.'";

-- pig: say "'Do you know who the pig is?' you say. [pb]'Oh my dear, I don't think any of us know, and I don't think any of us want to.'";

-- rat: say "'Have you met our waitress?' you say. [pb]'Delightful girl. Too bad they made her wear that ugly thing.'".

A conversation rule for cat when the noun is swan:

say "'I'd introduce myself but, you know, secrecy and all that,' you say. [pb]'Oh, that's okay, dear. All hush-hush.'".

A conversation rule for cat when the noun is raven:

add conversationalist to ask-order;

now investigating raven is true;

say "'I'm trying to learn more about the raven,' you say. 'He seems ... interesting.' [pb]'Oh, dear. We aren't supposed to know, you know. All I know is that a birdy mask means he's someone important. Not like us domestic animals.' She nudges the dog beside her and smiles.".

A conversation rule for cat:

if the noun is a furnishing begin;

say "'Do you like what Bud has done with the place?' you say. [pb]'I guess it's okay for a bar. I wouldn't know.'";

otherwise;

say "You don't want to bother the lady with irrelevant chat.";

rule fails;

end if.

A conversation rule for dog when the cat is crying:

say "The dog's head droops as he pats the cat's shoulder. You would rather leave them alone and let him try to calm his wife.";

rule fails.

A conversation rule for dog when the noun is an NPC person:

if the noun is:

-- Bud: say "'How well do you know Bud?' you say. [pb]'Enough to know why this place is the [']Bore Bar.[']'";

-- cat: say "'[unless the cat has spoken of the dog]Is this your wife[otherwise]Your wife is a sweetheart[end if],' you say. [pb] 'Yes, as gentle as a kitten.' The dog chuckles.[if the cat is crying] 'And maybe a bit too sensitive.'[end if] ";

-- dog: say "'I'd normally introduce myself but ... ' you say. [pb]The dog laughs. 'Of course. As would I, under different circumstances.'";

-- fly: say "'Do you know our red-eyed friend?' you say. [pb]'Don't know him myself. But he seems interested in you, I think.' ";

-- pig: say "'Do you know the pig?' you say. [pb]'If I did, I wouldn't tell you. Knowing him as I do.'";

-- rat: say "'Have you met our waitress?' you say. [pb]'She'll be getting a big bonus tonight, to be sure. Putting up with this lot.'".

A conversation rule for dog when the noun is swan:

say "'Do you think my mask has any significance?' you say. [pb]'I think all of ours do. A ranking, I think.'".

A conversation rule for dog when the noun is raven:

now the cat is crying;

now investigating raven is true;

say "'Do you know anything about the raven?' you say. [pb]'If I told you, I'd have to kill you.' The dog chuckles. 'Seriously, no. I hope he isn't anything like the real thing, though. Crows are smart. They're also mean bastards. Turn on you in a snap. You feed them, they hang around, then one day you don't. So they kill your dog.' He bangs the table with his hand. [pb]The cat bursts into tears. She pulls a tissue from her purse and grips it, sobbing. [pb]'So sorry, sweetie,' the dog says. 'Our dog ... ' He shakes his head. [pb]'That's okay,' you say. 'I'll leave her alone.'";

add conversationalist to ask-order.

A conversation rule for dog:

if the noun is a furnishing begin;

say "'How do you like this place?' you say. [pb]'A little spartan for my tastes.'";

otherwise;

say "You don't want to intrude on the couple more than you need to.";

rule fails;

end if.

A conversation rule for the fly when noun is a person and noun is not the swan:

let sober level be the drunkenness of the fly;

if sober level is less than 6 begin;

say "'[if the noun is listed in the sober talk list]Can you tell me more about [the noun]?' you say. 'I'm curious.'[otherwise]Do you know [the noun]?' you say. [end if] [pb]";

if noun is listed in sober talk list begin;

say "[if sober level is less than 3]The fly steps back and shakes his head. [otherwise]The fly teeters a bit and ignores you[end if].";

otherwise;

say "[if sober level is less than 3]'Loose lips sink ships, and Captain Fly is sailing steady.'[otherwise]The fly shakes his head an puts a finger to his lips. 'These lips are sealed.' He sips from his drink.[end if]";

add noun to sober talk list, if absent;

end if;

rule fails;

end if;

if the noun is the raven begin;

now investigating raven is true;

say "'The raven,' you say. '[if fly is listed in sober talk list]Come on, you can tell me, right[otherwise]Know him[end if]?' [pb]The fly drains his drink. 'He's big. Really big. Has his fingers in a lot of pies. Not just good old American apple pie, either.' [pb]'Do you know his name?' [pb]The fly stands perfectly still. He shakes his head. 'Perhaps I've stead, said, too much, too much.' He turns to the rat and yells, 'Another drink. Let's try Bud's [Raven's drink].' [pb]The rat scowls and orders the drink from Bud.";

add conversationalist to ask-order;

otherwise;

say "'[if the noun is Bud]Know Bud well, do you?' you say. [pb]The fly nods, the eyes bobbling. 'Yeah, we're great mates. Good guy[otherwise if the noun is cat]Have you met the cat?' you say. [pb]He shrugs. 'Never met her. I think. It's hard to tell. You know, with the masks[otherwise if the noun is dog]What's your take on the dog over there?' you say. [pb]The fly swivels his head to the dog. 'Good man. Likes beer. I like my drinks stiffer[otherwise if the noun is fly]So why did you end up with the bug eyes?' you say. [pb]'I guess [']cause I see all from above, that's my gig[otherwise if the noun is rat]I'm sure you're familiar with our waitress,' you say. 'The rat.' [pb]'A right good wench she is,' the fly says and raises his drink at her. [pb]The rat frowns and shakes her head. 'Pig[end if].'";

end if.

A conversation rule for fly when the noun is swan:

say "'Take a picture, it lasts longer,' you say. [pb]'What,' the fly says. [pb]'You've been watching me all night.' [pb]'He smiles. 'I watch everyone.'".

A conversation rule for fly:

if the noun is a furnishing begin;

say "'Come here a lot, do you?' you say and cringe at the implication. 'I mean ... ' [pb]The fly shakes his head. 'Here.

There..' He holds up his drink. 'It taste the same anywhere, really.'";

otherwise;

say "You don't want to talk to the fly more than you need to.";

rule fails;

end if.

A conversation rule for pig when the noun is an NPC person:

say "You look up at the pig. 'Can I ask you about [if noun is the conversationalist]yourself[otherwise][the noun][end if]?' [pb][if noun is Bud]The pig shrugs. 'A bit bristly, and he isn't the one with the whiskers in this place.' [otherwise if (pig has spoken of cat or pig has spoken of dog or pig has spoken of pig or pig has spoken of rat or pig has spoken of fly)]'No.' [otherwise]'We're wearing masks for a reason. You should know that.' [end if]".

A conversation rule for pig when the noun is swan:

say "'Do you know anything about me?' you say. [pb]'I know what I need to about who I need to know.'".

A conversation rule for pig when the noun is raven:

add conversationalist to ask-order;

now investigating raven is true;

say "[if (pig has spoken of cat or pig has spoken of dog or pig has spoken of fly or pig has spoken of rat)]'So I guess you won't tell me now about the raven?' [otherwise]'Can you tell me about the raven?' [end if]you say. [pb]The pig snorts. 'The raven? You dare ask?' [pb]'Well, I just did ... ' [pb]He clenches his fists. 'I can keep my mouth shut. Not like them.' He gestures at the other people in the bar. 'I told him they can't keep secrets. Everyone talks eventually. You just gotta know when to ask. I oughtta know.' He thumps his chest. 'And he should know about you.' He points at you, charges out the door, and stomps down the stairs.";

now the pig is off-stage.

A conversation rule for pig:

if the noun is a furnishing begin;

say "'Why don't you come in and have a seat?' you say. [pb]'I'm just fine where I am, Missy.' ";

otherwise;

say "The pig is too tight-lipped to talk about anything, never mind something like [regarding the noun][those].";

rule fails;

end if.

A conversation rule for rat when the noun is an NPC person:

if the noun is Bud begin;

say "'Do you know Bud well?' you say. [pb]'Yeah, sure.' The rat winks. 'Just don't ask me anything about him.'";

otherwise;

if the noun is the rat begin;

say "'Anything about you I should know?' you say. [pb]The rat smiles. 'Me? I'm not hiding anything, hon.'";

otherwise;

say "'What can you tell me about [the noun]?' you say. [pb]'[one of]Well, I'm not one to talk, but ... ' The rat looks around then leans toward you. '[or]Hmmmm. [stopping][if the noun is the cat]Their dog died, and she had it stuffed. It sits in its own chair[otherwise if the noun is the dog]I wouldn't be surprised if he had a little accident on the way out of here tonight. Seems he has a lot of those. I hope Bud has insurance[otherwise if the noun is fly]Three girlfriends, one wife, three kids. His wife doesn't know about one of them[otherwise if the noun is the pig]He's a detective, you know. He's good. A little too good, if you know what I mean. He always gets his man, even if he didn't do it[end if].'";

end if;

end if.

A conversation rule for rat when the noun is swan:

say "'Got any dirt on me?' you say. [pb]The rat's eyes widen. 'You, hon? No, of course not.' She nods at your black hair. 'So the blond hair is a dye job. Knew it.'".

A conversation rule for rat when the noun is raven:

if fly is listed in ask-order begin;

add conversationalist to ask-order;

say "'You must be able to tell me something about the raven,' you say. [pb]The rat considers. 'All I can tell you is that he likes the same drink as the fly. [Raven's drink].'";

otherwise;

say "'[one of]I'd really like to know more about the raven.'[or]Anything about the raven?'[stopping] you say. [pb]'[one of]I can't think of anything, hon. Maybe something will jog my memory[or]Nothin['] yet, hon. Sorry[stopping].' [lb]";

rule fails;

end if.

A conversation rule for rat:

if the noun is a furnishing begin;

say "'A little dark in here, but otherwise I like it,' you say. 'Simple.' [pb]'That's Bud for you. I think.'";

otherwise;

say "Anything she has to say about [regarding the noun][those] would just be white noise right now.' [lb]";

rule fails;

end if.

Chapter - Task Two Action-Processing Rules

First before doing something other than gazing when player is yourself and (location is Boar Bar or location is the Chamber) and every involved thing is enclosed by the location:

if clicking a conspirator and player is yourself, try biographing for the noun instead;

unless showing attributes for or showing room attributes for, say "You cannot do anything to influence the game state unless you are controlling a PC. Use HEADPOP INTO [bracket]a PC[close bracket] to take control of an inactive PC. COMMANDS shows a list of the testing commands." instead.

Before asking Bud to try taking an alcoholic drink, try taking the noun instead.

Before asking someone to try taking an alcoholic drink, try discussing the noun with the actor instead.

Before answering someone that "hi/hello/greetings" when engaged in Task Two, try discussing the raven with the noun instead.

Before changing channels when location is Boar Bar, say "The snear Bud gives you tells you it's his tv and his bar. His choice." instead.

Before conversing when the second noun is crying cat, say "You're not going to get anything out of her while she is mourning." instead.

Before discussing a mask with someone, try discussing a random person who incorporates the noun with the second noun instead.

Before discussing the raven with the rat when the number of entries in ask-order is less than 4 and the pig is off-stage for the first time, now investigating raven is true.

Before discussing an alcoholic drink with Bud, try taking the noun instead.

Before discussing an alcoholic drink with the rat, try taking the noun instead.

[We never want to print the "give the fly a drink" phrase when we do something with the fly.]

Before doing something other than showing attributes for when the fly is involved and not discussing the fly with someone who is not the fly, now the player is raven-asking.

Before doing something when the raven is involved and engaged in Task Two:

if conversing and the second noun is not the raven, continue the action;

say "He isn't around." instead.

Before doing something other than showing attributes for when the alcohol is involved, say "In a bar, referring to a drink in general is too ambiguous." instead.

Before drinking a not carried alcoholic drink, try taking the noun.

Before eating an alcoholic drink, try drinking the noun instead.

Before examining a mask, try examining a random person who wears the noun instead.

Before examining the invitation, say "You pull the card from your pocket. [rpo]".

Before giving an alcoholic drink to the player, try taking the noun instead.

Before listening when player is the swan, try listening to Bud's tv instead.

The can't remove from people rule does nothing.

Before smelling when engaged in Task Two, try examining the cologne instead.

Before smelling the cologne, try examining the noun instead.

Investigative technique is a stored action that varies.

Setting action variables for doing something other than talking to something when engaged in Task Two:

now investigative technique is the action of waiting.

Before talking to someone when engaged in Task Two:

if the noun is the crying cat, try discussing the noun with the cat instead;

if investigative technique is the action of waiting or (noun part of investigative technique is not noun), try discussing the raven with the noun instead;

now investigative technique is the current action;

repeat with selection running through npc persons begin;

unless the noun has spoken of selection, try discussing selection with the noun instead;

end repeat;

unless the noun has spoken of the swan, try discussing the swan with the noun instead;

say "You [if the noun is a person]can't think of anything to say right now[otherwise]don't want to appear any crazier than anyone else here[end if]." instead.

Before taking the invitation, say "It's easiest to carry in your pocket." instead.

Before taking the pocket, say "It's firmly sewn to your jeans." instead.

Before waiting, unless engaged in Task Two, try looking instead.

Instead of acting like bunny when engaged in Task Two, say "You're not dressed like a rabbit.".

Instead of activating something when engaged in Task Two and player is the swan, say "There is nothing to activate around here.".

Instead of asking someone to try doing something when engaged in Task Two, say "You can't tell anyone in here what to do. Not yet, anyway. After tonight, maybe.".

Instead of decommissioning something when engaged in Task Two and player is the swan, say "You wouldn't dare turn off anything without Bud's permission.".

Instead of discussing something with the fly when drunkenness of the fly is greater than 14 and engaged in Task Two, say "'So, what ... ' you say. [pb]'[one of]Wha's a chick li['] ya doin[']'[or]Tha's what I'm sayin[']'[or]The fly sways and smiles[or]He licks his lips, and you don't want to finish your thought[or]'Score!'[purely at random] [lb]".

Investigating raven is initially false.

Instead of discussing something with an npc person when engaged in Task Two:

now the conversationalist is the second noun;

follow the conversation rules for the conversationalist;

if rule succeeded, add the noun to the things spoken about of the conversationalist, if absent;

if investigating raven is true begin;

unless the conversationalist is the fly begin;

say lb;

give the fly a drink;

end unless;

if the conversationalist is the fly, increment the drunkenness of the fly;

now player is raven-asking;

end if.

To give the fly a drink:

increment the drunkenness of the fly;

unless the player is raven-asking begin;

unless the number of entries in ask-order is 5, say "You turn to see the fly retreat [if the drunkenness of the fly is greater than 8]in a few stumbling[otherwise]a few[end if] steps. ";

say "Swaying, [if the number of entries in ask-order is 5]the fly [otherwise]he[end if] ";

say "takes a swig of his drink[first time]. He seems to be hovering around you like a fly on ... let's say flypaper[only].";

end unless.

Instead of doing something other than examining to the cologne, say "You can smell it. That's enough.".

Instead of drinking a not carried alcoholic drink, say "You'll need to order one first.".

Instead of drinking a carried alcoholic drink:

decrement sippiness of the noun;

say "[if sippiness of noun is 0]You finish the drink and return the glass to Bud[otherwise]You sip the [noun].";

if sippiness of noun is 0 begin;

move the noun to location;

now sippiness of the noun is 5;

end if.

Instead of dropping a carried alcoholic drink, say "You don't want to leave your drink unattended.".

Instead of dropping or taking or taking off the swan's mask, say "You're wearing a mask for a reason. Besides, you like it.".

Instead of dropping or taking or taking off a mask, say "You wouldn't dare.".

Instead of entering something which is not a person when engaged in Task Two and the noun is not a furnishing, say "Not possible, you're sure.".

Instead of entering someone who is not the player when engaged in Task Two, say "That would be awkward.".

Instead of entering a furnishing when engaged in Task Two, say "You couldn't possibly sit on [regarding the noun][those].".

Instead of entering barstools when engaged in Task Two, say "You're a bit too anxious to sit right now.".

Instead of entering the player when engaged in Task Two, say "You're too tall to be a gymnast.".

Instead of examining a carried alcoholic drink, say "Just one of your favorites.".

Instead of switching on or switching off a device when location is Office during Task Two, say "You don't want to bother with that right now.".

Instead of talking about text with someone who is not the player during Task Two:

if the second noun is:

-- Bud: say "Bud shakes his head. 'Can't hear you.' [pb]That's odd; he seems able to take drink orders from his waitress just fine. ";

-- the cat: say "The cat pats your hand. 'No business of mine, my dear.' ";

-- the dog: say "The dog looks around. 'I may have said too much to too many already.'";

-- the fly: say "'I'm not sure what you're getting at,' the fly says. ";

-- the pig: say "'I won't discuss anything with you,' the pig says. ";

-- the rat: say "'I do stay quiet about some things, despite what you might have heard,' the rat says. ";

say lb.

Instead of giving Raven's drink to the fly when the fly is listed in ask-order, say "He's had enough.".

Instead of giving an alcoholic drink to the fly when the fly is listed in ask-order, say "You don't want to encourage him to expand his tastes.".

Instead of giving an alcoholic drink to the dog:

if the noun is the beer begin;

say "There's plenty remaining in his mug.";

otherwise;

say "It looks like he prefers beer, and he isn't finished with what he has.";

end if.

Instead of giving an alcoholic drink to someone, say "You don't know what [the second noun] drinks.".

Instead of giving the invitation to someone, say "It's yours. You don't know who else should be invited.".

Instead of going up from Boar Bar, try going east.

Instead of going east from Boar Bar, say "*** [username of yourself] (as the swan) cannot leave Caledonian Boar Bar while PC is waiting for another PC. *** [lb]".

Instead of going down from Boar Bar, say "Solid floor.".

Instead of going nowhere from Boar Bar, say "That would run you into a wall.".

Instead of inserting something into the pocket, say "It isn't big enough to carry much.".

Instead of listening to Bud's tv, say "A guy describes the play-by-play of the hockey game.".

Instead of listening to the player when the player is the swan, say "You'll have to speak to someone to hear your voice.".

Instead of listening to someone, say "You'll have to ask [the noun] something if you want to hear h[if noun is male]im[otherwise]er[end if].".

Instead of opening or closing the pocket, say "It's easily accessible as-is.".

Instead of removing an alcoholic drink from the fly, say "Taking away any alcohol from the fly might tick him off, and you don't know what he's capable of when he's angry.".

Instead of removing the beer from the dog, say "He looks like he's enjoying it too much.".

Instead of removing an alcoholic drink from someone, say "[The noun] isn't drinking.".

Instead of smelling the player, say "Perfect.".

Instead of smelling someone, say "You don't want to act too suspicious with these people.".

Instead of taking an alcoholic drink when 1 alcoholic drink is carried, say "One drink at a time is all you can handle.".

Instead of taking someone when engaged in Task Two, say "You're not taking anyone anywhere. You're waiting.".

Instead of taking something which is not an alcoholic drink when engaged in Task Two, say "Besides a drink, there's nothing else here you can carry. Except maybe a conversation.".

Instead of taking inventory when player is the swan and engaged in Task Two, say "You carry an invitation in your pocket, and you're wearing the swan mask.".

Instead of waiting when engaged in Task Two, say "The hockey game plays in the background as you wait.".

Instead of wearing a mask which is worn by the player when engaged in Task Two, say "It's firmly in place and already doing its job.".

Instead of wearing a mask when engaged in Task Two, say "That one isn't yours, and you're pretty sure they are coded for specific positions.".

Instead of wearing something which is not a mask when engaged in Task Two:

if the noun is a person, say "That would require some sort of skin grafting. Gross, and [the noun] would never sign the consent form.";

otherwise say "Clothing works just fine.".

After examining the invitation, say "You slip the card back into your pocket.".

After listening to something when engaged in Task Two, say "[regarding the noun][They] remain silent.".

After looking when location is Boar Bar for the first time:

say "The scent of the raven's cologne [pb]*** Warning: [username of yourself] does not recognize PC raven. *** [pb]lingers in the air. [pb]From [i]The Titan Handbook,[/i] ('Connecting with Players', pg. 50)[lb]All titans should recognize every thing in the game, including PCs. If you encounter an unrecognized PC, re-establish a connection by finding another name for the PC. This may be done using the testing commands RELATIONS and SHOWME [bracket]a thing[close bracket] . In some situations, you may also be able to find the name by assuming the role of a PC or NPC and interacting with the game world. HEADPOP [bracket]someone[close bracket] will put you into a character, and DEPOSSESS will take you out. Talking to other PCs and NPCs is usually a good way of identifying players. Use RECOGNIZE RAVEN as [bracket]someone[close bracket] with the name of the person you would like to re-connect. [pb]*** Remember, when you are finished assuming the role of a PC, you need to RESET your session so that the game state is restored to what it was before you took control. *** [lb]".

After taking an alcoholic drink:

add noun to favorite drinks of the swan, if absent;

say "Bud pours your request, [noun], and hands it to you.".

Section - Task Two Out-of-World Actions

Carry out showing relations when engaged in Task Two:

say "Boozing relates various people to various alcoholic drinks.";

say "The dog drinks beer.";

say "The fly drinks [favorite drinks of the fly].";

say "The rat drinks [favorite drinks of the rat].";

say "The swan drinks [favorite drinks of the swan].".

Chapter - Task Two Turn Sequence Rules

Every turn when investigating raven is true and engaged in Task Two:

now investigating raven is false.

Every turn when the number of entries in the ask-order is at least 3 and fly is not listed in ask-order and the drunkenness of the fly is less than 15 and engaged in Task Two:

if the number of entries in ask-order is at least 4, now the player is raven-asking;

give the fly a drink.

Acting attempts is initially 0.

Every turn when player has not been swan and engaged in Task Two:

increment acting attempts;

if six npc people are blocked from player and acting attempts is greater than 15 begin;

move Eve to location;

say "[b]*** Eve Martin has taken control of PC the swan. ***[/b] [pb]";

say ">l [lb] [description of location] [pb]";

let requested drink be a random alcoholic drink;

say ">ask Bud for [requested drink] [lb]Bud pours your request, [requested drink], and hands it to you. [pb]>drink [requested drink] [lb]You sip the [requested drink]. [pb]";

repeat with counter running from 1 to 4 begin;

say ">z [lb]The hockey game plays in the background as you wait. [pb]";

end repeat;

say "A hunched man in a vulture mask enters the bar. [pb]The vulture says (to the swan): Come with me. [pb]>e [lb]The swan follows the vulture east, out of the bar.";

report a premature ending;

end if.

Every turn when engaged in Task Two and (time since Task Two began is 60 minutes or waiting for 10 turns):

say "[description of location] [pb]The vulture enters the bar. [pb]The vulture shoots the swan with a blanker. [pb]You, Eve Martin as the swan, flicker and disappear. [pb]*** PC the swan has been removed from the game world. *** [lb]";

report a premature ending.

Last every turn when engaged in Task Two and the player is raven-asking:

now the player is not raven-asking.