Volume - World Parameters
Book - Kinds, Variables, and Descriptors
Chapter - Things, Values, and Variables
A computer is a kind of device.
An icon is a kind of thing.
Understand "icon/icons" as an icon.
An icon can be no-screen, low-screen, or full-screen. An icon is usually no-screen. [Low-screen are minimized icons.]
An animalistic resource is a kind of animal.
An animalistic resource can be on-site.
A human resource is a kind of person.
A human resource can be waiting for a decision.
A human resource can be on-site.
A mechanical resource is a kind of thing.
A mechanical resource can be on-site.
A thing can be standby, activated, or deactivated (this is its preparedness).
A human resource is usually standby. [That is, starts out awaiting instructions from the player.]
An animalistic resource is usually standby.
A mechanical resource is usually standby.
Understand "costume", "disguise", "face mask", "facemask", and "mask" as "[disguise]".
A mask is a kind of wearable thing. Understand "[disguise]" as a mask.
the buzzard's mask, the cat's mask, the dog's mask, the eagle's mask, the fly's mask, the hawk's mask, the owl's mask, the pig's mask, the rat's mask, the raven's mask, and the swan's mask are masks.
Should the game choose doing something with a mask:
An alcoholic drink is a kind of thing.
An alcoholic drink has a list of things called drinkers.
A secret folder is a kind of thing.
A conspirator is a kind of person.
A Conspirator has a list of people called aliases.
A conspirator can be connected or disconnected. A conspirator is usually disconnected. [Players can't use aliases for disconnected conspirators.]
The addressee is a conspirator that varies.
A co-conspirator is a kind of person. A co-conspirator is privately-named. [Because we don't want the player to be able to use their name until they are connected with the conspirator name.]
A co-conspirator has some text called real name. A co-conspirator has some text called DOB. A co-conspirator has some text called residence. A co-conspirator has some text called pic. A co-conspirator has some text called email.
The description of a co-conspirator is usually "[b]Username: [/b] [if item described is Chin][set link 19]Chin Lee[end link][otherwise if item described is Olga][set link 20]Olga Burlenko[end link][otherwise if item described is Yaphet][set link 21]Yaphet Kalotto[end link][otherwise if item described is Tuttle][set link 22]Richard Tuttle[end link][otherwise][set link 23]Fiona Campbell[end link] [end if][lb][b]Real Name: [/b][real name of item described] (DOB: [dob of item described])[lb][b]Address:[/b] [residence of item described][lb][b]S.hip e-mail: [/b] [email of item described] [pb][pic of item described]".
Chin Lee, Olga Burlenko, Fiona Campbell, Yaphet Kalotto, Richard Tuttle, and Eve Martin are co-conspirators.
A second co-conspirator is a kind of person. A second co-conspirator is privately-named. [For the same reason as above for co-conspirators.]
EveryMan, LaserLight, LuckySeven, MoneyClip, and NeedlePoint are second co-conspirators.
Awareness is a kind of value. automaton, awakening, conscious, and godly are awarenesses.
A person has an awareness. The awareness of a person is usually automaton.
The awareness of a conspirator is usually godly.
An occupation is a kind of value. banker, bartender, doctor, engineer, journalist, law enforcement, lawyer, pilot, politician, retiree, and exotic dancer are occupations.
A person has an occupation.
A responsibility is a kind of value. NPC characteristics, Player Characteristics, Resource Management, Titan Management, and World Modeling are responsibilities.
A conspirator has a responsibility. The verb to be responsible for means the responsibility property.
Eye color is a kind of value. blue, gray, green, and hazel are eye colors.
Hair color is a kind of value. black, blond, brown, and red are hair colors.
Stature is a kind of value. average, short, and tall are statures.
Movement is a kind of value. bold, careful, clumsy, and refined are movements.
Weight is a kind of value. skinny, stocky, muscular, and thin are weights.
Some conspirators are defined by the Table of Attributes.
Table of Attributes
|Conspirator||Co-conspirator||Second Co-conspirator||Eye Color||Hair Color||Stature||Movement||Weight||Occupation|
|The buzzard||Chin Lee||MoneyClip||hazel||brown||average||bold||stocky||banker|
|the eagle||Olga Burlenko||LuckySeven||blue||blond||average||careful||thin||lawyer|
|the hawk||Yaphet Kalotto||EveryMan||hazel||brown||tall||careful||muscular||politician|
|the raven||Richard Tuttle||LaserLight||blue||black||tall||careful||thin||engineer|
|the swan||Eve Martin||--||blue||black||tall||refined||thin||journalist|
|the owl||Fiona Campbell||NeedlePoint||green||red||short||clumsy||skinny||doctor|
The eagle, Olga, LuckySeven, the swan, Eve Martin, the owl, Fiona Campbell, and NeedlePoint are female.
The swan is connected. The swan is awakening.
An actionable dialogue is a kind of value. No-dialogue is an actionable dialogue.
An actionable dialogue can be relevant or irrelevant. An actionable dialogue is usually irrelevant.
An actionable dialogue can be accomplished.
The current dialogue is an actionable dialogue that varies. The current dialogue is no-dialogue.
Dialogue choices is a list of actionable dialogues that varies.
Ask-order is a list of things that varies. [To track if the player has asked the NPCs in the right order for Task Two.]
A thing can be examined or unexamined. A thing is usually unexamined.
A person has a list of things called things spoken about.
A person can be npc.
A scene can be debugging.
Understand "gal/gals/girl/girls/lady/ladies/woman/women" as a woman.
Understand "boy/boys/guy/guys/man/men" as a man.
Understand "animal/animals" as an animal.
Ending quest finally is initially false.
Fussing in the office is initially false.[Used when the player wants to do something in the Office while engaged with HarborMaster.]
Section - The Manual
table of help contents
|title (text)||subtable (table name)||description (text)||used (number)||bookpage (number)||localpage (number)|
|"Introduction and How to Play (for novice and experienced interactive fiction players)"||--||"[fiction title] uses many unusual commands. A sidebar along the left side of the screen shows these when a within-world interpreter, [i]HarborMaster,[/i] is open (and not during the introductory session). These commands can also be listed in the main window by typing RESOURCES or COMMANDS. SIDEBAR ON and SIDEBAR OFF toggles the sidebar. The resources are listed in the status bar if you choose to play without the sidebar. Many parts of the game use some hyperlinks, but they can be activated with X or BIO FOR [bracket]link name[close bracket] as well, whichever is appropriate. When numbered dialogue choices are presented, select the dialogue you want by typing the corresponding number, without the parentheses. [pb]Conventional actions are also available when appropriate, the most common being ASK [bracket]someone[close bracket] ABOUT [bracket]something[close bracket], EXAMINE (or X) [bracket]something[close bracket], LOOK (or L), and TALK TO [bracket]someone[close bracket]. You can try different actions as well, just keep the phrasing simple. Two additional commands are used on resources: ACTIVATE and DEACTIVATE. [pb]Check the 'hints' in this menu if you need some help; it includes a walkthrough called 'Untangling the Web.' [lb]"||--||--||--|
|"Hints"||Table of Help Options||--||--||--||--|
|"Acknowledgements"||--||"The creative team behind [fiction title] was headed by Nigel Jayne, with code contributed by Wade Clarke, Eric Eve, Stephen Granade, Alice Grove, Jon Ingold, Aaron Reed, Emily Short, and Erik Temple. Thank you to Jonathan Blask and David White for consulting on the project and for testing. Comments and transcripts are welcome. Send them to firstname.lastname@example.org. The cover, 'Spider web,' is a photograph by Tom Burke, and it is used under the creative commons by 2.0 license ([fixed letter spacing]http://creativecommons.org/licenses/by/2.0/[variable letter spacing]). Jeff Meloche designed and added the title. [pb]The game was designed using Inform 7 ([fixed letter spacing]http://inform7.com/[variable letter spacing]), created by Graham Nelson with help from Emily Short and many others."||--||--||--|
Include Menus by Wade Clarke. [We need this here because it needs to be included after defining the Table of Help Contents.]
To say spinning the web:
say "I had no idea what I was doing for [i][story title].[/i] I wrote it for a game jam, called Imaginary Games from Imaginary Universes, in which each entry had to be inspired by entrant-submitted reviews of fictional games, defined as those that would be very difficult or impossible to actually create. It took me a week to choose the [i]S.hip of Theseus[/i] (SOT) review out of the five I received, and it is reprinted as part of the e-mail you can read in your office at the beginning of this game. I liked the conspiracy plot and the mention of [i]House of Leaves,[/i] though I'm not familiar with SOT. After a little more thought, I decided to sprinkle references to Greek mythology throughout the game, based solely on the Ship of Theseus paradox, and that the game would use an experimental style, much like [i]House of Leaves[/i] had. Obviously I couldn't make SOT as described in the review, but I wanted to use its game mechanics in some way, and giving the player a beta testing role seemed like a good strategy. Besides, it would allow me to explore how a game like SOT would work in the real world. I had seven weeks to build and launch my S.hip. [pb]";
say "I wanted to design Gaia around the idea that players would need to complete several debugging tasks before transitioning into the real world and uncovering a real conspiracy. Inform 7 debugging commands would therefore be included as part of the game play. I liked the idea of drones monitoring the player as mentioned in the SOT review, and I decided to expand on it to include the other resources that would be needed for player surveillance. The first task, reconnecting to the game world, grew from there. Given the time limit, though, I started coding Gaia without much notion of where to take it after this initial task. Gaia originally began with the player in the office,
but I soon realized that it would probably be more interesting to show that the player was a beta tester, rather than just mention it in the room description. The introduction then became the first game-within-a-game, a theme which would continue throughout Gaia, and I used Greek mythology as a bit of foreshadowing (I still feel a little guilty about lifting some ideas from the movie [i]Clash of the Titans[/i] (2010)).";
say "The remaining tasks were to focus on the multiplayer concept suggested in the SOT review, but first I needed a scenario. Restricting players to a single room for each task would keep the map simple and help focus them on what exactly had to be done. For the second task, I sought alternatives to the typical 'find object, use object' puzzle design. In [i]Eclosion,[/i] another work of interactive fiction, players had to figure out the right sequence of actions to solve its puzzle. I thought that approach would probably work well for Gaia, given [i]Eclosion[/i] was written under a time constraint of three hours. [i]Taco Fiction,[/i] another game involving a conspiracy, inspired the use of masks, and an objective crystallized. I was reading [i]The Barkeep[/i] by William Lashner at this time. Each chapter of the book is named after a mixed drink. I now had the remaining ingredients [mdash] a setting and a puzzle solution [mdash] from which to write the second task. [pb]";
say "The first task was a typical interactive fiction setup: The player, as a PC, influences the game world by using typed commands. The second task delved deeper into meta-game territory by layering PC upon PC and combining within-world and debugging commands. For the third, I wanted to limit players to debugging commands and let the multiplayer concept dominate. Essentially players would watch other PCs, but ideally there would also be a puzzle for players to solve. This design presented a couple of problems: how would time advance if player actions don't influence the game world, and how would players feel any sense of agency if events progress without intervention? With regard to the first, I could have used an Inform extension so that text could be printed in real time, but there is no guarantee that all interpreters would support this function and, given that reading speeds vary, I couldn't pace the scene properly to also allow players to type commands between within-world events. So, I settled on conventional turn-based time progression. I thought about the second problem for awhile, and I could never figure out a satisfying way to immerse players in the game world using only debugging commands. The best I could do was reward players with a bit of information after they identify each conspirator. [pb]";
say "Transitioning players from the game world of the tasks into the real world presented another problem: In theory, [fiction title] is a product of the fictional company FromChaos, so why would they release a game that exposes themselves? My solution was to include a bonus section, the egg hunt, which, presumably, the FromChaos executives would take little heed of but hardcore players would attempt and, if clever and tenacious, eventually find the secret that was hidden by one of the game developers. I wanted a hint system that included the hunt though, so I consider the menu system 'out-of-world,' and it contains information that a true FromChaos production wouldn't include. This is why 'Spinning the Web' only appears in the menu and not as an option listed at the end of the game. [pb]";
say "With the deadline looming, I had to change my plans for the 'hidden' content. Originally, players were going to be able to actually copy several top secret files onto their game devices, read them and, theoretically, distribute them for all to see. They would also need to solve a final puzzle to access the top level of the conspiracy. This last challenge was going to be a variation on the 'find the password' problem. However, I am happy with the compromise. By the time the player reaches this part of the game, I think it was a better idea to wrap up the proceedings quickly. Players have gone through enough just to get there. And I like the software glitch because it fits with the testing objectives set up in the rest of the game. [pb]";
say "When the games from the game jam were released, there was very little feedback from the interactive fiction community. What little comment [fiction title] did receive was positive, with a couple of reviewers remarking that it was weird. I think that is an apt description, befitting of the source material and of some of the conspiracy theories that are really out there.";
say "[lb]Nigel Jayne, May 2016 [lb]".
table of Help Options
|title (text)||subtable (table name)||description (text)||used (number)||bookpage (number)||localpage (number)|
|"Connecting with Eve"||--||"The first task has several outcomes, which depend upon what you tell your resources to do and which you activate. Activate the drone early to watch the action. If you let the car pass Chucky, it will take him longer to find his target. De-activating Chucky frees him to roam [mdash] and less likely to distract."||--||--||--|
|"Recognizing the Raven"||--||"You need to ask each bar patron about the raven in the correct order. It's possible to lock yourself out of the solution, but remember you have the RESET command to take you back to the start of the task. The fly needs to get drunk enough to talk about the raven and, when he does, the rat remembers something. Note the properties (using SHOWME) for a particular drink in the bar."||--||--||--|
|"Eavesdropping the Meeting"||--||"You can recognize people at the meeting based on the SHOWME results. The raven is interested in his tablet, which has the names of members at the meeting. As the raven addresses specific people, the globe hints at where the person is from. Remember to check BIO FOR someone after you recognize him or her."||--||--||--|
|"Finding Eggs"||--||"There are 12 egg types to find. Every action you need to perform is some form of jumping. Be specific; use common phrasings. The room should give hints on what to act upon [mdash] which isn't always a physical object."||--||--||--|
|"The server"||--||"You really do just need to open a folder. Notice a different one appears when you try. It can be opened,||too."||--||--||--|
|"Untangling the Web"||--||"To start: n / kill Zeus (note that many actions cause an intentional error message; you're beta testing a game [pb]To open [HarborMaster]: read e-mail / read review / open HarborMaster / Titan (or whatever you want) / Password (or whatever you want) [pb]To connect to Eve: (one of many possibilities) activate drone / x drone / x alicia / talk to Alicia / 1 / x travis / talk to Travis / 1 / x Chucky / activate Chucky / x Eve / z / x roger / x Sam / talk to sam / 2 / z / z / deploy gas / talk to Alicia / 1 / z [pb]To recognize the raven: headpop into the swan / x me / read invitation / ask bud about raven / ask pig about raven / ask cat about raven / ask dog about raven / ask rat about raven / ask fly about raven / ask rat about raven / showme (the drink the raven ordered) / recognize Tuttle as raven [pb]To recognize Gaia members: showme globe / relations / showme tablet / recognize Chin as the buzzard / bio for Chin / showme buzzard / recognize Olga as eagle / bio for Olga / showme eagle / recognize hawk as Yaphet / bio for Yaphet / showme hawk / recognize owl as Fiona / bio for Fiona / showme owl / bio for raven / showme raven / z / showme swan [pb]To find the eggs and the server: jump over wall / jump into arms / jump start / jump for joy / jump rope / jump on the spot / jump kick / jump off the deep end / jump back / jump cut / jump scare / jump through hoop / jump through hoop / jump through hoop / jump through hoop / jump through hoop / open people / open earthsim"||--||--||--|
Chapter - Starting room and Player
SOC is a room. "[one of]From among the trees, you continue to watch the naked women. The younger and shorter of the two wades into the stream, her hair like threads spun from Midas['] gold. She lowers her basket to the water's surface. Fish flop into it, settling into a motionless stack. The other woman, bright flowers in her black hair, plucks apples from a tree and drops them into the basket hanging from her arm. The fruit ripen and swell under her touch. [pb]You were right. Nymphs. Your search is nearly over. [pb]The water nymph returns to land. She begins to sing. The forest nymph joins in, her pitch deeper than that of the blond. With both of their baskets full, the pair follow the bank upstream. [pb]You venture from the trees to the stream, keeping the nymphs in sight. They have joined a group of their sisters to the north of you. You call that direction 'north' because you're facing it; fatigue has rendered your inner compass as trustworthy as Zeus with a farmer's daughter[or]You're transfixed by the naked nymphs gathered to the north[stopping].".
The printed name of SOC is "Stream of Consciousness".
Questing is a scene. Questing begins when the location is SOC.
Yourself has a text called username. Yourself has a text called password.
Understand the username property as describing yourself when the player is yourself.
Understand "titan" as yourself when the player is yourself.
Yourself can be oblivious to problems, alerted to problems, or attending to problems.
Yourself is oblivious to problems.
The description of the player is "[if Questing is happening]You're exhausted, Hermes['] sandals having failed you. Poseidon's trident rakes the ground behind you; it's much easier to drag the weapon than it is to wield it. Hades['] helmet might have served him well in the Underworld, but out here in the sun it just makes your scalp itchy and your forehead sweaty. The sack slung over one shoulder throws off your balance, causing you to stumble like a reveler at a party hosted by Dionysus, with music by an incessant siren song cycling through your brain[otherwise]You give yourself a strength of about 60, more mental than physical, but you're determined to increase the maximum of both. Your stamina started at 50 this morning after a good night's sleep, but weariness has set in, and the early-afternoon caffeine jolt is fizzing out. Maybe it's 25 now? Charm, on the other hand, holds steady at 50. The HR department at FromChaos wanted 'excellent interpersonal skills' for this job, which isn't normally associated with a code-tester position. It didn't take you too long after joining the [i]S.hip of Theseus[/i] team to learn why being cast such a large number for 'charm' on a throw of the cosmic dice would be so important[end if].".
Chapter - Definitions and Relations
Definition: a thing is involved if (it is the noun or it is the second noun) and it is not the player.
Definition: an object is on-screen rather than off-screen:
if location is the Office and it is clickable, yes;
if engaged in Task Two or engaged in Task Three and it is the location, yes;
if location is Calydonian Boar Bar and Calydonian Boar Bar encloses it, yes;
if location is the Chamber and The Chamber encloses it, yes;
if player has been bunny and it is in the location, yes;
Definition: a thing is clickable if it is enclosed by a computer.
Definition: a thing is resourceful rather than unresourceful if it is an animalistic resource or it is a human resource or it is a mechanical resource.
Definition: a thing is ready to act:
if it is resourceful begin;
if it is activated and it is not on-site and the travel time of it is 0 begin;
if it is a human resource and it enacts an actionable dialogue, decide yes;
if it is an animalistic resource or it is a mechanical resource, decide yes;
Accessibility relates one icon (called activator) to various things. The verb to access means the accessibility relation.
Enactment relates one actionable dialogue (called mission) to various people. The verb to be enacted by means the enactment relation.
The verb to enact means the reversed enactment relation.
Definition: a actionable dialogue is chosen if it is enacted by an activated human resource.
Disguising relates one person to another (called alter ego). The verb to disguise means the disguising relation.
Chapter - Phrases
Section - Deciding
To decide which text is the/-- accessible text of (converted - a snippet):
let t be text;
let t be converted;
decide on converted.
To decide whether conspiring:
if Finding Reality is happening, decide no;
if HarborMaster is full-screen, decide yes;
To decide which text is intervention time for (intervener - a thing):
if Roger is forestbound begin;
unless the intervener is a human resource, decide on "unknown";
if intervener is a human resource and intervener is actively enacting trail, decide on "unknown";
if Roger is roadbound and intervener is a human resource and intervener is not activated, decide on "undetermined";
decide on "[travel time of intervener]".
To decide whether (converser - a person) is actively enacting (task - an actionable dialogue):
if converser is enacting task and converser is activated, decide yes;
To decide whether (agent - a thing) is actively on-site:
if agent is on-site and agent is activated, decide yes;
To decide whether (task - an actionable dialogue) is accomplished by (agent - a human resource):
if agent is activated and agent is on-site and agent enacts task, decide yes;
To decide whether (talker - a person) has spoke/spoken about/of (target - a thing):
if the target is listed in the things spoken about of the talker, decide yes;
To decide whether (name of kind of value K) has been spoke/spoken generally about/of:
repeat with selection running through Ks begin;
if conversationalist has spoken of selection, decide yes;
To decide whether engaged in Task One:
if Task One is happening and Conspiring, decide yes;
To decide whether engaged in Task Two:
if Task Two is happening and Conspiring, decide yes;
To decide whether engaged in Task Three:
if Task Three is happening and Conspiring, decide yes;
Section - Saying
To say i -- beginning say_i -- running on:
(- style underline; -).
To say /i -- ending say_i -- running on:
(- style roman; -).
To say b -- beginning say_b -- running on: (- style bold; -).
To say /b -- ending say_b -- running on: (- style roman; -).
To say fiction title: say "[i][story title][/i]".
To say mdash: say unicode 8212.
To say lb: say line break.
To say pb: say paragraph break.
To say rpo: Say run paragraph on.
To say quest final message:
say "Would you like to RESTART, RESTORE a saved game, QUIT or UNDO the last command?".
To say Buick:
say "[first time]maroon[only] Buick".
To say Roberta:
say "[one of]a gray-haired woman[or]Roberta[stopping]".
Section - Verbs
To activate is a verb.
To attain is a verb.
To attempt is a verb.
To come is a verb.
To mull is a verb.
To mutter is a verb.
To stand is a verb.
Section - Other Phrases
To set the/-- (operatives - a table name):
Repeat through the operatives begin;
unless resource entry is Jason begin;
now HarborMaster accesses Resource entry;
now office-computer incorporates Resource entry;
To report a premature ending:
say "[if location is Boar Bar]You lost contact with the swan and the raven, thus ending your session ... and apparently your job. The day after your encounter with Eve, FromChaos fired you. No 2 weeks notice. Just get out[otherwise]*** Signal from Eve Martin lost. *** [pb] You think about what may have happened [mdash] [Eve] could have turned off her phone [mdash] then your phone rings. You're fired. Just like that. Get out[end if]. As you transferred your players to other titans, you notice that [Eve] had already been removed from your roster. Maybe you weren't her designated titan. Was it a bug? [unless location contains Eve or engaged in Task One]A PC can only be removed from play by a titan, and the vulture wasn't controlled by one. If Eve wasn't supposed to be under your watch, that would explain why she was removed without your permission. [end unless]But that kind of error shouldn't be the reason for firing you. You decide to take some time off and create some games of your own.";
say thank the player.
To say thank the player:
end the story finally saying "Thank you for playing [fiction title]. Continue to unravel the mystery of Gaia in [i]Re.constructing the Ship of Theseus,[/i] the official sequel to [i]S.hip of Theseus,[/i] and take control of real-world resources to defend yourself and your friends from Gaia's web.".
To decide which object kind is the specific kind for (candidate - a thing):
let result be a list of object kinds;
repeat with I running through object kinds begin;
if candidate is of kind I, add I to result;
decide on entry (number of entries in result) in result. [Kinds are listed hierarchical, so that the last one listed is not subdivided into any other kinds.]
[Obviously this won't be adequate for games with complicated hierarchies of things, but for this game it is good enough.]
To test (selection - a thing) for attributes:
let OK be the specific kind for selection;
say " [selection] - [if selection is a conspirator or the selection is a co-conspirator]PC[otherwise if the selection is an npc person]bar patron[otherwise][the singular of OK][end if]";
if selection is a container, say "[lb] [random thing which is in selection]";
if selection incorporates something begin;
repeat with part-of running through things incorporated by selection begin;
now OK is the specific kind for part-of;
say "[lb] [part-of] (part of [selection] [lb] - [the singular of OK] ";
if part-of contains something, say "[lb] [random thing which is in part-of]";
repeat with worn-thing running through things worn by selection begin;
now OK is the specific kind for worn-thing;
say "[lb] [worn-thing] (worn - [the singular of OK]) ";
repeat with carried-thing running through things carried by selection begin;
now OK is the specific kind for carried-thing;
say "[lb] [carried-thing] (carried - [the singular of OK])";
[We alter the "Common Commands Sidebar" extension defaults below. We adapt these phrases instead of those in the extension because we use things - Resources - and testing commands instead of text, the commands for the table in the extension.]
To print a table of commands in the sidebar, in main window:
say "[bold type]HarborMaster ";
say "[if location is the Office]Resources [roman type](estimated time before intervention in parentheses)[otherwise]Testing Commands[roman type][end if][pb]";
if yourself is attending to problems and location is Office begin;
show the Table of Task One Biological Resources;
say "[pb] [i]Mechanical[/i][lb]";
show the Table of Task One Mechanical Resources;
say "To learn more about a resource, type its name or CLICK it. You can also ACTIVATE it or DEACTIVATE it, which places it on standby. ";
say "[b]BIO FOR [bracket]someone[close bracket]:[/b] shows registration information for a player.";
unless location is the Chamber begin;
say "[B]DEPOSSESS [bracket]someone[close bracket]:[/b] relinquish control of a PC.";
say "[B]HEADPOP [bracket]someone[close bracket]:[/B] take control of a PC.";
say "[B]RECOGNIZE [bracket]a person[close bracket] AS [bracket]a thing[close bracket]:[/B] allows a titan to re-connect a player with an unrecognized PC.";
say "[B]RELATIONS:[/B] shows the relationships between people or things.";
unless location is the Chamber, say "[B]RESET:[/B] resets the game session to the state it was in before connecting with a player.";
say "[B]SHOWME [bracket]any character or thing[close bracket]:[/B] shows game information, such as properties.";
if in main window, say lb.
To show the/-- (operatives - a table name):
if (operatives is Table of Task One Biological Resources and (1 human resource is on-screen or 1 animalistic resource is on-screen)) or (operatives is Table of Task One Mechanical Resources and 1 mechanical resource is on-screen) begin;
repeat through the operatives begin;
let re be resource entry;
if re is on-screen begin;
indent the upcoming sidebar entry;
if re is Chucky, say "[set link 12][re][end link]";
if re is Alicia, say "[set link 13][re][end link]";
if re is Jason, say "[set link 14][re][end link]";
if re is Samuel, say "[set link 15][re][end link]";
if re is Travis, say "[set link 16][re][end link]";
if re is DONCAN-132, say "[set link 17][re][end link]";
say " ([intervention time for Re] mins; [preparedness of Re])";
[Adapted from the extension Real-Time Delays by Erik Temple.]
Current teletype character delay is initially 30.
To teletype (text-to-be-printed - a text):
repeat with N running from 1 to the number of characters in the text-to-be-printed begin;
say "[character number N in the text-to-be-printed][rpo]";
wait (current teletype character delay) milliseconds before continuing, strictly;
To transition the human resources:
now every human resource is not on-site;
now every human resource is standby;
now every relevant actionable dialogue is irrelevant;
repeat with freelancer running through human resources begin;
now freelancer enacts nothing;