gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for A Fly on the Wall, or An Appositional Eye

Volume - Processing and Turn Sequence Rules

Book - processing Rules

Chapter - Disambiguation

[We need this to avoid a "match error" generated by the Disambiguation Control extension.]

Should the game choose doing something to a person who is in the location:

it is an excellent choice.

Should the game choose doing something to the current song:

if listening, it is a good choice;

never.

Should the game choose doing something to an artist:

if listening, it is a good choice;

never.

Should the game choose doing something to a room:

if going by name to or entering or exiting, it is a good choice;

never.

Should the game choose doing something to Flyeye-rm:

if entering, it is a good choice;

never.

Should the game choose doing something to an unidentified person:

never.

Should the game choose doing something with a center-stage thing (called target):

it is an excellent choice.

Should the game choose doing something to an on-screen thing (called target) during Observation:

it is a good choice.

Should the game choose doing something to a person:

it is an excellent choice.

Should the game choose doing something with a room-proxy (called target):

if Preparation is happening, never;

if target is laboratory, it is an excellent choice;

it is a passable choice.

Should the game choose replaying the event stage:

it is a good choice.

Should the game choose researching with something about a person:

it is an excellent choice.

Should the game choose consulting the laptop about text:

it is a good choice.

Should the game choose researching with the internet about something:

it is a good choice.

Should the game choose doing something to Black Widow:

if conversing or examining, it is a good choice;

it is a passable choice.

Should the game choose doing something with the gray:

it is a good choice.

Should the game choose doing something to the large bag:

if Preparation is happening, never;

it is a good choice.

Chapter - Before, Instead, After

When play begins:

now mn_breadcrumb_preference is "off"; [If we leave it on, as is the default for the Menus extension, it uses an incorrect heading when we choose a menu option that uses a subtable.]

set the raw background volume to 9500;

if glulx sound is supported and audio mode is toggled on, play the sound of theme in background with loop;

create the midground channel;

create the midground 1 channel;

create the midground 2 channel;

set the raw midground volume to 8000;

set the raw midground 1 volume to 800;

set the midground 2 volume to 1;

move Techno-Celebration to Ballroom-rm;

now Techno-Celebration is current.

Setting action variables for examining a room-proxy:

if noun is not Fly Eye and Observation is happening, now event stage is the noun.

Before undoing an action when playroom is beginning to static:

if glulx sound is supported begin;

stop the midground sound;

stop the midground 1 sound;

stop the midground 2 sound;

end if.

Before ruminating (this is the change ruminating to thinking rule):

try thinking instead.

The change ruminating to thinking rule is listed first in the before rules.

First before doing something other than examining a room-proxy when screentime is either 1 or 2:

unless pondering begin;

if screentime is 1 and creaky door is false begin;

follow the creak the door rule;

end if;

if screentime is 2 and dropped book is false begin;

follow the drop the book rule;

end if;

end unless.

First before conversing when the noun is worn:

now the noun is the holder of the noun.

First before doing something except looking when location is Ballroom-rm and Goldie is not aware of characters:

Goldie looks around in 0 turns from now.

First before doing something other than examining or following or listening to or pondering or replaying or researching with when one involved thing (called target)is on-screen during Observation:

unless target is a room-proxy or discussing target with something begin;

if target is a person and target is not the player, say "[if location contains Frankie]The only person here with you [mdash] in the flesh anyway [mdash] is Frankie[otherwise]You're alone in here . . . as far as you know[end if]." instead;

if Goldie is not aware of characters, say "You'll need to check the monitors to determine if [regarding target][they] [are] in one of the rooms." instead;

say "[The target] [are]n't in the Fly Eye with you." instead;

end unless.

First before doing something when the orb is involved:

if Preparation is happening, say "You haven't seen any orbs in the ballroom, but they do sometimes appear in recorded images like those in the Fly Eye." instead;

if event played out is true and screentime is 5 and event stage is ballroom, say "It was there and now it isn't. Typical." instead;

if screentime is greater than 4 and entry 5 in realizations is ballroom, say "No other orbs have appeared." instead;

say "It's possible one of the cameras will record an orb[if screentime is greater than 0], but no luck so far[end if]." instead.

First before doing something when Goldie is aware of characters and location is Flyeye-rm for the first time:

now Goldie is not aware of characters.

First before doing something when Goldie is thinking about the conclusions:

unless thinking, say "Right now you just want to either say GOODNIGHT and go home or THINK about what happened." instead.

First before doing something when an animal is involved:

unless conversing and the noun is an animal and the second noun is not an animal begin;

if screentime is greater than 2 begin;

if noun is cat and cat is not in location, say "The cat has been scared off." instead;

otherwise;

if Observation is happening, say "You haven't seen a [noun] around." instead;

end if;

end unless.

[We need this because the parser still recognizes the answering action in some instances, even though we removed its grammar.]

Before answering something that:

Let item be the most likely thing identified with the topic understood;

If item is a thing begin;

if the nun was not the conversationalist and item is not the hunched back, say "The nun sips from her punch as you approach. [pb]";

try discussing item with the noun instead;

end if;

if the noun provides the property Conversation Threads begin;

if the noun is the nun and Preparation is happening begin;

if the nun has not spoken begin;

say "The nun is distracted. [first time]Maybe you should say 'hello.' [only] [lb]";

now the conversationalist is Goldie instead;

end if;

unless the nun is distracted, convert to the talking about it with action on the noun instead;

end if;

if the noun is Frankie and Frankie is in the location and Observation is happening, convert to the talking about it with action on the noun instead;

end if;

try talking to the second noun instead.

Before answering a personable thing that "bye/goodbye/goodnight", try talking about "bye" with the noun instead.

Before talking about "hi/hello" with someone:

if the second noun is the nun and Preparation is happening and the nun is the conversationalist, say "You already have the nun's attention." instead;

if Observation is happening and location contains Frankie, say "You assume he can hear you, so you can just say what you want." instead;

try talking to the second noun instead.

Before answering personable thing that "hi/hello", try talking about "hi" with the second noun instead.

Before attacking something:

say "You're not prone to violent unprovoked outbursts." instead.

Before closing the laptop, say "You're enjoying the music too much." instead.

Before closing the double-duty door during Preparation, say "You decide you don't get to decide that." instead.

Before closing the double-duty door when the creakiness of the noun is not 5 during Observation:

say "The door remains silent as you swing it. You leave it open[first time]; you don't want anything in your way if something happens out in the hall[only].";

increment the creakiness of the noun instead.

Before closing the double-duty door when the creakiness of the noun is 5 during Observation:

play the sound of door creaking;

say "The door creaks as you swing it. You leave it open.";

now the creakiness of the noun is 0 instead.

Before consulting something which is not an electronic device about text, say "Only the laptop is suitable for doing research in here." instead.

Before consulting something about text:

if the topic understood matches "dwayne/harrison/daughters/daughter" or the topic understood matches "dwayne harrison", try examining the laptop instead;

say "You don't think following that path of investigation would be helpful; better to watch the monitors." instead.

Before conversing when the second noun is a person and (location does not contain Frankie or (location contains Frankie and second noun is not Frankie)) during Observation, try talking to the second noun instead.

Before conversing when the second noun is a person and the second noun is not the nun during Preparation, try talking to the second noun instead.

Before conversing when the second noun is distracted nun and Preparation is happening, say "You're unlikely to get a word in when she is preaching her Word." instead.

Before discussing the nun with the nun:

unless the nun has spoken of the pregnancy, try discussing the pregnancy with the nun instead.

Before discussing Rasputin with Frankie during Observation:

if Goldie is following fright storyline begin;

unless Frankie has spoken of the leprechaun, now the noun is the leprechaun;

end if;

if Goldie is following greed storyline begin;

unless Frankie has spoken of medicine man, now the noun is medicine man;

end if.

Before examining a room, try examining the room-proxy of the noun instead.

Before examining the cutlass during Preparation, say "The cutlass is shiny like steel. Sharp steel. And Frankie is too drunk to wield it like that." instead.

Before examining not recognized Rasputin when screentime is 6 and Rasputin is on-screen, now Rasputin is recognized.

Before doing something other than conversing when the large bag is involved:

unless (number of entries in realizations is at least 1 and entry 1 in realizations is ballroom) or (number of entries in realizations is at least 2 and entry 2 in realizations is Communications) or (number of entries in realizations is at least 3 and entry 3 in realizations is laboratory) or (screentime is 1 and event played out is false), say "[if Preparation is happening]The shadows do seem to conceal something like a bag, but you're not sure. [end if]Cleopatra did pack up the dinner decorations and carry them back in [if Preparation is happening]something[otherwise]a bag[end if]." instead.

Before doing something when the holes are involved and the pole is unexamined and (realizations is {} or (realizations is not {} and Laboratory is not listed in realizations)), say "You don't remember seeing any holes, none that are unexpected, anyway." instead;

Before doing something when something which is enclosed by the scientist is involved and the scientist is not spotted, say "You don't see anyone with that in the crowd." instead.

Before examining or talking to when the noun is the not spotted scientist during Preparation:

say "He's around here somewhere. There by the wall opposite the stage. ";

now the noun is spotted;

say rpo.

Before discussing something with not spotted scientist:

say "He's around here somewhere. There by the wall opposite the stage.";

now the noun is spotted.

Before discussing the MIB with the nun during Preparation:

if the nun has spoken about the gray, say "'They keep to themselves,' the nun says. 'I don't know any more.' [lb]" instead;

try discussing the gray with the nun instead.

Before discussing the sasquatch with the nun during Preparation:

if the nun has spoken about the leprechaun, say "'I don't know anything about either of them,' the nun says." instead;

try discussing the leprechaun with the nun instead.

Before following when the noun is a personable thing and the noun is not the player and Goldie is not aware of characters during Observation:

try examining the noun instead.

Before doing something when the butcher is involved during Preparation, say "You haven't seen him since dinner." instead.

This is the nun running off rule:

say "'Well, I guess it's time for round two,' the nun says. She tosses away her cup and, stern faced, strides toward [if the nun has spoken of the scientist]the scientist[otherwise if the scientist is spotted]the white-haired scientist[otherwise]a white-haired man in a lab coat[end if]. [if the nun has spoken of the scientist]His[otherwise]The scientist's[end if] shoulders sag, and he frowns.";

now the scientist is spotted;

now the conversationalist is Goldie;

now the nun is distracted.

Before doing something other than conversing or taking inventory when the nun is the conversationalist:

unless answering something that or drinking or eating or examining or talking to, follow the nun running off rule;

unless eating or drinking begin;

if Goldie carries the punch begin;

say "[lb]You gulp down the punch and discard the cup.";

now Ballroom-rm contains the punch;

end if;

end unless.

Before doing something when static is involved:

if screentime is less than 6, say "You haven't heard any distortion in the footage." instead;

if examining or listening to, say "The laughter seems to be overlayed the static, as if recorded separately and played back in the distortion." instead;

say "You listen to the static; you can do nothing more. All the sound from the playroom is already being recorded." instead.

Before doing something other than examining to the mobile phone:

if researching with the mobile phone about something and Observation is happening, try researching with the laptop about the second noun instead;

if consulting the mobile phone about text and Observation is happening, try consulting the laptop about the topic understood instead;

say "The phone is good where it is, and it doesn't need your attention." instead.

Before drinking or eating or taking the punch for the first time:

if the nun is distracted, say "You think you could have chatted with the nun over a cup of punch, but she is engaged with the scientist now." instead;

now Goldie carries the punch;

if the scientist is not spotted, say "'I'm going to have a quick drink,' you say to the nun as you sidestep to the punch bowl and ladle out some of the orange liquid into a plastic cup. [pb]'I can't handle that hard stuff,' the nun says." instead;

try talking to the nun instead.

Before drinking or eating the punch:

if Goldie carries the punch, say "You sip from the cup[first time]. Tasty[only]." instead;

if the punch has been carried, say "As good as it was, you decide that you have work to do." instead;

say "You would have taken the time to drink with the nun, but you decide you should really head out." instead.

Before dropping the punch:

if the noun is carried begin;

say "You finish the punch and discard the cup.";

now Ballroom-rm contains the punch instead;

end if;

say "You don't have any punch, and you really don't have time for it." instead.

Before examining Fly Eye during Preparation, try exiting instead.

Before following something which is not a person:

if Preparation is happening begin;

if location contains noun, say "The people here are much more interesting than any thing." instead;

say "You think that [regarding the noun][those] [are] more likely to be found in one of the other rooms of the mansion." instead;

end if;

say "[regarding the noun][Those] [are]n't going anywhere." instead.

Before following the player, say "You always follow yourself." instead.

Before following a personable thing:

if Preparation is happening begin;

if the location contains noun, say "[The noun] doesn't appear to be ready to go anywhere." instead;

say "Perhaps [the noun] [are] in another room. You may be able to find out when you visit the Fly Eye." instead;

end if;

if event played out is true and the noun is currently elsewhere, say "[The noun] [are] no longer visible in [short name for event stage]. Maybe [if noun is a woman]s[end if]he's on another monitor." instead;

if the noun is on-screen begin;

let viewable be entry 1 in the hangouts of the noun;

unless screentime is either 0 or 1, now viewable is entry screentime in the hangouts of the noun;

if event played out is false, now viewable is entry (screentime plus 1) in hangouts of noun;

try examining viewable instead;

end if;

if the noun is Frankie and location contains Frankie, say "You don't want to follow him anywhere." instead;

try examining the noun instead.

Before discussing a room-proxy with personable thing when the second noun is Frankie or (the second noun is the nun and the noun is not Fly Eye), now the noun is the museum.

Before giving the punch to the nun during Preparation, say "She can get her own drink whenever she wants one." instead.

Before going:

if Ballroom-rm contains the player and the noun is up, say "You're already on the second floor of the museum." instead;

try exiting instead.

Before Heading out of the room-proxy of the location, try exiting instead.

Before going by name to Fly Eye during Preparation, try exiting instead.

Before going by name to something which is not Fly Eye:

if the noun is a room-proxy, try examining the noun instead;

if the noun is not a room-proxy and the location contains noun, say "[i]Yep,[/i] you think. [i]I'm where it's at.[/i] [lb]" instead;

if the noun is in a room, try examining the location of the noun instead;

if the noun is not in a room, try examining the noun instead.

Before looking for the first time:

say "A sasquatch bends down before a leprechaun, who pulls a gold coin from behind the beast's ear. Chuckling, the sasquatch takes the treasure and places it onto a table as the leprechaun speaks to him. With a shake of the head, he follows his fellow conspirator through a tangle of costumed guests and out of the ballroom. [pb]A pirate wobbles his way to the gold, a wooden prosthesis attached to one knee, a plush toucan on his shoulder bobbing as if it were keeping time with the music. the pirate retrieves the coin, scowls, and peels away the bright gold foil. Eating the chocolate and blinking his unpatched eye in the dim light, he watches the other members of the Fortean Society [mdash] a collection of caricatures, characters, monsters, and myths [mdash] mingle in the Soul Dancers ballroom. [pb]";

follow the display banner rule;

say lb;

say "[introductory options]" instead.

Before listening to a personable thing during Preparation , try talking to the noun instead.

Before listening to an artist:

let listenable be the Song corresponding to an artist of the noun in the Table of Halloween Songs;

try listening to listenable instead.

Before listening to the music during Preparation, try listening instead.

Before listening to laptop, try listening instead.

Before listening to or examining when the noun is the voices:

if screentime is either 1 or 2, try listening to playroom instead;

if Preparation is happening, say "They're just indistinct noise." instead;

say "You don't hear anyone." instead.

Before listening to playroom when screentime is either 1 or 2 and event played out is true:

if Goldie is aware of playroom audio begin;

if event stage is noun, try replaying instead;

say "There's no sound." instead;

end if;

try listening instead.

Before listening to something when (the noun is either the leprechaun or the sasquatch or Rasputin or the noun is the voices) and screentime is either 1 or 2 and event played out is true:

if Goldie is aware of playroom audio, say "[if event stage is playroom]You'll need to replay monitor 5 to hear the conversation again[otherwise]The conversation is over[end if]." instead;

unless event stage is playroom or screentime is 1 and noun is Rasputin, try listening instead.

.

Before looking when event played out is true during Observation, now event played out is false.

Before looking when Laboratory-rm contains player, say "[intro to Ballroom] [lb][introductory options]" instead.

To say intro to Ballroom:

say "The [first time]other [only]members of the Fortean Society of New England [mdash] a collection of caricatures, characters, monsters, and myths [mdash] mingle in groups in the dimly-lighted ballroom.".

Before looking when location is Flyeye-rm for the first time, say "The wire frames of your wings bend as you gently lean back into the only chair in the room. The two floppy legs attached to your belt rise as you rest your hands on a table in front of a bank of monitors on the wall. The five screens receive signals from cameras in five different rooms in the mansion. Normally, these would be used for security, but tonight the Society is trying to record footage of the supernatural that will raise the eyebrows of even the most stone-faced skeptics. While you're hoping to witness such phenomena, following the exploits of any one of the costumed characters would probably be more interesting, after looking at the screens to decide which captures your attention. [pb]The only person you know well is Gregory Hoblett, dressed as the Russian mystic and healer Grigori Rasputin, in the Laboratory on monitor 3. Everybody in the Society likes Hoblett, unlike Grigori who survived a stabbing, possible cyanide poisoning, and two point blank gunshots, only to succumb after being shot twice in the back and beaten. [pb]The sasquatch chuckles quietly from the playroom on monitor 5, which is wired to record the electronic voice phenomena of ghostly children." instead.

Before discussing or informing about when the second noun is the nun for the first time:

say "The nun sips from her punch as you approach.".

Before eating something which is not the punch during Preparation:

if the noun is the refreshment table and the player's command does not include "table", try taking the noun instead;

say "There's plenty of actual food here, but you're not hungry." instead.

Before entering a room-proxy:

if the noun is the room-proxy of the location, say "You consider the surroundings. Yes, you're already there." instead;

if the noun is Fly Eye, try exiting instead;

say "You'll need to visit vicariously[if Preparation is happening]using the monitors in the Fly Eye[otherwise], watching the screens on the wall[end if]." instead.

Before examining a thing when the location does not enclose the noun and the noun is not a backdrop and the noun is neither the monitors nor the camera during Preparation:

if noun is a room-proxy begin;

say "You believe that is one of the rooms under surveillance in the Fly Eye." instead;

end if;

if the noun is either the leprechaun or the sasquatch, say "He has left the ballroom." instead;

if the noun is personable, say "[We] [do]n't see [regarding the noun][them] anywhere." instead;

say "You [if noun is a person]can't see anyone in the crowd dressed like that[otherwise]don't see anything like [regarding the noun][those] around[end if]." instead.

Before following a personable thing who is not the player when Goldie is not aware of characters during Observation, try examining the noun instead.

Before giving or inserting or putting when the noun is the punch:

if Goldie does not carry the punch, say "You don't have any punch, and you really don't have time for some." instead;

say "You decide to hold onto it; it is rather tasty." instead.

Before opening the laptop, say "It's already open." instead.

Before opening the double-duty door during Preparation, say "They're already open and inviting you to leave." instead.

Before opening or pushing or pulling when the noun is the double-duty door during Observation, try closing the noun instead.

Before preserving text with something, say "[if Preparation is happening]There will be plenty more going on in the Fly Eye[otherwise]The cameras are capturing everything you need to record[end if]." instead.

Before pushing something during Preparation:

if the noun is a person, say "You can't think of a good reason to start pushing anyone around." instead;

say "You have better [mdash] and more interesting [mdash] things to do." instead.

Before recording, say "[if Preparation is happening]The cameras in the rooms being monitored in the Fly Eye are more interesting than what is going on out here, you suspect[otherwise]The cameras are doing a good enough job, you figure[end if]." instead.

Before recording something with something, say "[if Preparation is happening]You can't help but think there's a lot more interesting shenanigans to see on the monitors in the Fly Eye[otherwise]Unfortunately, nothing of note is happening with [regarding the noun][them] right now[end if]." instead.

Before remembering during Preparation, say "[i]I am supposed to take a shift in the Fly Eye.[/i] [lb]" instead.

Before replaying a room-proxy for more than 1 turn, say " Enough of that; you want to see what else is going on." instead.

Before researching with the internet about museum during Observation, try examining the laptop instead.

Before searching something during Preparation, try examining the noun instead.

Before switching on when the noun is either the music or laptop during Observation, say "The laptop is already on, playing music." instead.

Before switching off when the noun is either the music or laptop during Observation, say "You decide that there's no reason to turn off the laptop; you might need it for information, and you're enjoying the festive music." instead.

Before switching off when the noun is the monitors or the noun is a room-proxy during Observation, say "The monitors stay on; they're why you're here." instead.

Before switching on when the noun is monitors or the noun is a room-proxy during Observation, say "They are always on." instead.

Before taking the rat when location contains noun, say "Gross." instead.

Before taking inventory, say "This place has a very interesting and vast inventory of the weird and macabre." instead.

Before taking something which is not the punch during Preparation:

if the noun is a person, say "[The noun] didn't volunteer to sit in the Fly Eye with you." instead;

if the noun is the refreshment table and the player's command does not include "table", say "You had enough to eat at dinner." instead;

say "The only thing you really want to take is your turn in the Fly Eye." instead.

Before taking the punch:

if the punch is carried, say "One at a time." instead;

if the punch has been carried, say "Too much alcohol might impair your judgment, and punch without booze is a child's drink." instead;

try drinking the noun instead.

Before taking something during Observation:

if the noun is the laptop, say "Your phone works well enough." instead;

say "The only thing you want is to watch the screens." instead.

Before talking to a personable thing when the noun is not in the location during Preparation, say "You know [the noun] [are] around somewhere, but you don't see h[if noun is a woman]er[otherwise]im[end if]." instead.

Before talking to distracted nun, say "You're unlikely to get a word in when she is preaching her Word." instead.

Before talking to Frankie when Frankie is not in the location during Observation, say "The monster isn't around." instead.

Before talking to Frankie when Goldie is following fright storyline during Observation:

unless Frankie has spoken of the leprechaun, try discussing leprechaun with Frankie instead.

Before talking to Frankie when Goldie is following greed storyline during Observation:

unless Frankie has spoken of the medicine man, try discussing medicine man with Frankie instead.

Before talking to Frankie when Goldie is following curse storyline during Observation:

unless Frankie has spoken of Cleopatra, try discussing Cleopatra with Frankie instead.

Before talking to Frankie when Goldie is following threads during Observation:

unless Frankie has spoken of the museum, try discussing the museum with Frankie instead.

Before thinking during Preparation, say "[i]I think I better get to the Fly Eye.[/i] [lb]" instead.

Before thinking when Goldie is thinking about the conclusions, try conceiving a narrative instead.

Before touching or taking the rat, say "Flies usually like rotting meat, but you aren't one of them." instead.

Before turning monitors during Observation, try turning playroom instead.

Before turning music during Observation, try turning laptop instead.

Before turning volume on something to level understood:

if level understood is low, try turning down volume on second noun to 1 instead;

try turning up volume on second noun to 2 instead.

Before waiting for more than 1 turn, say "You can't wait [if Preparation is happening]to get to the Fly Eye[otherwise]to see what is going to happen[end if]." instead.

Before waiting, try looking instead.

Last before doing something other than conversing or dancing or examining or exiting or Heading out of or listening or looking or pondering or researching with or replaying or talking to or touching or turning:

unless turning up volume on to or turning down volume on to begin;

if Preparation is happening or (Observation is happening and not replaying), follow the default handling rule instead;

end unless.

The access through barriers rule is not listed in any rulebook.

Instead of discussing hunched back with Nun during Preparation, say "You don't feel comfortable talking about her deformity, because it could be real. And a real issue.".

Instead of doing something other than conversing or listening to or pondering when screentime is not 0 and (the noun is a personable thing and the noun is currently elsewhere and entry screentime in the hangouts of the noun is event stage) or (the noun is enclosed by a personable thing and the holder of noun is currently elsewhere and entry screentime in the hangouts of the holder of noun is event stage):

unless noun is personable, now noun is holder of noun;

say "You can't see [the noun] anymore. You can watch [them] again if you REPLAY monitor [number-name of event stage].".

Instead of doing something other than conversing or examining or heading out of or listening to or remembering specifically or replaying or thinking about or turning up volume on or turning down volume on when a room-proxy (called locale)is involved:

say "[i][The locale] is a room,[/i] you think. [i]There's not much to do with it except ask someone about it or watch its monitor.[/i] [lb]".

Instead of doing something other than examining or talking to or conversing when the guests are involved or the gals are involved or the guys are involved:

if Preparation is happening, say "You've seen as much of them as you want to see, and you figure there isn't much else to do with them.";

otherwise say "[if location contains Frankie]You and Frankie are the only Fortean members [otherwise]You're the only society member [end if]here.".

Instead of doing something other than discussing or examining when the noun is the museum, say "You're here to watch what happens in its haunted rooms, that's all.".

Instead of examining the camera during Preparation, say "You're not sure whether or not this room has a camera, but you know that all of them are wired to the monitors in the Fly Eye."

Instead of examining the camera:

if event played out is true, try examining the event stage;

if realizations is {} begin;

try looking;

otherwise;

say "You just watched the footage of camera [number-name of event stage], but there are four others to choose from.";

end if.

Instead of examining on-screen leprechaun when screentime is 1 and event played out is false and entry 1 in realizations is playroom, say "He's hidden in the toybox.".

Instead of examining the furniture, say "[if Preparation is happening]The people are much more interesting[otherwise]Each room on the monitors has its own set of unique furniture, so you'll need to be more specific[end if].".

Instead of examining the monitors during Preparation, say "All the monitors are in the Fly Eye.".

Instead of examining the museum:

if screentime is 0, try looking;

otherwise try replaying event stage.

Instead of examining the Fly Eye during Observation, try looking.

Instead of examining a room-proxy during Preparation:

if the noun is Ballroom, try looking;

otherwise say "You'll need to go to the Fly Eye to study the other rooms.".

Instead of examining a center-stage thing when event stage is Playroom and screentime is 6 and the noun is not Playroom, say "You can't make out any detail in the distorted colors on the screen.".

Instead of examining when the noun is either Frankie or the pirate during Preparation:

now the noun is examined;

if the noun is Frankie, say "Parry. Thrust. Swipe. Frankie uses the pirate's cutlass to battle enemies that exist only in his mind. He also takes a swipe at nearby soul dancers when they appear, his blade slicing through their bodies to no effect. [description of Frankie's disguise] [lb]";

otherwise say "The pirate tries to take the cutlass from Frankie, but an eyepatch over the buccaneer's left eye and the wooden leg protruding from the knee of his left pantleg impede his efforts. The toucan on his shoulder swings stiffly with every wobbly step and gyration. It's difficult to tell if the prosthesis is real; he could be bending his leg and hiding it in his baggy pants. ".

Instead of examining when the noun is either Black Widow or Cleopatra during Preparation:

now the noun is examined;

if the noun is Black Widow, say "With slight smiles, Black Widow occasionally acknowledges other costumed guests before returning her attention to Cleopatra beside the stage. [description of BW's-disguise] [lb]";

otherwise say "With arms crossed and a scowl, Cleopatra is standing in front of a darkened section beside the stage. She stares down anyone who passes her by. [description of queen's disguise] [lb]".

Instead of examining when the noun is either Nun or scientist during Preparation:

now the noun is examined;

if the noun is Nun, say "[if the Nun is not distracted]The attractive nun is standing in front of the refreshment table and sipping from her plastic cup of punch. She occasionally rubs her stomach, or maybe she is just making sure it stays in position[otherwise]Arms flailing and head nodding, the nun preaches to the scientist[end if]. [description of the nun's disguise] [lb]";

otherwise say "[unless the scientist is spotted and the scientist was spotted]He[otherwise]The scientist[end if] has secreted himself far from the crowds and the speakers[if the nun is distracted] but, apparently, not far enough: The nun has him cornered, and she preaches to him with her head bobbing and her arms flailing, like a woman possessed[otherwise]. He even seems oblivious to the spirited soul dancers who step and sway nearby[end if]. [description of the brainiac's-disguise] [lb]".

Instead of examining when the noun is either Piper or piper's disguise during Preparation:

now the noun is examined;

say "This isn't the exterminator who arrived in Hamelin in his multicolored garb to free the streets and houses of vermin. Rather, the man on the stage wearing green and a pointy feathered cap and with candy wrappers and a bag at his right hand reminds you of the spiteful musician who led Hamelin's children astray. He is still hypnotizing people with his music, but his weapon of choice is a laptop, not the flute hanging around his neck.".

Instead of examining the monitors:

if event played out is true begin;

try looking;

otherwise;

say "You watch the monitors. ";

carry out the teasing activity;

say lb;

end if.

Instead of examining when the noun is either the guests or the guys or the gals, try looking.

Instead of exiting during Preparation:

unless nun is distracted, say "The nun waves to you as you begin toward the hall outside. She strides off, targeting [if scientist is not spotted]a man with spiky white hair and wearing a lab coat. The scientist [otherwise]the white-haired scientist, who [end if]takes a few steps back and stares at the floor. [pb]";

say "You head out the double doors, descend the stairs, and enter the small room nicknamed, for tonight, the Fly Eye.";

if glulx sound is supported, stop the background sound;

now Techno-Celebration is off-stage;

choose a song;

move Goldie to Flyeye-rm;

now every person in Ballroom-rm is off-stage.

Instead of exiting during Observation, say "You think the best way to see something interesting tonight is to keep watching the monitors.".

Instead of talking about "goodnight/goodbye/bye" with a personable thing:

if Preparation is happening and the second noun is the nun begin;

if the nun has not spoken begin;

say "You wave to the nun, and she waves back.";

otherwise;

say "'See you around,' you say. [pb]The nun nods. ";

follow the nun running off rule;

end if;

rule succeeds;

end if;

if Observation is happening and the second noun is Frankie and location contains Frankie begin;

say "You'd like to, but you decide to stay at your post, and you doubt he would leave anyway.";

otherwise;

try talking to the second noun;

end if.

Instead of listening to an on-screen thing when noun is not a room-proxy:

if the noun is the guests begin;

say "[if Preparation is happening]The music masks most of the conversations[otherwise]You can't hear any of the Fortean members in the ballroom[end if].";

rule fails;

end if;

if screentime is 0 begin;

say "The only sound is the music playing on the laptop.";

rule succeeds;

end if;

if the noun is a person begin;

if event played out is false or the noun is center-stage begin;

say "[The noun] doesn't make any sound[unless entry screentime in hangouts of the noun is playroom] as [entry screentime in hangouts of noun] isn't wired for sound[end if].";

otherwise;

say "You can't hear [the noun], wherever [if noun is a woman]s[end if]he is.";

end if;

rule succeeds;

end if;

say "As far as you know, [the noun] [do]n't make sounds.".

Instead of looking when Ballroom-rm contains the player:

now Goldie is aware of characters;

say "[description of Ballroom-rm] [lb]".

Instead of talking to distracted nun when nun is finished talking, say "She is busy rolling her eyes and shaking her head as the scientist talks to her.".

Instead of talking to the nun when the noun has spoken about Fly Eye or the noun has spoken about the scientist during Preparation:

let dialogues be table of Nun's Conversation threads;

repeat through dialogues begin;

if (Topic Proxy entry is "noises" and the nun has spoken about Fly Eye) or (Topic Proxy entry is "mission" and nun has spoken about the scientist) begin;

unless there is a Spoken Status entry begin;

say "[Conversation entry] [lb]";

now Spoken Status entry is spoken-of;

rule succeeds;

end unless;

end if;

end repeat;

continue the action.

Instead of talking to Frankie when Flyeye-rm contains Frankie and (the noun has spoken about Cleopatra or the noun has spoken about medicine man):

repeat through table of Frankie's Conversation threads begin;

if (Topic Proxy entry is "curse" and Frankie has spoken about Cleopatra) or (Topic Proxy entry is "curare" and Frankie has spoken about medicine man) begin;

unless there is a Spoken Status entry begin;

say "[Conversation entry] [lb]";

now Spoken Status entry is spoken-of;

rule succeeds;

end unless;

end if;

end repeat;

continue the action.

Instead of talking to Frankie when Frankie is finished talking, say "You figure you've heard everything he has to say; the monitors are much more interesting.".

Instead of examining when the noun is an artist or the noun is the music, try listening to the noun.

Instead of doing something other than listening or examining when the noun is an artist, say "The only thing you can reasonably do is listen to [the noun].".

Instead of remembering when screentime is 0 during Observation, say "[italic type][if the nun has spoken of Fly Eye]The nun thought it would be fun to follow some of these characters around[otherwise]This place is supposedly haunted by some kids[end if].[roman type] [lb]".

Instead of remembering specifically Frankie during Observation, say "[if Flyeye-rm contains Frankie]Frankie watches the characters on the screens[otherwise if Flyeye-rm contained Frankie]Frankie was mesmerized by the action on the monitors[otherwise]He is probably bothering guests elsewhere[end if].".

Instead of remembering specifically a personable thing which is not Goldie when screentime is 0:

say "[if Goldie is not aware of characters]It's probably a good idea to check the monitors for [the noun]; the last time you saw [them] was in the ballroom[otherwise if the noun is on-screen][i]Maybe [the noun] will do something interesting if I continue to watch [them],[/i] you think[otherwise][i][The noun] [are]n't on any of the monitors, so I could watch someone else for now,[/i] you think[end if].".

Instead of remembering specifically a personable thing which is not Goldie when screentime is 0 and location is Ballroom-rm:

say "[first time]Everyone went to dinner at a restaurant before continuing the party at the mansion, [only]";

say "[one of][if the location does not contain noun and the noun is not spotted scientist]but y[otherwise]and [the noun],[end if][or][if the location does not contain noun and the noun is not spotted scientist]Y[otherwise][The noun],[end if][stopping]";

say "[if location does not contain the noun and the noun is not spotted scientist]ou're not sure where [the noun] has gone[otherwise] like many of the guests, has remained in the ballroom[end if].".

Instead of remembering specifically something when screentime is 0, say "The people here are more likely to make memories than are the things.".

Instead of talking about "[blowgun]" with Frankie during Observation:

if Frankie has spoken of medicine man, continue the action;

say "You decide it isn't worthwhile to engage Frankie's impaired cognitive abilities with topics that don't seem relevant right now.".

Instead of talking about "curse/expedition/temple" with Frankie during Observation:

if Frankie has spoken of Cleopatra, continue the action;

say "[one of]'Do you think Harrison was cursed?' you say. 'With him being an archaeologist, and what happened to his family?' [pb]Frankie shakes his head. 'Just bad luck. Nothing more.'[or]Frankie doesn't appear to believe in curses, so you don't pursue the matter.[stopping] [lb]".

Instead of talking to someone who is not the player when the noun is not the nun during Preparation :

if the noun is:

-- Black Widow: say "She seems more intent on studying Cleopatra.";

-- Cleopatra: say "She doesn't seem to be in the mood for talking.";

-- Frankie: say "You don't want to get close to a drunk wielding something that could be sharp.";

-- the pirate: say "You decide to let the pirate focus on getting his cutlass back.";

-- Pied Piper: say "He is bobbing his head as if he is enjoying the music, so you don't want to bother him.";

-- Cleopatra: say "She is at the other side of the ballroom, and you decide you don't have time to make your way over there.";

-- the scientist: say "[if the nun is distracted]He looks like he would like a distraction from the nun, but you don't want to interfere lest she call upon a higher power[otherwise]He seemed rather quiet at dinner, and you don't want to waste time trying to engage someone who doesn't seem too interested in talking[end if].".

Instead of talking to a personable thing when the noun is not the player and (location does not contain Frankie or (location contains Frankie and noun is not Frankie)) during Observation, say "There's no way of communicating with someone who is in another room.".

Instead of conversing when the second noun is either the guys or the gals or the guests, try talking to the second noun.

Instead of talking to when the noun is either the guests or the guys or the gals, say "[if Preparation is happening]Nobody is paying much attention to you[otherwise]You can't talk to anyone outside of this room[end if].".

Instead of talking to an animal, say "[if the noun is the cat]You don't expect any comment from the cat[otherwise]The rat is in no condition to do anything[end if].".

Instead of conversing when the second noun is an animal, say "[if the noun is the cat]You don't expect any comment from the cat[otherwise]The rat is in no condition to do anything[end if].".

Instead of researching with Facebook about something when the second noun is a spirit animal or the second noun is the totems during Observation, say "Facebook probably won't have the best information [the noun], you realize.".

Instead of researching with the laptop about something during Observation, try researching with the internet about the second noun.

Instead of researching with something about the totems during Observation:

say "You [if the noun is the mobile phone]take out your phone [otherwise]open a new window in the browser [end if]and do a Google search for the totems you've seen on the medicine man's staff: ";

repeat with figurine running through spirit animals begin;

say " [significance of figurine]. ";

end repeat;

say "[pb]You [if the noun is the mobile phone]put the phone back in your pocket[otherwise]close the Google window, and the museum's webpage reappears[end if].";.

Instead of researching with something about a spirit animal when the noun is either the internet or the mobile phone during Observation:

say "You [if the noun is the mobile phone]take out your phone [otherwise]open a new window in the browser [end if]and do a Google search for [second noun], with regard to totems: [significance of the second noun]. [pb]You [if the noun is the mobile phone]put the phone back in your pocket[otherwise]close the Google window, and the museum's webpage reappears[end if]";.

Instead of thinking about Fly Eye during Observation, say "[i]Which room should I look at?[/i] [lb]".

Instead of touching Frankie during Observation, say "Not even if it would prove the existence of an afterlife.".

Instead of touching something during Preparation, say "You don't really have time to be touching things.".

Instead of turning a room-proxy which is not playroom during Observation, say "Only the playroom on monitor 5 is wired for sound.".

After discussing something with Frankie when (the noun is either Cleopatra or leprechaun or medicine man or the noun is museum) and location contains the cat, now cat is off-stage.

After examining a room-proxy when screentime is seven:

say "Someone stomps toward the door to the Fly Eye. [pb]Press a key to whirl around and face the door.";

wait for any key;

play the sound of dolly in foreground with loop;

say "A doll the size of a small girl is sitting on the floor next to the door and with the black[unless we have touched the cat]-and-white[end unless] cat covering her lap. She smiles a black line under red freckles. She shakes as the cat raises its head and Frankie stomps into the room. The doll begins saying 'Mama . . . mama . . . mama . . . [pb]Frankie's voice booms. 'We have a problem. Everyone's meeting in the ballroom.' [pb]Press a key to follow Frankie out.";

wait for any key;

if glulx sound is supported begin;

stop the midground sound;

stop the midground 1 sound;

stop the midground 2 sound;

stop the foreground sound;

end if;

now Goldie is thinking about the conclusions;

say "Outside the mansion, paramedics lift Greg into an ambulance. [if Goldie is aware of the last teasers and entry 7 in realizations is ballroom]The resuscitation attempts by the nun may have saved his life. [otherwise]In the ballroom, the nun had been performing CPR on Greg. He was deathly pale, and his hair was white. The nun may have saved his life. [end if]But from what? [if entry 7 in realizations is ballroom]you know Greg wasn't shot. The bullet holes in the cape were part of the Rasputin costume, and [end if]Greg had no visible wounds. [pb]Everyone seems to have gathered around the lights cast by the mansion and its exterior lamps. Black Widow and Cleopatra, both in tears, tell their stories to a police officer. The medicine man places his staff into the trunk of a car before finding the scientist. They talk and wait. The leprechaun watches the paramedics, but the sasquatch stares at the ground. [pb]";

if the MIB is identified or the gray is identified, say "Someone is missing, though . . . You don't see the [if MIB is identified and the gray is identified]man in black or his gray partner[otherwise if MIB is identified]man in black[otherwise]gray[end if]. [pb]";

say "The ambulance drives away. Cleopatra points at you, and the officer she was talking to nods. It's time to tell your story";

if Goldie is following threads begin;

say ", but you can't make any reasonable connections between what happened to Greg and what you saw on the monitors. Maybe the events would have come together more clearly had you watched from a different perspective.";

try going home;

otherwise;

say ". The monitors gave you enough information to explain Greg's fate, but some questions remain. Would your story be different had you watched from another perspective? You can either be satisfied with your own imagining and say GOODNIGHT, or you could THINK about the events and conceive a narrative.";

end if.

After listening during Preparation, say "The Pied Piper plays music from the stage.".

After listening during Observation:

if Goldie is not aware of playroom audio and screentime is less than 3 and event played out is true begin;

say "[if screentime is 1]The leprechaun speaks: '[sequence 1 dialogue 1].' A pause and he continues, '[sequence 1 dialogue 2].'

[pb]'[sequence 1 dialogue 3].' That sounded like the sasquatch. [pb]The leprechaun says, '[sequence 1 dialogue 4].' [otherwise]Rasputin continues to speak: '[sequence 2 dialogue 1]' [pb]'[sequence 2 dialogue 2].' That was the baritone of the sasquatch. He chuckles as a ghost moans. The gravel-voiced leprechaun interrupts, '[sequence 2 dialogue 3].' [end if] [lb]";

now Goldie is aware of playroom audio;

otherwise;

say "[if screentime is greater than 5]Despite the static, you can hear the laptop playing[otherwise]The laptop below the screens plays a song you recognize:[end if] '[a random current song].' [lb]";

end if.

After listening to playroom when screentime is 6:

say "Static blares from the playroom feed.".

After listening to playroom:

say "The feed is silent.".

After listening to a room-proxy, say "Monitor [number-name of noun] is not transmitting sound.".

After touching the cat, say "You run your hand down its back[unless location contains Frankie], and the cat raises its head[end if]. [one of]There's something wrong with its fur. The white color is rough, unlike the soft black. The stripe is dry paint[or]It licks your hand[stopping].".

After touching the player, say "You adjust one of your legs and check your antenna.".

Chapter - Specific Action-processing Rules from Standard Rules

The carrying requirements rule does nothing.

The examine containers rule does nothing.

the examine devices rule does nothing.

the examine supporters rule does nothing.

[We use the adaptive text substitutions in these rules since they are most likely to be transferred to other games. However, the grammar used here, which works for this game, needs to be changed to fit every POV and tense.]

Check examining an on-screen thing when event played out is true during Observation:

unless noun is center-stage begin;

if the noun is a person, say "[We] [do]n't see [regarding the noun][them] on the monitor." instead;

say "[We] [do]n't see [the noun] in [the event stage] or in the Fly Eye." instead;

end unless.

Check examining something when the location of the noun is not Flyeye-rm during Observation:

if Goldie is not aware of characters or (Goldie is aware of characters and the noun is off-screen and location does not contain noun) begin;

if Goldie is not aware of characters and screentime is 0 and noun is a room-proxy begin;

say "[We] [watch] [the noun] in the context of the other rooms. ";

otherwise;

say "[We] [search] for [if the noun provides the property identified and the noun is unidentified][indefinite article of noun] [printed name of noun][otherwise][the noun][end if] on the monitors. ";

now event played out is false;

end if;

carry out the teasing activity instead;

end if;

if the noun is on-screen and the noun is not a room-proxy and noun is not a person and event played out is false begin;

let proxy be the noun;

if noun is enclosed by a person, now noun is the holder of noun;

say "[We] [study] [the noun] in [if noun is a person][the footage of noun][otherwise][location of noun][end if]";

if proxy is enclosed by a person and the description of proxy is not empty, say ", focusing on [the proxy]. [description of proxy] [lb]" instead;

say ". ";

say rpo;

end if.

Check examining the location:

try looking instead.

Check examining the jacket when the gray wears the jacket:

say "The black jacket drapes over the alien like a cape." instead.

Carry out examining a room-proxy during Observation:

if screentime is 6 begin;

if glulx sound is supported begin;

stop the midground 1 sound;

stop the midground sound;

end if;

play the sound of girl giggling too in midground 1 for 4 times;

end if;

if screentime is less than 2 begin;

now Goldie is not aware of playroom audio;

if the noun is Playroom, now Goldie is aware of playroom audio;

if event played out is true and screentime is 1 and creaky door is false begin;

play the sound of door creaking;

now creaky Door is true;

say "The door behind you creaks. You glance back at it. It's still, still in the position you left it. ";

end if;

say "[one of]As events on the other monitors unfold, y[or]Remembering that something could be happening on the other screens, y[stopping]ou [if realizations is not empty and entry screentime in realizations is noun]continue to [end if]watch: [pb]";

end if;

if event played out is true and screentime is 2 and dropped book is false begin;

play the sound of book falling;

now dropped book is true;

say "Something thumps onto the hallway floor. You wait but only hear '[Comment corresponding to an Artist of Jim Stafford in the Table of Halloween Songs]' from the laptop, so you resume watching: [pb]";

end if;

follow the event description rules for the noun;

if thought mode is toggled on, follow the event interpretation rules for the noun;

say roman type; [Just to be sure it is on.]

choose a song;

rule succeeds.

Last check examining something which is enclosed by a person:

if the description of the noun is empty, now the noun is the holder of the noun.

Carry out examining (this is the new standard examining rule):

if the noun provides the property description begin;

if the description of the noun is not empty, say "[the description of the noun][lb]";

now examine text printed is true;

end if;

if the noun wears a disguise and the noun is not the player, say "[description of a random disguise which is worn by the noun] [lb]";

if the noun is a disguise, now the holder of the noun is examined;

if the noun provides the property examined, now the noun is examined.

The new standard examining rule is listed instead of the standard examining rule in the carry out examining rulebook. [We can't substitute a rule because the action uses a truth state that is designed specifically for the examining action.]

Check listening to a person:

if the noun is an animal, say "[if the noun is the cat]It purrs softly[otherwise]It's dead silent[end if]." instead;

if the noun is the player, say "[We] [do]n't want to talk to [us]." instead;

say "[The noun] [are] elsewhere." instead.

Check listening to a played song:

say "That isn't playing anymore." instead.

The room description heading rule does nothing.

The announce the score rule response (C) is "[We] [listen] to '[random current song]' playing [if Preparation is happening]from the stage[otherwise]on the laptop[end if].".

Report touching something:

say "You're here to watch, not touch.".

Chapter - Every Turn Rules

Every turn when screentime is either 1 or 2 and event stage is not playroom and event played out is true and Goldie is not aware of playroom audio:

say "[if screentime is 1]The voices of the leprechaun and sasquatch play from the playroom feed[otherwise][one of]A woman screams from monitor 5, which watches the playroom. A trembling voice follows, and you recognize it as the somewhat nasal tones of Rasputin[or]Rasputin continues to speak in the playroom[stopping][end if].".

Every turn when creaky door is false and screentime is 1 and (event stage is Zoo or screentime was 1):

follow the creak the door rule.

This is the creak the door rule:

play the sound of door creaking;

now creaky Door is true;

say "The door behind you creaks. You whirl around. The door is still, still in the position you left it. You think it is, anyway. You stand and swing the door, but it doesn't make a sound. Hearing '[a random current song]' playing from the laptop, you return to your seat.".

Every turn when dropped book is false and screentime is 2 and ((screentime was not 1 and event stage is not Playroom) or (event stage is playroom and screentime was 2)):

unless event stage is Communications and entry 1 in realizations is not Communications, follow the drop the book rule.

This is the drop the book rule:

play the sound of book falling;

now dropped book is true;

say "Something thumps onto the hallway floor. On instinct, you pull your phone from your pocket and look out the door. The guestbook has fallen from the table in the lobby. You wait but don't detect anyone[if (closing or opening or pushing or pulling) and the noun is the double-duty door]. You test the door, and it swings silently. Y[otherwise], so y[end if]ou return to your chair and tuck away the phone as you hear '[Comment corresponding to an Artist of Jim Stafford in the Table of Halloween Songs]' from the laptop.".

Every turn when screentime was 2 and screentime is 3:

say "Something snaps and cracks behind you. You spin around. A black cat with a white stripe down its back tears at a rat on the floor. The cat discards its prey, leaps onto your lap, and settles. It purrs loudly.";

move cat to Flyeye-rm;

move rat to FlyEye-rm.

Every turn when screentime was 3 and screentime is 4:

say "A shadow is cast over you. You swivel around. Frankie's bulk crowds the tiny room. He considers the cat then looks up to you. His grin is crooked. 'What's new, pussycat?' he says. He laughs then starts humming the eponymous Tom Jones song before turning to the monitors. ";

if Goldie is following curse storyline begin;

say "'Stay away from Cleopatra tonight,' he says, nodding at the ballroom.";

otherwise;

if (entry 1 in realizations is Laboratory or entry 1 in realizations is Playroom) and (entry 2 in realizations is Playroom or entry 3 in realizations is Communications) begin;

say "'Nervous guy, that Rasputin. Bit of a wimp, if you ask me. I'm surprised he came out from hiding under his bed tonight.' [lb]";

otherwise;

say "He tries to focus on the monitored characters.";

end if;

end if;

move Frankie to Flyeye-rm.

Every turn when screentime was 5 and screentime is 6:

now playroom is beginning to static;

play the sound of girl giggling in midground;

play the sound of girl giggling too in midground 1 for 3 times;

play the sound of static in midground 2 with loop;

say "A high-pitched scream pierces the Fly Eye. That was from somewhere upstairs. [pb][if location contains the cat]The cat leaps from your lap and scrambles out the door. [end if]Static bursts from the playroom. Are children giggling? [pb]'Gotta check that out,' Frankie says before lumbering away.";

if location contains the cat, now cat is off-stage;

now conversationalist is Goldie;

now Frankie is off-stage;

now the description of Rasputin's disguise is "He's undoubtedly Greg, but his Rasputin-black hair is now white and, come to think of it, shorter. You don't remember his cape having two red holes in it, but they could have been hidden within the fabric's folds.".

Every turn when screentime is 7 and playroom is beginning to static:

now playroom is not beginning to static.

Every turn: follow the Numbered Disambiguation Choices reset disambiguables rule.

At the time when Goldie looks around:

now Goldie is aware of characters;

unless location is Flyeye-rm, say "[description of Ballroom-rm] [lb]".

Test intro with "1 / x nun / talk to nun / exit / thoughts on / l".

Test ballroom with "test intro / 1 / 1 / 1 / 1 / 1 / 1 / 1".

Test look-ballroom with "test intro / 1 / l / 1 / l / 1 / l / 1 / l / 1 / l / 1 / l".

Test Communications with "test intro / 2 / 2 / 2 / 2 / 2 / 2 / 2".

Test look-Communications with "test intro / 2 / l / 2 / l / 2 / l / 2 / l / 2 / l / 2 / l / 2".

Test laboratory with "test intro / 3 / 3 / 3 / 3 / 3 / 3/ 3".

Test look-laboratory with "test intro / 3 / l / 3 / l / 3 / l / 3 / l / 3 / l / 3/ l / 3".

Test zoo with "test intro / 4 / 4 / 4 / 4 / 4 / 4/ 4".

Test look-zoo with "test intro / 4 / l / 4 / l / 4 / l / 4 / l / 4 / l / 4/ l / 4".

Test playroom with "test intro / 5 / 5 / 5 / 5 / 5 / 5/ 5".

Test look-playroom with "test intro / 5 / l / 5 / l / 5 / l / 5 / l / 5 / l / 5/ l".

Test curse with "test intro / turn off sound / 1 / 2 / 3 / 1 / 2 / 1".

Test fright with "test intro / 5 / 5 / 4 / 2 / 2 / 2".

Test greed with "test intro / 3 / 5 / 2 / 2 / 2 / 1".

Test think-curse with "test intro / 1 think about cleopatra / l / think about cleopatra / 2 / think about cleopatra / l / think about cleopatra / 3 / think about cleopatra / l / think about cleopatra / 1 / think about cleopatra / l / think about cleopatra / 2 / l / think about cleopatra / 1 / l / think / 1".

Test think-fright with "test intro / 5 / l /think / 5 / l /think / 4 / l / think / 2 / l / think / 2 / l / think / 2 / l / think / 1".

Test think-greed with "test intro / 3 / l / think / 5 / l / think / 2 / l / think / 2 / l / think / 2 / l / think / 1 / l / think / 1".

Test follow-char with "test intro / l / follow leprechaun / l / follow sasquatch / l / follow leprechaun / l / follow leprechaun / l / follow widow / l / follow leprechaun / l / follow widow".

Test look-curse with "test intro / 1 / l / 2 / l / 3 / l / 1 / talk to frankie / l / 2 / l / 1 / l / 1".

Test look-fright with "test intro / 5 / l / 5 / l / 4 / l / 2 / talk to frankie / l / 2 / l / 2 / l / 5".

Test look-greed with "test intro / 3 / l / 5 / l / 2 / l / 2 / l / talk to frankie / 2 / l / 1 / 4".

Test hauntings with "test intro / 5 / 5 / 2 / 4 / 1 / 2 / 5 ".