gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for Gaia's Web

Volume - HarborMaster Tasks

Book - Task One

Chapter - Task One Players and Resources

Task One is a debugging scene. Task One begins when yourself is attending to problems. Task One ends when location is not Office.

When Task One begins:

now office-computer incorporates Eve Martin;

now office-computer incorporates Roger Thornhill.

Roadbound Roger is a scene. Roadbound Roger begins when Roger is roadbound. Roadbound Roger ends when Roger is gassed or Roger is forestbound.

Section - The Fugitives

Eve can be fleeing. Eve is fleeing.

Eve can be crashed by squirrel.

Understand "eve/martin", "eve martin", and "player/players" as Eve Martin when engaged in Task One.

Rule for printing the name of Eve when engaged in Task One:

say "[if Roger is identified]Sonja[otherwise]Eve[end if]".

The real name of Eve is "Sonja Kenyon". The DOB of Eve is "03/15/1988". The residence of Eve is "43 Thorogh St. Hamilton, On, Canada". The email of Eve is "fairydancer@sotfc.com".

The pic of Eve is "Picture of Sonja Kenyon: A young woman with short blond hair and green eyes. Her lips are full, her nose a small bulbous tip.".

The description of Eve is "[b]Username: [/b][if engaged in Task One][set link 11]Eve Martin[end link][otherwise][set link 18]Eve Martin[end link][end if] [lb][b]Real Name: [/b][real name of item described] (DOB: [dob of item described]) [lb][b]Address: [/b][residence of item described] [lb][b]S.hip e-mail: [/b] [email of item described] [pb][pic of item described]".

Eve's-phone is a device.

The printed name of Eve's-phone is "Eve's phone".

Understand "Eve's/martin's phone", "Eve's/martin's cell/mobile phone", and "electronic/game/gaming device" as Eve's-phone.

Roger Thornhill is a man. Roger has some text called real name. Roger has some text called DOB. Roger has some text called residence. Roger has some text called pic. Roger has some text called email.

The real name of Roger is "Grant Mason". The DOB of Roger is "11/7/90". The residence of Roger is "1112 Updike Dr. Toronto, On, Canada". The email of Roger is "thornroses@sotfc.com".

The pic of Roger is "Picture of Grant Mason: A man with black hair slicked back and almost touching his shoulders. His eyes are small and brown, his chin square."

Roger can be carbound, roadbound, gassed, or forestbound. Roger is carbound.

Roger can be identified or unidentified. Roger is unidentified.

Roger can be licence-tagged.

Roger can be fleeing. Roger is fleeing.

The description of Roger is "[b]Username: [/b][set link 10]Roger Thornhill[end link] [lb][b]Real Name: [/b][real name of item described] (DOB: [dob of item described]) [lb][b]Address: [/b] [residence of item described] [lb][b]S.hip e-mail: [/b] [email of item described] [pb][pic of item described]".

Rule for printing the name of Roger:

say "[if Roger is identified]Grant[otherwise]Roger[end if]".

Section - The Resources

Some things are defined by the Table of Task One Biological Resources.

Table of Task One Biological Resources

ResourceAffiliationDescriptionContact-textTravel Time
Chucky"gray squirrel, [i](Sciurus carolinensis[/i]""Like all animal operatives, squirrels are equipped with a microphone, which is useful for listening to conversations and the environment. Small animals like squirrels also have brain implants. Upon activation, the squirrel will seek out the target game device and remain in the vicinity until de-activation. Squirrels do not typically engage in physical contact with the players. However, the actions of animals are often unpredictable, as are the reactions of players upon encountering them."""15
Alicia Anderson"student""Alicia, 23 years old, has been a freelance field agent for 3 years. She is attractive, energetic, and personable. She travels by motorcycle.""Hey, Alicia,' you say. [pb]'Yeah, I gotcha[if Alicia has not been activated]. I'm on my bike, but I can be there in a jiff[end if]"4
Jason Williams"ecologist""Jason has been a freelance field agent for 5 years. Usually his dog, Diana, is with him, and the two are useful for both surveillance and interception, Diana being an effective way to attract human targets.""Hi, Jason,' you say. [if Jason is examined]'And Diana.'[end if] [pb]'We're here"2
Travis Watson"Ontario Provincial Police (OPP)""Travis, 32 years old, has been a versatile field agent for 10 years. He is most often used to impersonate police officers, for which he has formal training. Field agents are not employed by any police department, nor do they operate in any official capacity with the police. In some jurisdictions, field agents have been granted permission to impersonate police officers or detectives, including the use of uniforms and vehicles, under strict regulations.""Travis, you copy?' you say. [pb]'Loud and clear. Over"3
Samuel Walker"retired""Samuel, a 65-year-old former accountant, has been a freelance field agent for six years. He is willing to assume many roles, and his versatility means he is comfortable with surveillance, reconnaissance, and physical confrontation. His wife, Roberta, is also often available, and the two of them frequently collaborate.""Sam, you there?' you say. [pb]'We both are[if Roger is carbound][first time]. Me and Ma are just passing through, but we might be able to help[only][end if]"3

Chucky is an animalistic resource.

Alicia, Jason, Travis, and Samuel are human resources.

Understand "gray/grey squirrel", "squirrel", "Sciurus", and "Sciurus carolinensis" as Chucky.

Chucky can be distracting the dog.

A human resource has a list of actionable dialogues called action options.

Alicia is female.

Alicia has a number called time to car. The time to car of Alicia is 4.

alicia has a number called time to runners. The time to runners of Alicia is 5.

Understand "girl/lady/woman" and "hitchhiker/motorcyclist/student" as Alicia.

Jason is male.

Jason can be successful with Diana.

Understand "bloodhound/Diana", "ecologist/scientist", and "man/guy" as Jason.

Travis is male.

Travis has a number called time to car. Time to car of Travis is 4.

Travis has a number called time to runners. Time to runners of Travis is 5.

Understand "cop/detective/police", "guy/man", "police officer", and "opp" as Travis.

Samuel is male.

Understand "accountant/couple/retiree", "man/pa/sam", "roberta/ma", "Roberta Walker", and "walkers" as Samuel.

Some mechanical resources are defined by the Table of Task One Mechanical Resources.

Table of Task One Mechanical Resources

ResourceAffiliationDescriptionTravel Time
DONCAN-132"drone[if travel time of DONCAN-132 is greater than 13] Peterborough, ON (police station)[end if]""DONCAN-132 is a medium-sized drone equipped with a camera and designed to deliver packages. Because of its size, its maneuverability is limited, and it can't navigate tight spaces (e.g., building interiors, wooded areas). It is also able to disperse chemical reagents. It is carrying SynSleep, an anesthetic gas that causes loss of consciousness for about 10 minutes. DEPLOY GAS will release the drone's cargo."11

Understand "chopper/helicopter" and "drone/doncan" as DONCAN-132.

Should the game choose doing something with DONCAN-132:

if Task One is happening and HarborMaster is not no-screen, it is a good choice;

never.

Rule for printing the name of a resourceful thing (called agent) while constructing the status line:

say "[if agent is Alicia]Alicia[otherwise if agent is Jason]Jason[otherwise if agent is Travis]Travis[otherwise if agent is Samuel]Samuel[otherwise][printed name of agent][end if]".

DONCAN-132 incorporates the anesthetic gas.

The anesthetic gas can be deployed.

Understand "anesthesia/drug/sedative" and "synsleep" as the anesthetic gas.

Chapter - Task One Suggesting Options

Before suggesting options for someone:

say "'".

Rule for suggesting options for Alicia:

if Roger is carbound, say "They're heading my way, so I think I can try to get them to pick me up. There's a guy in that car, right? I can work with that. Once I'm in there, I may be able to get the phone, and we won't lose them. Whatever you think";

if Roger is gassed, say "They're down and out. It should be pretty easy for me to swipe their phone and hook you up";

if Roger is roadbound, say "I can follow them and wait for an opportunity[unless hitchhike is accomplished]. They haven't seen me, so maybe I can orchestrate a little run-in with them. A helpless girl in trouble, perhaps[end unless]. I'll have to hurry, though. I may not be able to find them if they decide to hide in the trees. But they need to come out eventually, right? I could just wait by their car. Up to you";

if Roger is forestbound, say "That's some pretty dense forest there, chief. I can try to follow them, or I can just wait by their car. I'm betting they'll be out eventually[unless hitchhike is accomplished]. I might have a better chance of running into them there[end unless]".

Rule for suggesting options for Jason:

say "[if sniff-out is accomplished]I don't see anyone out here, so we could give Diana another chance[otherwise]I have Diana with me. She's old, but she still has a little left in the sniffer. She could track them down. Lots of smells out here, though. I hope she doesn't lead us astray[end if]".

Rule for suggesting options for Travis:

if Roger is carbound, say "I have two options. I can set up a roadblock ahead of them and hope they don't just turn around, or I can pull them over. Either way, I should be able to get her to hand over the phone and get some cam shots so we can verify their identity. Over";

if Roger is roadbound, say "I can track them for now, before they hit those trees. Once they're in there, though, who knows?[if pull-over is accomplished or roadblock is accomplished] I won't be able to engage them, though, since they've already seen me. [end if]I can also watch their car. Wait for them to come back. Over";

if Roger is gassed, say "I suppose they won't be getting up anytime soon. I can get their quick, connect you with the phone. Over";

if Roger is forestbound, say "I can try to follow them in the trees, but if they know we're onto them, I think they can lose us rather easily. Or get the drop on us. Maybe I should just wait out here by their car[unless roadblock is accomplished or pull-over is accomplished]. A cop inspecting a car at the side of the road isn't too suspicious[end unless]. Over".

Rule for suggesting options for Samuel:

if Roger is carbound, say "I can stop ahead of them and pretend to have car trouble,' Sam says. 'If she is decent folk, she'll stop and help. Between the two of us, we'll try to get that phone.' [pb]'Screw that, Pa,' Roberta says. 'You want them stopped? Ram [']em! Hit them in the kiester. Then send in the troops".

After suggesting options for someone:

say ".' [lb]".

Chapter - Resource Conversations

attend car, establish connection, hitchhike, roadblock, pull-over, ram, roadside assistance, thought-processing, trail, and sniff-out are relevant actionable dialogues.

The action options of Alicia is {attend car, establish connection, Hitchhike, trail}.

The action options of Travis is {attend car, establish connection, pull-over, trail, roadblock}.

The action options of Samuel is {ram, roadside assistance}.

The action options of Jason is {sniff-out}.

Rule for offering an action of hitchhike when conversationalist is Alicia:

if Alicia is standby, say "I like the idea of getting someone in the car, and I think you have a good chance at getting that phone. Go ahead and try hitchhiking";

if Alicia is activated, say "[first time]There might be a better approach than putting you in the car with them. [only]Don't try hitchhiking just yet";

if Alicia is deactivated, say "[first time]Maybe I was right. [only]Try hitchhiking again".

Rule for offering an action of establish connection when the conversationalist is Alicia:

if Alicia is standby, say "I think you're in the clear. Go for the phone and hook me up";

if Alicia is activated, say "Hold off on the phone for a sec[if Travis is actively enacting establish connection]. I have Travis on it[end if]";

if Alicia is deactivated, say "Okay, go for the phone".

Rule for offering an action of attend car when the conversationalist is Alicia:

if Alicia is standby, say "[if Roger is roadbound]We'll try to catch them if they return. Find the car and stay with it[otherwise]I think we have a better chance at them when they're with the car. Keep an eye on it for me[end if]";

if Alicia is activated begin;

if Alicia enacts attend car, say "Shut off your cam, Alicia. [one of]We'll catch them when they come out[or]Take a break[stopping]. [if Travis is actively enacting attend car]Travis is watching the car for us[otherwise]I'll let you know if we need to monitor their car[end if]";

if Alicia enacts trail, say "[if Roger is roadbound][one of]Let's be more proactive and follow as close as we can. Maybe we won't lose them[or]Follow them, Alicia[stopping][otherwise][first time]We need to get a visual on them. [only]I'm sure you can find your way through a few trees[end if]";

end if;

if Alicia is deactivated, say "Power up, Alicia. [one of]Let's stay alert and w[or]W[stopping]atch that car".

Rule for offering an action of trail when conversationalist is Alicia:

if Alicia is standby, say "Time might be a factor here. Go ahead and follow them";

if Alicia is actively enacting attend car, say "[if Roger is roadbound][one of]Let's be more proactive and follow as close as we can. Maybe we won't lose them if we do[or]I want you on their trail instead[stopping][otherwise][one of]We need to get a visual on them. I'm sure you can find your way through a few trees[or]Try to find them in those trees[stopping][end if]";

if Alicia is actively enacting trail, say "Hold up. I don't want you getting too close to them just yet[if Travis is actively enacting trail]. Travis is on it[first time]. Let's see how he does[only][end if]";

if Alicia is deactivated, say "Okay, pick up their trail again".

Rule for offering an action of attend car when the conversationalist is Travis:

if Travis is standby, say "[if Roger is roadbound]Stick with the car, Travis. They'll likely be back[otherwise]I really don't think they'd just leave the car there. Keep an eye on it[end if]";

if Travis is actively enacting trail, say "Head back to the car[first time] instead[only]";

if Travis is actively enacting attend car, say "Power down. [if Alicia is actively enacting attend car]Alicia is on it [end if][first time]. I don't know how long they'll be in there, or if they're coming out where you are[only]";

if Travis is deactivated, say "I don't want to miss anything[first time]. You're back on duty. [only]Let's stay with their car".

Rule for offering an action of establish connection when the conversationalist is Travis:

if Travis is standby, say "Find Eve's phone and activate it";

if Travis is activated, say "Just hold up. [if Alicia is actively enacting establish connection]I put Alicia on it[otherwise]I may want you to just keep watch[end if]";

if Travis is deactivated, say "Go ahead and get me hooked up".

Rule for offering an action of trail when conversationalist is Travis:

if Travis is standby, say "[if Roger is roadbound]Try to follow them, and we'll wait for an opportunity to strike[otherwise]Search the trees for them, Travis. Maybe we can set something up in there[end if]";

if Travis is actively enacting attend car, say "Forget the car. Go find them";

if Travis is actively enacting trail begin;

if Roger is roadbound, say "[first time]We should hold back. We don't want to scare them too much. [only]Hold your position[if Alicia is actively enacting trail]. Alicia is on it[end if]";

if Roger is forestbound, say "Hang back[if Alicia is actively enacting trail]. Let's see what Alicia finds[end if][first time]. Maybe you'll hear something[only]";

end if;

if Travis is deactivated, say "[if Roger is roadbound][first time]I need your perspective on this. [only]Go ahead and follow them[otherwise][first time]We can't let them go. [only]Find out where they're headed, if you can[end if]".

Rule for offering an action of roadblock when conversationalist is Travis:

if Travis is standby, say "Stopping the car may be a good idea. And if you can get them out of it, even better. Go ahead and set up that roadblock";

if Travis is actively enacting roadblock, say "[first time]I'm not convinced the roadblock will work. [only]Hold off on [one of]it[or]the roadblock[stopping] for now";

if Travis is actively enacting pull-over, say "[first time]I don't want to risk a chase and losing them. [only]Let's block their escape instead";

if Travis is deactivated, say "Let's get that roadblock up[first time]. It may be our best approach after all[only]".

Rule for offering an action of pull-over when conversationalist is Travis:

if Travis is standby, say "Yeah, try pulling them over. We should at least be able to identify them if they stop";

if Travis is actively enacting pull-over, say "[first time]I'm thinking I don't want to risk a high-speed chase. [only]Hold your position[if Alicia is actively enacting hitchhike]. Alicia is trying something[end if]";

if Travis is actively enacting roadblock, say "[first time]I want you to get as close as you can. [only]Try to pull them over instead";

if Travis is deactivated, say "[first time]I don't think they'll run. [only]Go ahead and try to pull them over".

Rule for offering an action of roadside assistance when conversationalist is Samuel:

if Samuel is standby, say "All right. We'll go with Sam's idea. Maybe they'll stop for a couple having car trouble";

if Samuel is actively enacting roadside assistance, say "[if Alicia is actively enacting hitchhike or Travis is actively enacting pull-over]I put someone else on it, Sam, so just keep driving for now[otherwise]I may have a better idea, Sam, so don't pull over just yet[end if]";

if Samuel is actively enacting ram, say "[one of]Let's go with the less risky approach and fake car trouble[or]Try to get them to stop and help you instead[stopping]";

if Samuel is deactivated, say "[if 1 actionable dialogue is chosen]We can try a couple of strategies, so go ahead with that car trouble[otherwise][first time]You may have had it right, Sam. [only]Go ahead and fake the car trouble[end if]".

Rule for offering an action of ram when conversationalist is Samuel:

if Samuel is standby, say "I like Roberta's idea. Try to run them off the road. That'll probably get them out of the car";

if Samuel is actively enacting roadside assistance, say "[one of]Maybe Roberta had the best idea, so g[or]G[stopping]o ahead and try to run them off the road";

if Samuel is actively enacting ram, say "[one of]I'm not going to risk injury, so just hold back for now[or]Stay on their trail but don't engage for now[stopping]";

if Samuel is deactivated, say "[if Samuel enacts roadside assistance][first time]Maybe some force is needed. [only]Run them off the road, Sam[otherwise][first time]Let's stick with Roberta's idea. [only]Give them a bump, Sam[end if]".

Rule for offering an action of sniff-out when conversationalist is Jason:

if Jason is standby, say "Put Diana on it. Let's see where she leads us";

if Jason is activated, say "[if Alicia is actively enacting trail or Travis is actively enacting trail][one of]We'll try human trackers for now. I don't know how they'll react to a dog[or]We'll put a hold on canine tracking for now[stopping][otherwise][one of]Keep a leash on Diana for now. Maybe human contact would be safer[or]Hold Diana back for now[stopping] [end if]";

if Jason is deactivated, say "[if Chucky has been distracting the dog]Let's try Diana again[first time]. Let her sniff them out[only][otherwise][first time]I trust Diana. [only]Let [one of]her[or]Diana[stopping] find the trail[end if]".

Chapter - Task One Operation Rules

An operation rule for Alicia when Roger is carbound:

say "Alicia parks her motorcycle behind some trees and places her helmet upon it. She makes her way to the roadside. The Toyota appears. Alicia thrusts out her arm, thumb up. The car passes by. [pb]";

say "[if Travis is ready to act and pull-over is chosen]An OPP cruiser jiggles in the shot as it passes. Travis waves.[otherwise if Samuel is ready to act and ram is chosen][pb]A [Buick] approaches, and it jiggles in the shot. A woman waves from the passenger side.[end if] ";

if (Travis is ready to act and pull-over is chosen) or (Samuel is ready to act and ram is chosen), say "[pb]From Alicia's bodycam: ";

say "Alicia rushes back to her motorcycle and switches off her camera.";

if Roger is not licence-tagged begin;

say "[lb]From Alicia's cell phone: At least I got the plate, huh? I'm sending you the number now.";

Roger's licence is tagged in 0 turns from now;

end if;

now travel time of Alicia is 3;

now Alicia is standby.

An operation rule for Alicia when Roger is roadbound:

if Alicia enacts trail, say "Across the road, [Roger] and [Eve] walk toward the trees.";

if Alicia enacts attend car begin;

say "Alicia takes a position from behind the car, which is [if roadblock is accomplished]parked at the side of the road[otherwise]abandoned in a ditch[end if].";

if Roger is not licence-tagged, Roger's licence is tagged in 0 turns from now;

end if;

now Alicia is on-site.

An operation rule for Alicia when Roger is gassed:

say "[Roger] and [Eve] lie beside one another just short of some maple trees. Alicia picks up the phone from beside [Eve]. Fingers fly over the phone's screen. Alicia places the phone back onto the ground. [pb]From Alicia's cell phone: Done. You should be connected anytime now.";

rule fails.

An operation rule for Alicia when Roger is forestbound:

say "Alicia threads her way through maple trees[first time]. [pb]From Alicia's cell phone: As you can see, I'm still looking. They should be around here somewhere. I'll be in touch if I find them[only]. [pb]Alicia's bodycam shuts off.";

now Alicia is on-site.

An operation rule for Travis when Roger is carbound and Travis enacts pull-over:

say "Travis exits his cruiser and approaches the Toyota. As he sidles up to the driver's door, [Roger] looks up, smiles, and lowers his window. [Eve] sits in the passenger seat, hands empty. [pb]Travis steps away from the door, and the couple exit the car. Travis ushers them to the side of the road. He opens the passenger door. No phone on the seats or in the footwells. [pb]Travis closes the door and turns to the couple. [Eve] shakes her head and grips her purse. [Roger] speaks, and Travis allows the pair to get back into their car before returning to his own[if Samuel is ready to act and Samuel enacts ram]. Just before the camera goes black, a [Buick] passes by, and [Roberta] waves[end if]. [pb]From Travis['] cell phone: I couldn't justify a search, so I had to let them go. I got some good headshots, though. I'll send you the facial recognition and license number results. Over. [pb]'Thanks, Travis,' you say.";

if Roger is not licence-tagged, Roger's licence is tagged in 0 turns from now;

targets real names are revealed in 1 turn from now;

now travel time of Travis is 2;

now Travis is standby.

An operation rule for Travis when Roger is carbound and Travis enacts roadblock:

say "Travis stands outside in the middle of the road. He waits. The Toyota, still at a distance, slows and pulls over. Two people [mdash] a tall guy and a shorter woman [mdash] exit and head for the trees. [pb]From Travis['] cell phone: Looks like we scared them. I'll park to the side of the road. [pb]The camera goes black.";

now travel time of Travis is time to runners of Travis;

rule fails.

An operation rule for Travis when Roger is roadbound:

now Travis is on-site;

if Travis enacts trail, say "On the other side of a gravel road, [Roger] and [Eve] walk toward some large maple trees.";

if Travis enacts attend car begin;

say "Travis stands beside his car at the side of the road[if Eve is crashed by squirrel], the Toyota lying in a ditch[otherwise], the Toyota parked off-road nearby[end if].";

if Roger is not licence-tagged, Roger's licence is tagged in 0 turns from now;

end if.

An operation rule for Travis when Roger is gassed:

say "[Eve] lies on the ground next to [Roger], her cell phone at her side. [pb]Travis picks up the phone, which shows an interpreter open to [i]S.hip of Theseus.[/i] Travis taps at the phone. [pb]From Travis['] cell phone: You should be good now. Over. [pb]'Thanks, Travis,' you say. 'Good work.' [lb]";

rule fails.

An operation rule for Travis when Roger is forestbound:

say "Maple trees and bush. [first time][pb]From Travis['] cell phone: As you can see, they may be hard to find, especially if they don't want to be found. I'll be in touch if I find something. Over.[only][pb]The footage goes black.";

now Travis is on-site.

An operation rule for Samuel when Roger is carbound and Samuel enacts roadside assistance:

say "Sam is standing in front of his car with its hood raised. The phone swings around to catch the Toyota approaching. It drives by. [pb]'Told you we should've hit [']em,' Roberta says to Sam. To you, 'Sorry about that. You'd think after 46 years of marriage he would know enough to listen to me.' [pb]Sam shakes his head and says something before closing the hood. The feed goes black.";

now Samuel is standby;

now travel time of Samuel is 3.

An operation rule for Samuel when Samuel enacts ram:

say "The engine roars as Sam speeds at the Toyota and rams into its bumper. [pb]'Boom!' Roberta says. 'Good one, Pa.' [pb]The Toyota speeds up, but Sam hits it again, sending it careening into a ditch. [pb]'Suckers!' Roberta says as she passes the Toyota. 'We got them good.' [pb]Roberta swings her phone around to catch [Roger] and [Eve] leave their car. [pb]'Got the licence, too,' Roberta says. 'You're welcome.' She hangs up.";

if Roger is not licence-tagged, Roger's licence is tagged in 0 turns from now;

now travel time of Samuel is 3;

rule fails.

An operation rule for Jason:

if sniff-out was not accomplished, say "We've found the car, and Di is checking it out. She's got something. Boy, does she ever. We're following it. Hold on. [pb]Jason huffs, running.";

if Chucky is actively on-site begin;

say "[one of][lb]Whoa! She's after a squirrel. Get back here, Diana. Sorry. She's lost the scent. She is too interested in the squirrel[or]Sorry, no can do. Diana is still after that squirrel[stopping].";

now Jason enacts nothing;

now Jason is standby;

now Jason is on-site;

rule fails;

end if;

if sniff-out was not accomplished, say lb;

say "Okay, I think she has them. I'll see if I [mdash] [pb]Di! She just took off after them. Wait. Here she comes. What's that girl? Give it here. Hold on. [pb]Rustling. [pb]Okay. Diana grabbed a purse and brought it to me. Let's see ... cookies ... and a phone. I'll connect you then give the phone back. Gotta go, they're coming.";

now Jason is successful with Diana.

An operation rule for an activated resourceful thing (called agent) when the agent is not a human resource and Roger is carbound and ((Chucky is ready to act and DONCAN-132 is actively on-site) or (DONCAN-132 is ready to act and Chucky is actively on-site)):

say "From DONCAN-132: An aerial view shows the Toyota driving along a gravel road. Suddenly, Chucky lands on its hood. The squirrel claws across metal and leaps onto the car's windshield. [pb]The Toyota swerves off the road and into a ditch. Chucky is thrown off its hood. [pb][Roger] and [Eve] exit the car while Chucky watches them from the grass. [pb]From Chucky's microphone: [squirrel discussion] ";

say "[lb]From DONCAN-132: The couple rush toward the cover of the trees, [Eve] with a purse slung over her shoulder and a cell phone in hand. The drone dips lower and follows them from behind.";

now Eve is crashed by squirrel;

now Chucky is on-site;

now DONCAN-132 is on-site;

rule fails.

An operation rule for Chucky when Roger is carbound and DONCAN-132 is not on-site:

say "The sound of a car engine increases. A thud. Claws scrabble over metal. A loud bang. Silence. [pb][squirrel discussion] [lb]";

now Eve is crashed by squirrel.

To say squirrel discussion:

say "'What the hell was that?' Roger says[if DONCAN-132 is on-site] as he checks the hood of the car[end if]. [pb]'I think it was a squirrel,' [Eve] says. 'See over there? I think he's watching us.' [pb]'Now who's being paranoid? [if DONCAN-132 is on-site]I don't know about him, but that drone is going to be a problem. [end if]Let's go.'".

An operation rule for Chucky when Roger is roadbound:

say "'[if Chucky has been on-site][one of]Look, another squirrel,' [Eve] says. 'There seem to be an awful lot of them around. You sure one of them isn't watching us?' [pb]'I guess I wouldn't put it past them,' [Roger] says. 'Let's hurry it up[or]Here's our gray friend again,' [Eve] says. 'Shoo[stopping][otherwise]I think that squirrel is following us,' [Eve] says. 'Look. Over there.' [pb]'He does seem a bit too friendly, doesn't he?' [Roger] says. 'Let's see what he does when we get under some cover[end if].' [lb]".

An operation rule for Chucky when Roger is forestbound:

say "[one of]'See?' [Eve] says. [pb]'I see him,' [Roger] says[or]Indistinct low voices[stopping].".

An operation rule for Chucky:

now Chucky is on-site.

An operation rule for DONCAN-132 when Roger is carbound:

say "An aerial view shows the black Toyota driving along a gravel road, the drone trailing behind.".

An operation rule for DONCAN-132 when Roger is roadbound:

say "An aerial view of [Roger] and [Eve] running for the trees[if Chucky is ready to act], Chucky following them[end if].".

An operation rule for DONCAN-132 when Roger is forestbound:

say "Dense treetops.".

An operation rule for DONCAN-132:

now DONCAN-132 is on-site.

Chapter - Task One Action-Processing Rules

First before doing something when engaged in Task One or engaged in Task Two:

if fussing in the office is true, decrement time of day. [We don't want time to pass when we're fussing in the office.]

Before activating a human resource, try talking to the noun instead.

Before activating a device, try switching on the noun instead.

Before answering a human resource that "hi/hello/greetings" when engaged in Task One, try talking to the noun instead.

Before decommissioning a device, try switching off the noun instead.

Before clicking when the noun is a fleeing person or the noun is a resourceful thing:

if HarborMaster is not full-screen, say "That isn't on your screen." instead;

try examining the noun instead.

Before closing a fleeing person, try minimizing HarborMaster instead.

Before closing a resourceful thing, try decommissioning the noun instead.

Before dropping the anesthetic gas, try activating the noun instead.

Before opening a fleeing person, try examining the noun instead.

Before opening a resourceful thing, try examining the noun instead.

Before putting the anesthetic gas on a fleeing person, try activating the noun instead.

Before switching on a resourceful thing, try activating the noun instead.

Before switching off a resourceful thing, try decommissioning the noun instead.

Instead of conversing when the second noun is a human resource, say "You'll need to activate [the second noun] before you can talk to h[if the second noun is female]er[otherwise]im[end if].".

Instead of decommissioning a standby human resource, say "[We] [have] not activated [noun] yet.".

Instead of decommissioning a deactivated human resource, say "[Noun] [are] not activated."

Instead of doing something when Eve's-phone is involved:

if activating or clicking or decommissioning or examining begin;

if Task One is happening, say "No game session available.";

if Task Two is happening, try looking;

rule succeeds;

end if;

say "You don't have access to her phone beyond what you see on your computer.".

Instead of doing something other than activating or decommissioning when the anesthetic gas is involved, say "[if anesthetic gas is deployed]SynSleep has already been deployed, and DONCAN-132 has no other cargo[otherwise]DONCAN-132 is carrying SynSleep, which you can deploy whenever you are ready[end if].".

Instead of activating the anesthetic gas when DONCAN-132 is not activated, say "DONCAN-132 is inactive.".

Instead of activating the anesthetic gas when activated DONCAN-132 is not on-site, say "No target within range.".

Instead of activating the anesthetic gas:

if Roger is forestbound begin;

say "Target cannot be acquired successfully.";

otherwise;

say "Acquiring target ... locked. [pb]From DONCAN-132: ";

if Roger is carbound, say "The drone dips down over the Toyota's roof then rises again.";

if Roger is roadbound, say "The drone dips down behind [Roger] and [Eve], who begin to run. [if Chucky is on-site and Chucky is activated]Chucky's microphone picks up the whirring drone, and a man says, 'Let's go. Move it.' [end if] [pb]The drone speeds over grass and toward the pair as they run. Suddenly the view jerks upward and over their heads. The drone turns around. [Roger] stumbles and falls, pulling down [Eve]. Her phone tumbles to the ground. [Eve] gets to her knees then collapses. [pb]The two figures next to the trees shrink as the view pulls back and up[if Chucky is actively on-site]. An excited squirrel prances around the fallen woman[end if].";

say "[lb]*** SynSleep successfully deployed. *** [lb]";

now noun is deployed;

now Roger is gassed;

if one human resource is activated begin;

say lb;

if Alicia is activated, say "From Alicia's cell phone: And they all fall down. Looks like you got them.";

if Travis is activated, say "From Travis['] cell phone: They're down, and I'm standing down.";

if Samuel is activated, say "From Roberta's cell phone: 'Good shot!' Roberta says. 'They're down and out.' [lb]";

end if;

now every human resource is standby;

end if.

Instead of talking to a human resource when 2 human resources are activated and Roger is not forestbound and the noun is not activated, say "You don't want to activate too many human operatives; they may interfere with each other, especially in a situation like this.".

Instead of talking to Samuel when Roger is not carbound or roadside assistance is accomplished:

say "'Hey, Sam,' you say. [pb]'Sorry, but we were just passing through,' Sam says. 'We need to be on our way.' [pb]'Oh come on, pa,' Roberta says. 'Cassidy can wait. Let's get these baddies.' [pb]'Now Ma, we're already late. I'm driving and I'm not stopping.' [lb]";

now Samuel is off-stage.

Instead of talking to Alicia when Roger is carbound and hitchhike is accomplished, say "'Hey, Alicia,' you say. 'Do you have any other ideas?' [pb]'Not right now. I'll stick around, though.' [lb]".

After activating Chucky, say "Brain stimulation successful. Chucky is heading toward game device. [pb]From Chucky's microphone: Grass rustles and birds chirp.".

After activating DONCAN-132, say "[noun] has [one of]found Eve Martin's phone, and the drone has been launched[or]been redirected to Eve Martin's phone[stopping].".

After decommissioning Chucky, say "Brain stimulation stopped, and microphone turned off. Chucky is free to resume natural activity.".

After decommissioning DONCAN-132, say "Camera turned off. DONCAN-132 will remain in the vicinity until the operation is complete.".

After looking when engaged in Task One and (trail is accomplished or attend car is accomplished):

if trail is accomplished begin;

if trail is accomplished by Alicia and trail is accomplished by Travis begin;

say "Alicia's and Travis['] bodycams show ";

otherwise;

say "From [if trail is accomplished by Alicia]Alicia's[otherwise]Travis['][end if] bodycam: ";

end if;

say "[Roger] and [Eve] walk[if trail is accomplished by Alicia and trail is accomplished by Travis]ing[end if] toward dense tree cover.";

end if;

if attend car is accomplished begin;

if attend car is accomplished by Alicia and attend car is accomplished by Travis begin;

say "Alicia's and Travis['] bodycams show: [if roadblock is accomplished]The car parked on the side of the road[otherwise]The car stuck in a ditch[end if].";

otherwise;

say "From [if attend car is accomplished by Alicia]Alicia's[otherwise]Travis['][end if] bodycam: [if roadblock is accomplished]A car parked along the side of a gravel road[otherwise]A car trapped head-first in a ditch[end if].";

end if;

end if.

After looking when engaged in Task One and (an animalistic resource is activated or a mechanical resource is activated):

unless Chucky is ready to act begin;

if Chucky is activated begin;

say "From Chucky's microphone: ";

if Chucky is not on-site begin;

say "Grass rustles[one of] and birds chirp[or][purely at random][if Roger is carbound and (travel time of Chucky is 1)]. A car crunches along a gravel road[end if].";

otherwise;

say "[if Roger is roadbound]Grass rustles[otherwise if Roger is gassed]birds chirp[otherwise]crickets hum and birds chirp[end if].";

end if;

end if;

if DONCAN-132 is activated begin;

if Chucky is activated, say lb;

if DONCAN-132 is not on-site begin;

if travel time of DONCAN-132 is greater than 0 and the travel time of DONCAN-132 is less than 3, say "From DONCAN-132: [if Roger is carbound]A black car drives along a gravel road[otherwise if Roger is roadbound]Two small figures walk toward a wooded area[otherwise if Roger is gassed]Two small figures lay on the grass next to a wooded area[otherwise]Trees grow larger as the distance between them and the drone shortens[end if].";

otherwise;

say "From DONCAN-132: ";

say "[if Roger is carbound]The drone follows from behind the black car as it drives down a gravel road[otherwise if Roger is roadbound]The drone follows [Roger] and [Eve] from high overhead as they head for a wooded area[otherwise if Roger is gassed][Roger] and [Eve] lie unconscious on the ground[otherwise]The drone hovers over treetops[end if].";

end if;

end if;

otherwise;

say rpo;

end unless.

Check examining a resourceful thing:

say "[printed name of noun][if the noun provides an Affiliation] ([Affiliation of noun])[end if]: ";

say rpo.

Carry out looking when HarborMaster is full-screen and location is Office and username of yourself is not "":

if sidebar is disallowing toggling, now sidebar is allowing toggling;

say "[b]Player(s): [/b][set link 11]Eve Martin[end link] [b]Location: [/b]Rice Lake, ON, Canada [b]Heading: [/b][if Roger is carbound]North by northwest[otherwise]West[end if] [b]Average Speed (km/h): [/b][if Roger is carbound]20[otherwise]<5[end if][pb]";

if HarborMaster was no-screen, say "Locating and updating resources ... Done[if sidebar is g-present]. Sidebar open and updated. [end if] Appropriate field operatives have been notified. Type RESOURCES or check the resource sidebar for information. [if microphone is switched off][lb]Microphone on. [end if] [pb]";

now microphone is switched on;

say "No game session available[first time]. [pb]From [i]The Titan Handbook,[/i] ('Connecting with Players,' pg. 43)[lb]When a player has logged on but a game session is unavailable, visual and textual connection is needed. Use your resources to confirm that the player is in control of the playing device and sync playing device with [HarborMaster], which every field operative is trained to do[only].";

rule succeeds.

Chapter - Task One Turn Sequence Rules

[These prevent anything within-world from happening when the player is talking to a human resource.]

First scene changing rule when engaged in Task One and conversationalist is a human resource:

rule fails.

The timed events rule does nothing when engaged in Task One and conversationalist is a human resource.

The advance time rule does nothing when engaged in Task One and conversationalist is a human resource.

The update chronological records rule does nothing when engaged in Task One and conversationalist is a human resource.

First every turn when engaged in Task One (this is the change travel times rule):

if travel time of Chucky is greater than 0 and (Roger is carbound and travel time of Chucky has not been 0) or Chucky is activated begin;

decrement travel time of Chucky;

otherwise;

increment travel time of Chucky;

end if;

if DONCAN-132 is activated and the travel time of DONCAN-132 is not 0, decrement travel time of DONCAN-132;

if DONCAN-132 is deactivated and Roger is not carbound, increment travel time of DONCAN-132;

if a human resource is activated begin;

repeat with trailer running through activated human resources begin;

if travel time of trailer is 0, next;

if (Roger is roadbound or Roger is forestbound) and (trailer is Alicia or trailer is Travis) begin;

calculate travel time for trailer;

otherwise;

decrement travel time of trailer;

end if;

end repeat;

end if.

To calculate travel time for (intervener - a person):

if intervener is actively enacting attend car begin;

increment time to runners of intervener;

decrement time to car of intervener;

now travel time of intervener is time to car of intervener;

end if;

if intervener is actively enacting trail begin;

decrement time to runners of intervener;

increment time to car of intervener;

now travel time of intervener is time to runners of intervener;

end if.

[Note that, in this order, travel times reach 0 a turn before the resource actually acts.]

First every turn when a resourceful thing is ready to act and engaged in Task One (this is the make the resources act rule):

let operative order be a list of things;

if a human resource is ready to act, now operative order is the list of ready to act human resources;

if a mechanical resource (called operative) is ready to act, add operative to operative order;

if an animalistic resource (called operative) is ready to act, add operative to operative order;

repeat with counter running from one to the number of entries in operative order begin;

let freelancer be entry counter in operative order;

unless freelancer is standby, follow the operation rules for entry counter in operative order; [a resource could be made standby in the operation rules.]

if Roger is carbound and freelancer is a human resource and rule failed, now every human resource is standby;

if freelancer is a human resource and (Roger is gassed or Jason is successful with Diana) begin;

say "[lb]'Thanks everyone,' you say. 'We're done.' [pb]*** Titan [username of yourself] is now connected to cell phone of Eve Martin. Transferring game session ... done. Press any key to test connection. *** [lb]";

wait for any key;

now every resourceful thing is off-stage;

now The background color of the sidebar is "#d3d3d3";

now conversationalist is the player;

move player to Boar Bar, without printing a room description;

refresh the sidebar;

now Boar Bar contains the raven;

now Boar Bar contains the swan;

break;

end if;

end repeat;

now completed a previous operation is false;

if location is Boar Bar begin;

try looking;

rule succeeds;

end if.

First every turn rule when engaged in Task One and conversationalist is a human resource:

rule fails.

First every turn when fussing in the office is true and Conspiring:

say "You return to [HarborMaster] and the game world";

if engaged in Task Two begin;

say "[if playing as swan is true], playing as the swan[otherwise], as [username of yourself][end if]";

move the player to Boar Bar, without printing a room description;

if playing as swan is true, now player is the swan;

end if;

if engaged in Task Three begin;

say ", watching the proceedings";

move the player to the Chamber, without printing a room description;

end if;

say ".";

now Fussing in the office is false.

Every turn when Roger is carbound and engaged in Task One and time since Task One began is 21 minutes:

if one resourceful thing is ready to act, follow the make the resources act rule;

now Roger is roadbound.

Every turn when Roger was carbound and (Eve is crashed by squirrel or ram is accomplished or roadblock is accomplished or Roger is roadbound):

say "***Eve Martin has changed direction. She is now heading west at less than 5 km/h.*** [pb]";

transition the human resources;

now Roger is roadbound;

if roadblock is accomplished, now Roger is forestbound;

now Trail is relevant;

now attend car is relevant.

Every turn when (Roger is gassed for 10 turns or Roger is forestbound for 15 turns) and engaged in Task One:

if one resourceful thing is ready to act, follow the make the resources act rule;

if Boar Bar contains player, rule succeeds;

report a premature ending.

[We use scenes to measure time, but we could have also said "if roger is roadbound for x turns ... "]

Every turn when Roadbound Roger is happening and Roger is not gassed:

if time since Roadbound Roger began is 6 minutes begin;

if one resourceful thing is ready to act, follow the make the resources act rule;

now Roger is forestbound;

end if.

Every turn when Roger was not gassed and Roger is gassed:

transition the human resources;

now establish connection is relevant;

now the travel time of Alicia is 1;

now the travel time of Travis is 1.

Last every turn when Roger was not forestbound and Roger is forestbound:

Jason arrives in 1 turn from now;

if Roger was carbound begin;

if activated DONCAN-132 is on-site begin;

say "From DonCAN-132: The Toyota pulls over to the side of the road and parks. [Roger] and [Eve] exit and, after both look at the drone, they rush into the cover of a wooded area.";

otherwise;

say "From Travis['] cell phone: Looks like they're parking along the road. I can't see them anymore. They've got some tree cover now. Over.";

end if;

otherwise;

if Chucky is actively on-site, say "From Chucky's microphone: 'Even if they can still track your phone in here, I think we can stay one step ahead of them,' [Roger] says. [pb]'Wanna bet that squirrel follows us? I don't think we'll lose him,' [Eve] says.";

if DONCAN-132 is actively on-site, say "[if Chucky is actively on-site][lb][end if]From DONCAN-132: [Roger] and [Eve] disappear into a region of dense maple trees[if Chucky is actively on-site], and Chucky follows[end if]. The drone flies above the treetops and hovers.";

say "[if activated DONCAN-132 is on-site or Chucky is actively on-site][lb] [end if]From Alicia's cell phone: They're taking cover in the trees. We might lose them. [unless Alicia enacts an actionable dialogue]I'm still waiting for orders, sir.'[end unless] ";

if Alicia enacts trail begin;

say "I'll try to follow them into their hidey hole, though.' ";

now Alicia is not on-site;

now time to runners of Alicia is (time to runners of Alicia plus 2);

end if;

if Alicia enacts attend car, say "[if Alicia is not on-site]Once I get good position on their car I'll stick with it[otherwise]I'll keep an eye on their car[end if] until you let me know otherwise.'";

say pb;

say "From Travis['] cell phone: ";

if Travis enacts trail begin;

say "I'm still on their trail, and I'll try to follow them in there. ";

now Travis is not on-site;

now time to runners of Travis is (time to runners of Travis plus 2);

end if;

if Travis enacts attend car, say "[if Travis is not on-site]I'm closing in on their car. Notify me if plans change[otherwise]I'm staying at the car. Let me know if you want me to follow them instead[end if]. ";

unless Travis enacts an actionable dialogue, say "I'm still on standby. ";

say "Over.' [lb]";

end if.

Every turn when the sidebar is g-present and Conspiring:

refresh the sidebar.

At the time when Roger's licence is tagged:

if HarborMaster is full-screen begin;

now Roger is licence-tagged;

say "[b]License Plate information for RTEMGMSK[/b] [lb]Vehicle: black Toyota Corolla [lb]Registered to: Grant Mason ([dob of Roger]) [pb][b]FromChaos Registration Information: [/b][description of Roger] [lb]";

now Roger is identified;

otherwise;

Roger's licence is tagged in 1 turn from now;

end if.

At the time when targets real names are revealed:

if HarborMaster is full-screen begin;

now Roger is identified;

say "Results of facial recognition: [pb]";

say "[description of Eve] [pb] [description of Roger] [lb]";

otherwise;

targets real names are revealed in 1 turn from now;

end if.

At the time when Jason arrives:

if HarborMaster is full-screen begin;

say "*** New resource available: Jason Williams *** [pb] From Jason's cell phone: I just got wind of the situation. I'm close-by. Out for a hike with my dog. Let me know if we can help.";

now HarborMaster accesses Jason;

now office-computer incorporates Jason;

now sniff-out is relevant;

otherwise;

Jason arrives in 1 turn from now;

end if.

At the time when Travis reports:

if HarborMaster is full-screen begin;

say "From Travis['] cell phone: They're on a side road. They're out in the open now, but there's a lot of tree cover around, and they could be headed for that, especially if they know we're onto them.";

otherwise;

Travis reports in 1 turn from now;

end if.

At the time when Christopher calls:

if HarborMaster is full-screen begin;

say "Christopher Suthen is calling from his cell phone ... connected. [pb]From Christopher's cell phone: Those two yer after was just here at my gas station. They got some food and gas. He's Roger. Short guy with slicked back, long black hair. She's Eve. Short, blond hair. Pretty, though I can't really say how [']cause I wasn't lookin['] in her eyes, if you catch me there. Both could be twenty-something. I offered to help them get hooked up, but she wouldn't give me her phone. Guess I can't blame her, though. Game like [i]Ship.[/i] Players are a suspicious group.' [pb]'Thanks, Chris. We're on them now,' you say.";

Travis reports in 1 turn from now;

otherwise;

Christopher calls in one turn from now;

end if.