gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for A Fly on the Wall, or An Appositional Eye

Book - Activities, Rules, and Actions

Chapter - Activities

Section Activities from Standard Rules

The display banner rule is not listed in any rulebook.

Rule for printing the banner text:

say "[b][story title][/b] [story headline] by Nigel Jayne. Release [release number]. [lb]Copyright [unicode 169] [story copyright string] by [story author]. The license is under a Creative Commons attribution, CC BY-NC 4.0 [fixed letter spacing](https://creativecommons.org/licenses/by-nc/4.0/)[variable letter spacing]. [lb]Serial number [story serial number] / Inform 7 build [I7 version number].".

Rule for constructing the status line:

stop.

Before listing nondescript items of a room:

now every marked for listing thing is not marked for listing.

First after reading a command:

remove stray punctuation.

After reading a command when (the player's command matches "x/examine [a number]" or the player's command matches "look at [a number]", or the player's command matches "[a number]") and (the number understood is greater than five or the number understood is less than one) during Observation:

say "There are [if the number understood is greater than five]only [end if][(number of room-proxies minus 1) in words] monitors on the wall, and they are numbered from one to five.";

reject the player's command.

After reading a command when (the player's command matches "x/examine [a number]" or the player's command matches "look at [a number]", or the player's command matches "[a number]") and Ballroom-rm contains the player:

say "You don't see anyone dressed as a number, or wearing a number.";

reject the player's command.

After reading a command when player is yourself and the player's command matches "1/one/continue/start":

say "A green-skinned man with a stitch across his forehead lumbers toward you, two jumper cables swinging from his chest. Frankie bumps into Cleopatra standing next to the stage, sending her to the floor and knocking the headdress from her head. He extends his hand down to her, but she swats it away and glowers. Black Widow, a woman dressed in black with a red hourglass symbol on her back, picks up the headdress. Cleopatra snatches it back, stands, and returns to her spot beside the stage. [pb]Frankie stops in front of you. [i]Are those batteries attached to opposite sides of his neck? [/i] you wonder. As Frankie speaks, his chin taps at the antenna protruding up from your forehead, and his breath suffocates your nose with alcohol. 'Our whorey sister over there has sent me.' He gestures erratically behind him. A nun with a hunched back bends over the punchbowl by the stage. You think he must have said 'holy' sister, not 'whorey.' [pb]The nun straightens and turns around to face you. She rests her cup of punch on her pregnant belly. [pb]'She told me it's your turn in the Fly Eye, Goldie,' Frankie says. [pb][i]Goldie? [/i]you wonder. [i]My name isn't Goldie.[/i] Then you realize that, despite the alcoholic soup bathing his brain, Frankie connected your costume with the eponymous horror film, Goldie being a contraction of its star's surname, Goldblum. [pb]Frankie retreats toward Cleopatra. Arms crossed, she stands firm. Frankie stumbles away, passing Black Widow who, head cocked, watches Cleopatra. [pb]You glance at the double doors and consider making your exit to the Fly Eye, but the nun attracts your attention. She smiles and raises her cup in salute.";

now player is Goldie;

now yourself is off-stage;

reject the player's command.

[We need this because "think" is interpreted as "think about" and it produces a disambiguation error.]

After reading a command when the player's command matches "muse/ponder/think":

change the text of the player's command to "ruminate".

After reading a command when player is yourself and mn_menupresent is false:

if (the player's command matches "[a number]" and the number understood is greater than zero and the number understood is less than four) or the player's command matches "restart/load/look/l" or the player's command matches "[helpers]" begin;

if the number understood is two or the player's command matches "[helpers]", change the text of the player's command to "help";

if the number understood is three or the player's command matches "restore/load", change the text of the player's command to "restore";

otherwise;

say introductory options;

reject the player's command;

end if.

Include (-Replace PrintInferredCommand;[ PrintInferredCommand; ];-) before "Parser.i6t". [This removes parenthetical confirmations when the parser fills in a second noun or chooses an object (in this case, the parser does this before the "supplying a missing noun/second noun" activity and "Does the player mean."]

The disambiguation printing rule response(A) is "You will need to be more specific. ".

The disambiguation printing rule response(C) is "[We] [wonder] which one [we] [want] to [print-or-construct]: ".

The disambiguation printing rule response(E) is "[We] [ponder] [our] options. ".

The disambiguation printing rule response(G) is "[We] [wonder] which one [we] [want] to [print-or-construct]: ".

Rule for printing a parser error when the latest parser error is the can't see whom to talk to error:

say "[We] don't recognise anyone that resembles whom you have in mind.".

Rule for printing a parser error when the latest parser error is the can't talk to inanimate things error:

say "There isn't anyone dressed up like that.".

Rule for printing a parser error when the latest parser error is the only understood as far as error:

let candidate be the accessible text of the player's command;

if candidate matches the regular expression "\w\w\w's\s\w", say "[We] can't distinguish that as part of the costume.";

otherwise say "[We] [decide] that action doesn't need all those words.".

Rule for printing a parser error when the latest parser error is the can't see any such thing error:

say "[We] [have] seen many things here tonight, from the mundane to the bizarre, but nothing like that. Yet.".

Rule for printing a parser error when the latest parser error is the not a verb I recognise error:

say "[We] [decide] that some actions are inappropriate,[if screentime is 7] especially at this time[otherwise]even in a place like this[end if].".

Rule for printing a parser error when the latest parser error is the can't use multiple objects error:

say "Your other four appendages are fake, so you decide to act on only one thing at a time.".

Rule for printing a parser error when the latest parser error is the I beg your pardon error:

say "You zone out for a second and do nothing.".

Rule for printing a parser error (this is the default handling rule):

if Preparation is happening begin;

unless the nun is distracted begin;

say "Cradling the drink resting on her belly, the nun continues to smile at you, and y";

otherwise;

say "[if the nun is involved]With the nun engaged, y[otherwise]Y[end if]";

end unless;

say "ou decide that your priority is the Fly Eye.";

otherwise;

say "[if screentime is 7]You can CONCEIVE a narrative or say GOODNIGHT. [otherwise][i]Focus on the cameras,[/i] [we] [think]. [i]I don't want to miss anything.[/i][end if] [lb]";

end if.

Rule for supplying a missing noun:

say "And [we] [decide] to do that to . . . [lb]".

Rule for supplying a missing second noun:

say "[We] [decide] to finish that action using . . . [lb]".

Rule for clarifying the parser's choice of something:

stop.

Chapter - New Rulebooks

Teasing is an activity.

Before teasing when Goldie is not aware of characters:

now Goldie is aware of characters.

Before teasing when screentime is 1 and event played out is false:

now Cleopatra is trailer-spotted.

Before teasing when screentime is either 2 or 3 and event played out is false:

if screentime is 3 begin;

now MIB is trailer-spotted;

now devil is trailer-spotted;

now player is aware of jacketed MIB;

end if;

now medicine man is trailer-spotted;

now leprechaun is trailer-spotted;

now sasquatch is trailer-spotted;

now Goldie is aware of the doll.

Before teasing when screentime is 4 and event played out is false:

now gray is trailer-spotted.

Before teasing when screentime is 5 and event played out is false:

now leprechaun is trailer-spotted;

now sasquatch is trailer-spotted;

now MIB is trailer-spotted;

now nun is trailer-spotted;

now Widow is trailer-spotted.

Rule for teasing:

now contemplative mood is false;

let teaser be the transition events of event stage;

if event played out is true begin;

if there is a Trigger Time of Screentime in teaser, say "[Event corresponding to a Trigger Time of screentime in teaser] ";

otherwise;

let room counter be 1;

repeat with selection running through room-proxies begin;

unless selection is Fly Eye begin;

now teaser is the transition events of selection;

say "([room counter]) [if selection is ballroom][set link 1][selection][end link][otherwise if selection is communications][set link 2][selection][end link][otherwise if selection is laboratory][set link 3][selection][end link][otherwise if selection is zoo][set link 4][selection][end link][otherwise][set link 5][selection][end link][end if]: ";

if there is a Trigger Time of Screentime in teaser begin;

say "[Event corresponding to a Trigger Time of screentime in teaser] ";

otherwise;

if selection is ballroom begin;

say "[if screentime is 1]Guests continue to mingle[otherwise if screentime is 2]Some guests mingle at the refreshment table[otherwise if screentime is 4][one of]A couple of dancers materializes, jitterbugs, and disappears[or]The crowd has thinned[stopping][otherwise]Guests mingle in front of the stage and refreshments[end if]. ";

otherwise;

say "Vacant. ";

end if;

end if;

say pb;

increment room counter;

end unless;

end repeat;

end if;

if event played out is false and screentime is 6, now Goldie is aware of the last teasers.

After teasing when watched trailer is false:

now watched trailer is true.

Event Description is an object-based rulebook.

[These are descriptions of what is happening on the screen the player chooses to watch.]

Table of User Styles (continued)

style namecolor
special-style-1"#FFA500"

First event description rule for something (called sequence):

say "[special-style-1][sequence][roman type] ([if sequence is Laboratory]third floor, west[otherwise if sequence is Ballroom]second floor, east[otherwise if sequence is Communications]second floor, west[otherwise if sequence is Zoo]second floor, north[otherwise]main floor, west[end if] wing) [unless screentime is 7][lb][set link 6](watch all monitors)[end link][end unless][pb]";

if not replaying begin;

if sequence is Communications and the number of entries in realizations is greater than 2 and entry 2 in realizations is not Communications, say "[first time]Something is different about the room . . . The lighting has dimmed, and shadows shroud the corners. [pb] [only]";

add sequence to realizations;

if (event played out is true) or (screentime is 0 and watched trailer is false), carry out the teasing activity;

increment screentime;

if screentime is greater than 1 begin;

unless screentime is 7 or (screentime is 2 and Goldie is following greed storyline) begin;

if (Goldie is following curse storyline and entry screentime in realizations is not entry screentime in curse events) or (Goldie is following fright storyline and entry screentime in realizations is not entry screentime in fright events) or (Goldie is following greed storyline and entry screentime in realizations is not entry screentime in greed events), now Goldie is following threads;

end unless;

end if;

end if.

Event interpretation is an object-based rulebook. The event interpretation rulebook has default success.

[These are Goldie's thoghts of what is happening on-screen.]

First event interpretation rule for something (called notable):

now contemplative mood is true;

if Goldie is thinking of previous event and not remembering and not remembering specifically begin;

say "You remember ";

otherwise;

if there is a Trigger Time of (screentime minus 1) in the transition events of the notable begin;

unless (screentime is 2 and notable is Laboratory) or (screentime is either 6 or 7 and notable is playroom) or (screentime is either 4 or 6 and notable is Zoo) begin;

if remembering or remembering specifically begin;

say "[if need a line break is true][pb][otherwise][lb][end if] [mdash] ";

otherwise;

say lb;

end if;

now need a line break is false;

end unless;

end if;

unless remembering or remembering specifically, say italic type;

end if;

make no decision.

Character recall is an object-based rulebook. The character recall rulebook has default success.

Chapter - New Actions

Section - New Understanding of Standard Grammar

Understand "drink" as drinking.

Rule for supplying a missing noun while drinking or eating:

if the player carries the punch, now the noun is the punch;

otherwise say "You don't have anything suitable to consume.".

Understand "swing [a door]" as closing.

Understand "sit", "sit down", "lie down", and "lay down" as a mistake ("[if Preparation is happening][i]I'll get trampled in this crowd,[/i] you think[otherwise]You're already comfortable in the chair[end if].").

Understand "topic" and "topics" as a mistake ("You can just talk to someone if you don't know what to say.").

Understand "consult [something] for [text]", and "search [something] for [text]" as consulting it about.

Understand "look up [text] with/using/on [something]", "research [text] with/using/on [something]", and "search for [text] with/using/on [something]" as consulting it about (with nouns reversed).

Understand "load" and "load game" as restoring the game.

Understand the command "think" as something new.

Understand the command "pet" as "touch".

Understand the command "shove" as "push".

Understand the command "watch" as something new.

Understand "examine [any room]", "x [any room]", "look at [any room]", "look at [any thing]", "play [any room]", "[any room]", "[any thing]", "examine [any thing]", and "x [any thing]" as examining.

Understand "examine", "look at" and "x" as examining.

Understand the command "investigate" as "examine".

Rule for supplying a missing noun while examining:

if Preparation is happening, say "There are many colorful characters you could look at in here.";

otherwise say "You figure any of the five haunted hotspots on the monitors are worth investigation.".

Understand "all monitors", "look at all/every monitor/monitors", "look around", and "walk around" as looking.

Understand nothing as setting it to.

Understand the commands "adjust" and "set" as "turn".

Understand "re-load", "reload", "re-open", and "reopen" as restarting the game.

Section - Out of World

Conceiving a narrative is an action out of world. Understand "conceive", "narrative", "story", "plot", "plots", "conceive a/-- narrative/story/storyline", "think about what/-- happened/tonight", and "think about a/the/-- events/monitors/narrative/story/storyline" as conceiving a narrative.

Check conceiving a narrative when Goldie is not thinking about the conclusions:

if Preparation is happening, say "You can't think of any good stories to tell about tonight. Not yet." instead;

try thinking instead.

Carry out conceiving a narrative:

if Goldie is following curse storyline, say "Cleopatra didn't want anyone to open the bag she was carrying, because she was hiding something in it. Something she could drop through a hole in the Laboratory's floor. She dimmed the lights in Communications to help conceal it. It could have poisoned Greg. Cleopatra needed to ensure Greg would reach behind those speakers, so she planned to take him to Communications, but he left the ballroom with Black Widow instead. She waited for him to return, not knowing that her scheme had worked, Black Widow an unwitting accomplice. [if Frankie has spoken of Cleopatra]Maybe she blames Greg's father for the death of her family. Or maybe she was acting out the curse, either intentionally or unintentionally[otherwise]Nothing you've seen suggests a motive, though[end if]";

if Goldie is following greed storyline, say "The medicine man was angry with Greg for bumping into him and touching the totems. Greg seemed puzzled by them when he picked up the frog in Communications. Maybe he noticed they had been re-arranged along the staff, as if the medicine man had removed some and hadn't replace them in the same order. Or maybe there was something different about the frog totem itself that made it worth killing for. The medicine man may have also conspired with the scientist. [if Frankie has spoken of medicine man]. Frankie mentioned an exhibit on Mesoamerica. The medicine man could have switched one of his totems for one that had been on display. He was afraid that Greg noticed the discrepancy, and he enlisted the scientist to help him steal the goods. They could have poisoned Greg by putting curare in the bottle[otherwise]You can't figure out how they may have done it, though, or why those totems are important[end if]";

if Goldie is following fright storyline, say "Greg certainly seemed anxious about the mansion and its reputation. Maybe the leprechaun decided to have some fun with the idea. After two unsuccessful attempts, one inside the zoo and one outside Communications, maybe the leprechaun did finally scare Greg with the doll he had taken from the playroom. Or maybe Harrison's daughters really were haunting the mansion tonight, and they frightened Greg[if event stage is Zoo]. The leprechaun could have put the scientist's wig on Greg . . . or maybe the ghosts did[end if ]";

say "[unless (Goldie is following curse storyline and Cleopatra is a Conversation Piece listed in the Table of Frankie's Conversation Pieces) or (Goldie is following greed storyline and Medicine Man is a Conversation Piece listed in the Table of Frankie's Conversation Pieces) or Goldie is following fright storyline]. You wonder how much Frankie knew about what was going on[end unless]. [lb]";

try going home.

Understand "examine", "read", and "x" as "[peruse]".

Displaying cover is an action out of world. Understand "display the/-- cover art/image/page/--", "show the/-- cover art/image/page/--", and "cover art/image/page" as displaying cover.

Check displaying cover:

unless glulx graphics is supported, say "This interpreter doesn't support graphics (Some interpreters that support both graphics and sound include Gargoyle and Windows Glulxe).".

Carry out displaying cover when glulx graphics is supported:

set the justification for special-style-1 to center-justified;

say "[special-style-1]";

say " ";

display figure of gamecover inline;

say " [lb]";

say "[roman type]".

To set the justification for (style - a glulx text style) to (N - a text justification):

(- GTE_SetStylehint( wintype_TextBuffer, {style}, stylehint_Justification, {N} - 1 ); -).

To display (chosen figure - a figure-name) inline:

(- DrawInline({chosen figure}); -)

Include (-

[ DrawInline N;

glk_image_draw(gg_mainwin, ResourceIDsOfFigures-->N, imagealign_InlineUp, 0);

];

-)

Report displaying cover:

say "<b>[mdash] A fly with a large head is standing on a wall in a corner of the room. His eyes are big orange orbs with red stripes. 'A Fly on the Wall' is printed in white along the top of the image. [mdash] </b>".

Table of Perspectives

Perspective (an indexed text)
with 3 blank rows

Going home is an action out of world. Understand "go home", "good bye/night", "say goodbye/goodnight", "goodbye", and "goodnight" as going home when Goldie is thinking about the conclusions.

Check going home:

if file of followed perspectives exists, read File of followed perspectives into the Table of Perspectives;

if the Table of Perspectives is full, blank out the whole of the Table of Perspectives.

Told stories is a list of texts that varies.

Carry out going home:

let followed storyline be "threads";

if Goldie is following curse storyline, now followed storyline is "curse";

if Goldie is following fright storyline, now followed storyline is "fright";

if Goldie is following greed storyline, now followed storyline is "greed";

if the Table of Perspectives is not empty begin;

repeat through the Table of Perspectives begin;

add Perspective entry to told stories;

end repeat;

end if;

unless Goldie is following threads or (the Table of Perspectives is not empty and followed storyline is a Perspective listed in the Table of Perspectives) begin;

choose a blank row in the Table of perspectives;

now Perspective entry is followed storyline;

end unless;

write File of followed perspectives from the Table of Perspectives;

end the story finally saying "[final notice]".

To say final notice:

say "There are three different interpretations of Greg's fate, each dependent upon which character you decide to follow when you settle in the Fly Eye. ";

if Goldie is following threads begin;

say "You didn't follow any of them during your vigil";

otherwise;

say "[if Goldie is following curse storyline]You witnessed Cleopatra's vengeful spirit enact the 'curse'[otherwise if Goldie is following fright storyline]The leprechaun's tricks pulled you into the 'fright'[otherwise]You found some value in watching the medicine man's scheming in the 'breed'[end if] storyline";

end if;

say ". ";

if the number of filled rows in the Table of Perspectives is 3, say "You've [if Goldie is following threads]already[otherwise]now[end if] discovered all of the perspectives ('curse,' 'fright,' and 'greed'). ";

if the number of filled rows in the Table of Perspectives is 2, say "You [if Goldie is not following threads]previously watched the '[entry 1 in told stories]' perspective,[otherwise]seen two perspectives, '[entry 1 in told stories]' and '[entry 2 in told stories],'[end if] so there is one last to discover. ";

if the number of filled rows in the Table of Perspectives is 1, say "[if Goldie is not following threads]There[otherwise]You've seen the '[entry 1 in told stories]' perspective, so there[end if] are two more to discover. ";

say "You ";

if haunted manifestations is at least 1 begin;

say "[if Goldie is not following threads]also [end if]witnessed [if haunted manifestations is less than 5][haunted manifestations in words] of the five [otherwise]all of the [end if]phenomena occurring tonight that are typically reported as hauntings. You decide how much influence, if any, [if haunted manifestations is 1]it[otherwise]they[end if] had on the night's events";

otherwise;

say "[if Goldie is following threads]also [end if]didn't witness any phenomena that are usually reported at haunted sites";

end if;

say ".".

Carry out restarting the game:

if glulx sound is supported begin;

stop the midground sound;

stop the midground 1 sound;

stop the midground 2 sound; [Because they continue to play when the player restarts and the sounds have started.]

end if.

Understand "thought", "thoughts", "thought process", "comments", and "commentary" as "[comments]".

Understand "Goldie's [comments]", "my [comments]", and "[comments]" as thought mode.

[These actions could use the standard switching actions instead, with the different modes coded as a device or something in the game. However, we don't want the player to be able to access them except when toggling, and we don't want them to appear on a disambiguation list.]

Toggling on is an action out of world, applying to a game mode. Understand "turn on [game mode]", "t on [game mode]", "t [game mode] on", "[game mode] on", "switch on [game mode]", "switch [game mode] on", "toggle on [game mode]", and "toggle [game mode] on" as toggling on.

Check toggling on game mode understood when game mode understood is toggled on:

if game mode understood is audio mode, say "You should already be able to hear sound effects and music when they are being played." instead;

otherwise say "You should already be able to read Goldie's mind." instead.

Check toggling on audio mode:

unless glulx sound is supported, say "This interpreter doesn't have sound support." instead.

Carry out toggling on game mode understood:

now game mode understood is toggled on;

if game mode understood is audio mode begin;

set all the volumes;

unless Preparation is happening or screentime is greater than 5, play the sound of girl giggling in background;

end if.

Report toggling on audio mode:

say "The audio effects are now active, and [if Preparation is happening]you should hear the piper's music[otherwise if screentime is greater than 5]you should hear static[otherwise]you should hear laughter[end if].".

Report toggling on thought mode:

say "You now have access to Goldie's thoughts.".

Toggling off is an action out of world, applying to a game mode. Understand "turn off [game mode]", "t off [game mode]", "t [game mode] off", "[game mode] off", "switch off [game mode]", "switch [game mode] off", "toggle off [game mode]", and "toggle [game mode] off" as toggling off.

Check toggling off game mode understood when game mode understood is toggled off:

if game mode understood is audio mode, say "The audio effects and music shouldn't be audible." instead;

otherwise say "You shouldn't be able to see Goldie's interpretations right now." instead.

Check toggling off audio mode:

unless glulx sound is supported, say "This interpreter doesn't support sound." instead.

Carry out toggling off a game mode:

now game mode understood is toggled off;

if game mode understood is audio mode, set all the volumes.

Report toggling off audio mode:

say "The audio effects and music won't play anymore.".

Report toggling off thought mode:

say "You now won't be able to see Goldie's interpretations of the night's events.".

Toggling is an action out of world, applying to a game mode. Understand "switch [game mode]", "toggle [game mode]", "t [game mode]", and "[game mode]" as toggling.

Carry out toggling game mode understood:

if game mode

Section - Hints

Understand "about", "guidance", "guide", "guidebook", "help", "info", "information", "instructions", "manual", "menu" as "[helpers]".

Helping is an action out of world. Understand "[helpers]", "info desk", "information desk", and "[peruse] [helpers]" as helping.

Carry out helping:

carry out the displaying activity;

clear the screen;

try looking.

Hinting is an action out of world. Understand "hint", "hints", and "[peruse] hint/hints" as hinting.

Report hinting:

say description corresponding to a title of "Hints" in the Table of Help Options.

Showing author is an action out of world. Understand "author", "about the/-- author/writer" and "writer" as showing author.

Report showing author:

say description corresponding to a title of "About the Author" in the Table of Help Contents.

Showing credits is an action out of world. Understand "acknowledgements", "acknowledgement", "credits", "credit", and "[peruse] the/-- acknowledgements/acknowledgement/credits/credit" as showing credits.

Report showing credits:

say description corresponding to a title of "Acknowledgements" in the Table of Help Contents.

Showing solutions is an action out of world. Understand "solution", "solutions", "tour", "tours", "walkthrough", "walkthroughs", "walkthru", "[peruse] solution/solutions/walkthrough/walkthroughs/walkthru/tour/tours/guided tour/--" as showing solutions.

Report showing solutions:

say description corresponding to a title of "The 3 Perspectives" in the Table of Help Options;

say lb.

Suggesting actions is an action out of world. Understand "action list", "commands", "command list", and "verb list" as suggesting actions.

Report suggesting actions:

say description corresponding to a title of "Commands" in the Table of Help Options.

Section - Within World

Consulting is an action applying to a topic. Understand "google [text]", and "look up [text]", "research [text]" as consulting.

Before consulting text during Observation, try consulting the laptop about the topic understood instead.

Dancing is an action applying to nothing. Understand "dance" and "sing" as dancing.

Check dancing:

if location is Ballroom-rm, say "The fly costume and your limited vocal range prevent you from performing a monster mash tonight." instead;

otherwise say "Even if you really wanted to, this small room isn't the place." instead.

Following is an action applying to one visible thing. Understand "follow [any thing]" and "search for [any thing]" as following.

Understand the commands "trail" and "watch" as "follow".

Understand "picture", "image/images/pic/pics/picture/pictures" and "audio/sound/sounds" as "[recordable]".

Understand "[recordable]" as the monitors.

Preserving it with is an action applying to one topic and one thing. Understand "record a/-- [recordable] of [text] with/using [something]", "take a/-- [recordable] of [text] with/using [something]", "record a/-- [recordable] of [text]", and "take a/-- [recordable] of [text]" as preserving it with.

Rule for supplying a missing second noun while preserving text with:

now the noun is the mobile phone.

Understand the commands "shoot" and "snap" as "record".

Recording is an action applying to nothing. Understand "record [recordable]" as recording.

Before recording, say "[if Preparation is happening]You'll see enough of everyone and everything when you get to the Fly Eye[otherwise]The only things you're interested in are on the monitors[end if]." instead.

Recording it using is an action applying to two things. Understand "take [something] with/using [something]", "snap [something] with/using [something]", "record [something] with/using [something]", and "tape [something] with/using [something]" as recording it using.

Before recording something using something:

unless the second noun is the mobile phone, say "The only thing you have that records is your phone, but you don't want to use it now." instead;

say "The only events worthy of recollection are taking place on the monitors[if Preparation is happening] in the Fly Eye[end if], and they're already being recorded." instead.

Recording it with is an action applying to two things. Understand "record a/-- [recordable] of/-- [something] on/with/using [something]", "take a/-- [recordable] of/-- [something] on/with/using [something]", "record a/-- [recordable] of/-- [something]", and "take a/-- [recordable] of/-- [something]" as recording it with.

Understand "record [something]" as recording it with.

Rule for supplying a missing second noun while recording something with:

now the second noun is the mobile phone.

Researching with it about is an action applying to two visible things. Understand "consult [anything] about/for [anything]", "search [anything] for [anything]", "google [any thing]", "look up [anything]", "research [anything]", and "search for [anything]" as researching with it about.

Understand "look up [anything] with/using/on [an electronic device]", "research [anything] with/using/on [an electronic device]", and "search for [anything] with/using/on [an electronic device]" as researching with it about (with nouns reversed).

Rule for supplying a missing second noun while researching with something about:

now the second noun is the noun;

now the noun is the internet.

First check researching with something which is not an electronic device about something:

say "Only your mobile phone and the computer are capable of doing any kind of research." instead.

Check researching with something about the player:

say "[We] [have] already googled [player]." instead.

Check researching with something about a personable thing:

say "[We] [decide] that creeping people is not why [we][']re here." instead.

Check researching with something about a disguise:

say "The costumes are self-explanatory." instead.

Check researching with something about something:

say "[We] should really focus [our] attention on the screens." instead.

Replaying is an action applying to one visible thing. Understand "play [any thing] again", "replay [any thing]", "rewatch [any thing]", "rewind [any thing]", "watch [any thing] again", "play again", "replay", "rewatch" , "rewind", and "watch again" as replaying.

Rule for supplying a missing noun while replaying:

now the noun is event stage.

First check replaying something when event played out is false:

say "You can't replay all the feeds at once." instead.

First check replaying when screentime is 0 during Observation:

say "You'll need to watch a monitor before you can replay the footage." instead.

Check replaying something which is not a room-proxy when the noun is not a person:

say "[We] can only replay a monitor number or a person [we] just watched." instead.

Check replaying a person:

unless entry screentime in the hangouts of the noun is entry screentime in realizations, say "[if noun is a woman]She[otherwise]He[end if] wasn't on the screen." instead.

Check replaying something when event played out is true:

unless the noun is center-stage, say "[We] [if the noun is a room-proxy]aren't watching [the noun][otherwise]didn't see [the noun] in [the event stage][end if]." instead.

Last check replaying when screentime is 3:

now the props are open.

Carry out replaying something:

follow the event description rules for the noun.

Chapter - Conversation

Understand nothing as answering it that. Understand nothing as asking it about. Understand nothing as telling it about.

To decide whether (dialoguist - a person) is finished talking:

repeat through the Conversation Threads of the dialoguist begin;

unless there is a Spoken Status entry, decide no;

end repeat;

if the number of entries in the pieces discussed of the dialoguist is the number of rows in the Conversation Pieces of the dialoguist, decide yes;

no.

Discussing it with is an action applying to two visible things. Understand "ask [any thing] to/-- [any thing]", "talk about [any thing] to/with [any thing]", "ask for/about/-- [any thing]", "talk about [any thing]", "speak [any thing]", "tell [any thing]", and "say [any thing]" as discussing it with.

Understand "ask [any person] about/-- [any thing]" and "talk to [any person] about [any thing]" as discussing it with (with nouns reversed).

Understand "ask [any thing] about/-- [any thing]" and "talk to [any thing] about [any thing]" as discussing it with.

Check discussing the player with the player:

say "[We] [have] no new insight into [ourselves]." instead.

Check discussing something with the player:

say "[We] [decide] to keep [our] ideas about [the noun] silent." instead.

Check discussing something with something:

if conversationalist is a person and the location does not contain second noun, say "[We] [do]n't see [regarding the second noun][them] around." instead;

unless the second noun provides the property Conversation Pieces begin;

if conversationalist is a person, say "[The conversationalist] doesn't appear interested in talking to [us] right now." instead;

say "There are some rather creative costumes here, but [we] doubt [the second noun] [are] a person in disguise." instead;

end unless;

if the second noun has spoken of the noun begin;

if the second noun is the nun, say "[if the noun is the pregnancy]'Anything more stays between the two of us[otherwise if the noun is the nun]'My secrets stay with me[otherwise]She shrugs. 'I don't have anything more on [the noun][end if],' she says." instead;

if the second noun is Frankie, say "[if the noun is Frankie]He remains silent and shakes his head. [otherwise]He blinks. 'Anything else I know stays with me.' [end if] [lb]" instead;

end if;

unless the noun is a Conversation Piece listed in the Conversation pieces of the conversationalist, say "[if conversationalist is the nun]'What do you think about [the noun]?' you say. [pb]'I don't have anything to say about [the noun],' she says[otherwise]'I can't sort out my thoughts on [the noun] right now, if you know what I mean,' he says[end if]." instead.

Carry out discussing something with something:

add the noun to the pieces discussed of the conversationalist;

choose row with a Conversation Piece of the noun in the Conversation Pieces of the conversationalist;

say conversation entry;

say lb.

Informing about it to is an action applying to two visible things. Understand "tell [any thing] about/to/-- [any thing]" and "tell to [any thing] [any thing]" as informing about it to.

Understand "tell [any person] about/-- [any thing]" and "tell to [any person] [any thing]"as informing about it to (with nouns reversed).

Check informing about the player to the player:

say "[We] [expect] no new insight into [ourselves]." instead.

Check informing about something to the player:

say "[We] [decide] to keep [our] ideas about [the noun] silent." instead.

Check informing about something to something:

if the location does not contain the second noun and the second noun is a person, say "[We] [do]n't see [regarding the second noun][them] around." instead;

if the second noun is a person, say "[The second noun] doesn't appear interested in what [we] [have] to say." instead;

say "There are some rather creative costumes here, but [we] doubt [the second noun] [are] a person in disguise." instead;

Talking about it with is an action applying to a topic and one thing. Understand "ask [text] to [something]", "talk about [text] with/to [something]", "say [text] with/to [something]", "speak [text] with/to [something]", "tell [text] with/to [something]", "ask about/for [text]", "talk about [text]", "speak [text]", "say [text]", and "tell [text]" as talking about it with.

Understand "ask [something] to/about/-- [text]" and "talk to [something] to/about [text]" as talking about it with (with nouns reversed).

Check talking about text with the player:

say "[We] [consider] it from all angles, but you don't draw any new conclusions." instead.

Check talking about text with something:

unless the second noun provides the property Conversation Threads begin;

if the second noun is a person, say "[The second noun] doesn't appear interested in talking to you right now." instead;

say "There are some rather creative costumes here, but you doubt [the second noun] [are] a person in disguise." instead;

end unless;

if topic understood is a topic listed in the Conversation Threads of the second noun begin;

if there is a Spoken Status entry and Spoken Status entry is spoken-of, say "[if the second noun is the nun]She thinks a bit before saying 'I don't have anything more on any of that.' [otherwise]'I've told you what I know,' Frankie says. [end if] [lb]" instead;

end if;

unless topic understood is a Topic listed in the conversation threads of the second noun, say "[if the second noun is the nun][one of]The nun shrugs and smiles. 'Yeah. Yeah.' [or]'Whatever you think,' the nun says. 'I have nothing on that.' [purely at random][otherwise]'I'm beyond being able to talk about that,' Frankie says then burps. [end if] [lb]" instead.

Carry out talking about text with something (this is the talk about a topic rule):

let threads be the conversation threads of the second noun;

repeat through threads begin;

if Topic entry is topic understood begin;

say "[conversation entry][lb]";

now Spoken Status entry is spoken-of;

end if;

end repeat.

Discussing something with is conversing. Informing about something to is conversing. Talking about text with is conversing.

Rule for supplying a missing second noun while conversing:

now second noun is the conversationalist.

Setting action variables:

if conversing, now the conversationalist is the second noun;

if (talking to something) or (answering someone that), now the conversationalist is the noun;

if (the conversationalist provides the property distracted and the conversationalist is distracted) or the conversationalist is not in the location, now the conversationalist is Goldie.

Talking to is an action applying to one visible thing. Understand "talk to/with [anything]", "ask [any person]", "greet [any person]", "salute [any person]", "speak to/with [any thing]", "converse", "speak", and "talk" as talking to.

Rule for supplying a missing noun while talking to during Preparation:

if the nun is distracted, now the noun is Goldie;

otherwise now the noun is the nun.

Rule for supplying a missing noun while talking to during Observation:

if location contains Frankie, now noun is Frankie;

otherwise now noun is Goldie.

Check talking to the player:

say "[We] [figure] [we] [look] crazy enough in this fly outfit; no need to confirm as much by talking to [ourselves]." instead.

Check talking to something:

if the noun is not a personable thing, say "[We] [poke] [the noun]. There is no reaction, so [we] [do]n't talk to it." instead.

Carry out talking to a person:

if the number of rows in the Conversation Pieces of the conversationalist is greater than the number of entries in the pieces discussed of the conversationalist begin;

if Fly Eye is a Conversation Piece listed in the Conversation Pieces of the noun begin;

unless noun has spoken about Fly Eye begin;

try discussing Fly Eye with the noun;

rule succeeds;

end unless;

end if;

let subjects be a list of things;

repeat through the Conversation Pieces of the noun begin;

unless noun has spoken about Conversation Piece entry, add Conversation Piece entry to subjects;

end repeat;

unless subjects is {} begin;

let chosen be a random number between 1 and the number of entries in subjects;

try discussing entry chosen in subjects with conversationalist;

rule succeeds;

end unless;

end if;

repeat through the Conversation Threads of the conversationalist begin;

unless Topic Proxy entry is "mission" or there is a Spoken Status entry begin;

say "[Conversation entry] [lb]";

now Spoken Status entry is spoken-of;

rule succeeds;

end unless;

end repeat;

say "[The noun] [nod] and smiles as you speak.".

Understand "get up", "stand", and "stand up" as exiting when Observation is happening.

Understand "go", "go in/into/to hall/hallway", and "run out", and "walk out" as exiting.

Going by name to is an action applying to one visible thing. Understand "go to/-- [any thing]", "go to/-- [any room]", "visit [any thing]", and "visit [any room]" as going by name to.

Heading out of is an action applying to one thing. Understand "get out of [something]", "get out from [something]", "leave [something]", "exit [something]", and "flee [something]" as heading out of.

Check heading out of something which is not a room-proxy:

say "[We] [are]n't in [the noun]" instead.

Check heading out of a room-proxy when the noun is not Fly Eye:

if the noun is the event stage and event played out is true, try looking instead;

say "There are four other monitors to consider." instead.

Turning up volume on it to is an action applying to one thing and one number. Understand "turn up the/-- volume of/on/for [something] to [a number]", "turn [something] up to [a number]", "turn up [something] to [a number]", and "turn up the/-- volume of/on/for [something]" as turning up volume on it to.

Check turning up volume on something to a number:

if the noun is a person, say "[if the noun is the player][We][']re pitch perfect[otherwise][The noun] speaks loud enough[end if]." instead;

say "[if the noun is playroom]The volume on monitor 5 is not adjustable[otherwise][The noun] [do]n't have volume control[end if]." instead.

Turning down volume on it to is an action applying to one thing and one number. Understand "turn down the/-- volume of/on/for [something] to [a number]", "turn [something] down to [a number]", "turn down [something] to [a number]", and "turn down the/-- volume of/on/for [something]" as turning down volume on it to.

Check turning down volume on something to a number:

if the noun is a person, say "[if the noun is the player][We][']re pitch perfect[otherwise][The noun] might take offence to that[end if]." instead;

say "[if the noun is playroom]The volume on monitor 5 is not adjustable[otherwise][The noun] [do]n't have volume control[end if]." instead.

Turning volume it for is an action applying to two things. Understand "turn volume/-- of/-- [something] [a direction]", "turn [a direction] volume/-- of/-- [something]", and "turn [a direction] volume" as turning volume it for.

Rule for supplying a missing second noun while turning volume a direction for:

if Preparation is happening, try helping;

otherwise now the second noun is playroom.

Before turning volume a direction which is not up for something, try turning down volume on second noun to 1 instead.

Before turning volume up for something, try turning up volume on second noun to 2 instead.

A level is a kind of value. low and high are levels. Understand "max" and "maximum" as high.

Turning volume on it to is an action applying to one thing and one level. Understand "adjust volume of/-- [something] to [a level]", "turn volume of/-- [something] to [a level]" and "set volume of/-- [something] to [a level]" as turning volume on it to.

Section - Thought-processing

The block thinking rule does nothing.

Remembering is an action applying to nothing. Understand "remember" as remembering.

Successfully remembered is initially false.

Carry out remembering:

say "[We] [remember] . . . ";

remember events for entry 1 in realizations, nonspecifically;

if successfully remembered is false, say " . . . that nothing particularly interesting happened.";

now successfully remembered is false;

Remembering specifically is an action applying to one visible thing. Understand "remember [any thing]" as remembering specifically.

Understand the commands "recount" and "recall" as "remember".

Check remembering specifically the player:

say "You remember everything you need to know about yourself." instead.

Check remembering specifically something which is in Flyeye-rm when the noun is not a room-proxy:

say "[The noun] [are] in the room with [us]." instead.

Check remembering specifically something when the noun is not a person and noun is not a room-proxy:

if the noun is a disguise, try remembering specifically the holder of the noun instead;

say "[We] ";

if the noun is the large bag, say "[if entry 3 in realizations is Laboratory]saw Cleopatra drop her bag behind the chest in the Laboratory[otherwise if entry 2 in realizations is Communications]saw Cleopatra carrying her bag when she visited Communications[otherwise if entry 1 in realizations is Ballroom]saw Cleopatra carry her bag out of the ballroom[otherwise][remember] seeing Cleopatra with a bag full of props earlier this evening[end if]." instead;

if the noun is the red-haired doll begin;

if leprechaun is accounted for and (entry 2 in realizations is Playroom or entry 3 in realizations is Zoo or entry 4 in realizations is Communications), say "saw the leprechaun with a red-haired doll in [if entry 4 in realizations is Communications]Communications[otherwise if entry 3 in realizations is Zoo]the Alien Zoo[otherwise]the playroom[end if]." instead;

if Playroom is listed in realizations, say "thought [we] saw a red-haired doll in the playroom." instead;

say "think that the playroom might have a red-haired doll." instead;

end if;

if the noun is the jacket, say "[remember] seeing the jacket on [if entry 6 in realizations is Playroom or entry 4 in realizations is Zoo]the gray[otherwise]a man earlier this evening who was completely dressed in black[end if]." instead;

unless a room contains noun, say "[are]n't sure where [we] may find [the noun]." instead;

let stand-in be a random room-proxy which is in the location of the noun;

say "[if stand-in is listed in realizations][remember] seeing [the noun] in [the location of the noun][otherwise]guess that [the location of the noun] may have [regarding the noun][them][end if]." instead.

Check remembering specifically a room-proxy when noun is not listed in realizations:

say "[We] [have]n't watched [the noun] yet." instead.

Need a line break is initially false.

Carry out remembering specifically a person:

let old-time be screentime;

unless the noun is accounted for begin;

say "[The noun] was hanging out in the Soul Dancers Ballroom earlier this evening.";

otherwise;

say "[We] [remember] watching [the noun]: [lb]";

repeat with counter running from 1 to the number of entries in realizations begin;

if counter is 1 begin;

if noun is either Black Widow or Cleopatra and entry 1 in realizations is not ballroom, say "[lb]in the ballroom, [if noun is Cleopatra]protecting a darkened area beside the stage[otherwise]watching Cleopatra standing guard beside the stage[end if].";

if noun is either medicine man or Rasputin and entry 1 in realizations is not laboratory, say "[lb]in the lab, [if noun is medicine man]ignoring Rasputin[otherwise]digging into a chest[end if].";

if noun is either leprechaun or sasquatch and entry 1 in realizations is not playroom, say "[lb]in the playroom, [if noun is leprechaun]probably planning something[otherwise]laughing at the leprechaun[end if].";

end if;

unless noun was spotted in trailer counter begin;

if entry counter in realizations is entry counter in the hangouts of the noun begin;

now screentime is counter;

unless (the noun is leprechaun and counter is 1 and number of entries in realizations is at least 2 and entry 2 in realizations is playroom) or (noun is either butcher or pirate and entry (counter minus 1) in the hangouts of the noun is entry counter in realizations) begin;

say "[lb]In [short name for entry counter in realizations]";

follow the character recall rules for the noun;

end unless;

end if;

end unless;

end repeat;

end unless;

now screentime is old-time;

rule succeeds.

To decide whether (target - person) is not remembered in event (cue - a number) of (footage - a thing):

if ((the number of entries in realizations is at least cue and entry cue in realizations is not footage) or the number of entries in realizations is less than cue), decide yes;

no.

To decide whether (observable - a person) was spotted in trailer (event - a number):

if event is 1 and observable is Cleopatra and entry 1 in realizations is ballroom, decide no;

if observable is trailer-spotted begin;

if event is 1 and observable is Cleopatra and observable is not remembered in event 2 of Communications begin;

say "[lb]In Communications, studying a far corner of the room.";

decide yes;

end if;

if event is 2 begin;

if observable is medicine man and medicine man is not remembered in event 3 of Communications begin;

say "[lb]In Communications, gazing into a mirror.";

decide yes;

end if;

if observable is either leprechaun or sasquatch and observable is not remembered in event 3 of Zoo begin;

say "[lb]In the Alien Zoo where he seemed to be planning to scare someone.";

decide yes;

end if;

end if;

if event is 3 begin;

if observable is medicine man and medicine man is not remembered in event 4 of Communications begin;

say "[lb]In Communications, examining a chandelier.";

decide yes;

end if;

if observable is either devil or MIB and observable is not remembered in event 4 of Zoo begin;

say "[lb]In the Alien Zoo, [if observable is devil]rope in hand and under watch by the MIB[otherwise]studying the devil[end if].";

decide yes;

end if;

if observable is either leprechaun or sasquatch and observable is not remembered in event 4 of Communications begin;

say "[lb]In Communications where he encountered the medicine man.";

decide yes;

end if;

end if;

if event is 4 and observable is gray and entry 4 in realizations is not Zoo begin;

say "[lb]In the Alien Zoo, staring out the door.";

decide yes;

end if;

if event is 5 begin;

if observable is either Black Widow or nun and Widow is not remembered in event 6 of ballroom begin;

say "[lb]In the ballroom, talking with [if observable is nun]Black Widow[otherwise]the nun[end if].";

decide yes;

end if;

if observable is either leprechaun or sasquatch and observable is not remembered in event 6 of Communications begin;

say "[lb]In Communications, waiting by the door.";

decide yes;

end if;

if observable is MIB and MIB is not remembered in event 6 of playroom begin;

say "[lb]In the playroom, checking for spooks.";

decide yes;

end if;

end if;

end if;

no.

Carry out remembering specifically something:

say "[We] [remember] . . . ";

remember events for noun;

if successfully remembered is false, say "but nothing of note comes to mind.";

now successfully remembered is false.

Ruminating is an action applying to nothing. Understand "ruminate" as ruminating.

Check thinking when event played out is true:

if contemplative mood is true, try remembering instead;

try thinking about event stage instead.

Carry out thinking when screentime is 0:

say "[italic type][if Goldie is not aware of characters]I should look at the monitors[otherwise]I can follow Cleopatra or Black Widow in the ballroom, Rasputin or the medicine man in the lab, or the leprechaun and sasquatch in the playroom[end if]. [roman type] [lb]";

rule succeeds.

Carry out thinking:

let recent event be entry (number of entries in realizations) in realizations;

say italic type;

if screentime is 1, say "[if entry 1 in realizations is Ballroom]Cleopatra has made her way to Communications . . .[otherwise if entry 1 in realizations is Laboratory]Rasputin has escaped to the playroom . . .[otherwise if entry 1 in realizations is Playroom]What are the leprechaun and sasquatch up to in the playroom?[otherwise]I probably missed something, but I can catch up with Cleopatra in Communications or the sasquatch and Rasputin in the playroom.[end if]" instead;

if screentime is 2 begin;

if Goldie is following curse storyline, say "Cleopatra has made her way to the lab." instead;

if recent event is playroom and (Goldie is following fright storyline or Goldie is following greed storyline), say "[if Goldie is following fright storyline]What is the leprechaun planning in the zoo?[otherwise]Rasputin isn't around, but something is bothering the medicine man in Communications.[end if]" instead;

end if;

if screentime is 3 begin;

if recent event is Communications, say "The medicine man is staying in Communications, so maybe I should, too." instead;

if recent event is Laboratory, say "Cleopatra has returned to the ballroom." instead;

if recent event is zoo, say "The leprechaun and sasquatch are probably going to talk to the medicine man in Communications." instead;

end if;

if screentime is 4, say "There's only Rasputin and Black Widow to watch in Communications." instead;

if screentime is 5 and recent event is Communications begin;

if Goldie is following curse storyline, say "Black Widow and Cleopatra are at it again in the ballroom." instead;

if Goldie is following fright storyline, say "The leprechaun and sasquatch have set something up, but will they be successful?" instead;

if Goldie is following greed storyline, say "Black Widow has returned to the ballroom. No sign of Rasputin, though, or the medicine man." instead;

end if;

if screentime is 6, say "What's happened to Greg?" instead;

say "Maybe I should have tried following some of these characters around more closely.";

say roman type.

Understand "think further" and "think more" as thinking.

Thinking about is an action applying to one visible thing. Understand "think about [any thing]" as thinking about.

Understand the commands "muse" and "ponder" as "think".

First check thinking about the player:

say "[i]My costume isn't too bad compared to some of these.[/i] [lb]" instead.

Check thinking about something when the noun is not a room-proxy and the noun is not a person:

say "[i]I'd need to look at [the noun] to get more info,[/i] you think." instead.

Check thinking about a room-proxy when noun is not listed in realizations:

say "[i]It would be better to actually [if location is Ballroom-rm]go to the Fly Eye and[end if] watch what happens in [short name for noun] first.[/i] [lb]" instead.

Check thinking about a room-proxy when (event played out is false) or (event played out is true and noun is not event stage):

try remembering specifically the noun instead.

Check thinking about a person:

if event played out is false or (event played out is true and entry screentime in the hangouts of the noun is not event stage), try remembering specifically the noun instead.

Carry out thinking about something when screentime is at least 1:

if the noun is a person begin;

say "You just watched h[if noun is a woman]er[otherwise]im[end if] in [short name for event stage]";

abide by the character recall rules for the noun;

say "You shrug, not thinking much of what [the noun] was up to.";

end if;

if contemplative mood is true, now Goldie is thinking of previous event;

abide by the event interpretation rules for the noun;

say roman type;

say "[i]Another room would Probably be more interesting,[/i] you think.".

Report thinking about something when screentime is less than 1:

say "[We] [consider] [the noun] thoughtfully.".

Thinking is pondering. Thinking about is pondering. Remembering is pondering. Remembering specifically is pondering.

Volume - The Mysteries

Book - People and Places

Chapter - People

The description of Goldie is "You're dressed completely in black, including leather gloves and a hoody, its hood hiding your hair but not your forehead, from which a paper towel roll wrapped in a black sock points like a unicorn horn. Two more of these appendages are stuck to your belt, each attached by a length of string to the arm above. Oval wire scaffolds covered in plastic wrap protrude from your back. Your mobile phone is tucked under your belt.".

[If the player types, say, "x pants" and there are two NPCs with pants, we will choose the pants of the NPC the player last examined.]

Goldie wears a disguise called Goldie's disguise. Understand "fly's costume/disguise" as Goldie's disguise.

Understand "antenna", "abdomen", "belt", "gloves", "hood", "hoody/hoodie", "plastic wrap", "legs", "paper towel", "paper towel roll", "pseudolegs", "proboscis", "sock/socks", "thorax", "wing", "wings", "wire/wiress", and "wire wing/wings" as Goldie's disguise.

Goldie carries the mobile phone. Understand "cell phone", "cell", "Goldie's phone/mobile/cell", and "goldie's mobile/cell phone" as the mobile phone.

The description of the mobile phone is "It's stuffed behind your belt; you don't want to think about where some of the other society members with the most extravagant costumes are holding theirs. For the next hour, though, your attention is focused strictly on the monitors.".

Understand "poisonous spider" and "spider" as Black Widow.

Understand "Jeanette's/ange's/nun's sister" and "ange's sister" as Black Widow when the nun has spoken about Black Widow.

Black Widow can be trailer-spotted.

Black Widow wears a disguise called BW's-disguise. Understand "black widow's costume/disguise" and "spider's/widow's costume/disguise" as BW's-disguise.

Understand "black blouse/leotards/skirt/shirt", "curves", "blood red lips", "blood-red lips", "fang", "hood", "hourglass", "hour glass", "legs", "leg-things", "leg things/thing", "leg-thing", "leotard", "lips", "plastic teeth", "pseudolegs", "purse", "teeth", "red mark/hourglass", "red lips", "shirt", "skirt", "sharp teeth", and "vampire teeth" as BW's-disguise.

The description of BW's-disguise is "She appears ready to seduce and slay. Dressed all in black, she wears a short skirt, pantyhose, and a curve-hugging shirt. Her hair is also black, and it falls just short of the red hourglass on her back. As if a mate needed a stronger warning, fangs poke from between blood-red lips. Those floppy leg-things dangling from her sides, though, are likely to provoke a giggle rather than a scream from potential prey, and that black purse doesn't match the killer look.".

Understand "chef" as the butcher.

Understand "bald guy/man" as the butcher when screentime is less than 4 or (screentime is greater than 3 and MIB is unidentified).

The butcher wears a disguise called the butcher's disguise.

Understand "apron", "blood", "bloody/dirty/stained apron", "cleaver/knife", "bloody/meat/dirty cleaver/knife", "head", "intestine/intestines/sausage/sausages", "plush/rabbit/animal/stuffed/decapitated head", "meat", "rabbit/animal/toy", "stain/stains", and "plush/stuffed toy/animal" as the butcher's disguise.

The description of the butcher's disguise is "A link of intestines is slung over the butcher's shoulder, and some kind of animal head hangs around his thick neck. The intestines resemble sausage, but they are too shiny. Plastic, perhaps. [one of]You can make out long ears on the head around the butcher's neck, and you think there's a pair of buck teeth in its mouth. A rabbit. It [or]The rabbit's head hanging from the butcher's neck

[stopping]has cartoonish, oversized features, and it has clearly been ripped from a stuffed toy. He carries a stained cleaver covered with chunks of . . . chunks. The cleaver points out from his apron, which is covered in bright red blood.".

Understand "egyptian", "egyptian queen/princess/pharaoh", "pharaoh", "princess" and "queen" as Cleopatra. Understand "Fay Clarkson" and "fay" as Cleopatra when Frankie has spoken of the item described.

Cleopatra can be trailer-spotted.

Cleopatra wears a disguise called queen's disguise. Understand "cleopatra's costume/disguise" as queen's disguise.

Understand "asp", "bejeweled headdress/crown", "blonde/blond hair", "chin", "cobra", "crown", "fanged snake", "gold-laced gown/robe/robes", "gold/golden robe/robes/gown", "gown", "headress/headdress/headgear", "head dress/gear", "jewel/jewels", "knobby nose", "long nose", "snake", "thin lips", "nose", and "robe/robes" as queen's disguise.

The description of queen's disguise is "[if Cleopatra carries the bag]With a bag over her shoulder, Cleopatra sneers at a corner of the room. Befitting of her[otherwise]Befitting of Cleopatra's[end if] mystique and majestic caste are her vibrant multi-colored gown laced in gold and bejeweled headdress fronted by a fanged snake ready to strike. But, like her namesake, this Cleopatra's features are decidedly bourgeois: long nose, thin lips, and a knobby chin. And, though the hairstyle seems right, that blond color isn't.".

Understand "alien", "extra-terrestrial", "extra terrestrial", "extraterrestrial", "et", and "grey" as the gray.

The gray can be identified or unidentified. The gray is unidentified.

Gray can be trailer-spotted.

The gray wears a disguise called the gray's disguise. Understand "alien's/grey's costume/disguise" as the gray's disguise.

Understand "bathcap", "black orbs/eyes", "grey/gray bathcap", "cap", "gray/grey cap", "showercap", "shower cap", "gray/grey showercap", "gray/grey shower cap", "spacesuit", "space suit", "gray/grey spacesuit", "gray/grey space suit", "wetsuit", "wet suit", "gray/grey wetsuit", and "gray/grey wet suit" as the gray's disguise.

The indefinite article of the gray is "an".

The printed name of the gray is "alien".

The description of the gray's disguise is "[if the gray wears the jacket]A large black jacket engulfs the tiny frame of the MIB's charge. She[otherwise]The MIB's spindly-armed charge[end if] is undoubtedly human, unless the grays wear wetsuits and shower caps, both differing shades of gray than that of their faces, lips, and hands. More convincing are those big black eyes, which could have been plucked from an alien's orbitals at autopsy.".

Understand "agent", "cia/fbi/mib agent", "cia", "fbi", and "man in black" as the MIB.

Understand "bald man" as the MIB when screentime is not 2 or (event stage is not ballroom and screentime is 2).

The MIB can be identified or unidentified. The MIB is unidentified.

MIB can be trailer-spotted.

MIB wears a disguise called the MIB-disguise.

Understand "man in black's costume/disguise" and "agent's/mib's costume/disguise" as MIB-disguise.

Understand "black belt/suit/tuxedo", "belt", "hand mixer", "head", "shaved/bald head", "mixer", "suit", and "tuxedo" as the MIB-disguise.

The MIB wears the black jacket. Understand "man in black's jacket" and "agent's/black/mib's/sports/suit jacket"as the MIB-disguise when MIB wears the item described.

Understand "black/sports/suit jacket" as the gray when the gray wears item described.

The indefinite article of the MIB is "a".

The printed name of the MIB is "man dressed in black".

The description of the MIB-disguise is "The bulky [if examining the item described]MIB[otherwise]man[end if] [if screentime is greater than 5]has a no-nonsense look about him, except for that egg beater in his belt. His black attire really brings out the gleam off his bald head[otherwise]has a no-nonsense look about him, from the shaved head, sunglasses, and wicked sneer to his simple black suit. Still, he was willing to stuff an egg beater in his belt[end if].".

Devil can be trailer-spotted.

The devil wears a disguise called the devil's disguise. Understand "satan's costume/disguise" as devil's disguise.

Understand "cardboard", "cardboard wing/wings", "demon", "hockey player/stick/sticks", "horns/jersey/pitchfork", "jersey devil", "new jersey devil", "satan", and "wing/wings" as the devil.

The devil can be identified or unidentified. The devil is unidentified. The indefinite article of the devil is "a".

The description of the devil is "You're guessing that this guy is supposed to be a devil because he has a red face and horns on his head. In fact, he is probably the Jersey Devil, given the cardboard wings and not-so-subtle hockey jersey with an 'N' and horned 'J.' You don't think the real demon's pitchfork is just two upside-down hockey sticks that have been tied together, though.".

Frankie carries the cutlass. Understand "buccaneer's/pirate's cutlass/saber/sword" and "saber/sword" as the cutlass.

Understand "frankenstein", "frankenstein's monster", and "monster" as Frankie.

Frankie has a list of things called pieces discussed. [We could use the dialogue status value like we did for topics, but I'm not sure it is any better.]

Frankie has a table name called Conversation Pieces. Frankie has a table name called Conversation Threads.

The Conversation Pieces of Frankie is the Table of Frankie's Conversation Pieces. The Conversation Threads of Frankie is the Table of Frankie's Conversation Threads.

Frankie wears a disguise called Frankie's disguise. Understand "Frankenstein's/monster's costume/disguise" as Frankie's disguise.

Understand "battery", "batteries", "blue jeans", "cable", "cables", "dirty jeans/pants/shirt", "green skin", "electrodes", "jeans", "jumper", "jumpers", "jumper cables", "pants", "stitch", and "stitches" as Frankie's disguise.

The description of Frankie's disguise is "Reanimation, apparently achieved by shocking one's heart through jumper cables attached to the chest, has turned Frankie's face green and tore his shirt and jeans, and the brain transplant has left a nasty black stitch across his forehead. Given the way Frankie has been stumbling around the party, maybe it's time to hook up those batteries attached to his neck because he definitely isn't fully charged.".

Table of Frankie's Conversation Pieces

Conversation PieceConversation
Black Widow"'Have you met the black widow spider?' you say. [pb]'She's tempting, isn't she?' Frankie says. 'I don't know her, but maybe it isn't too late to introduce myself. We have something in common.' He smiles at you. 'I bite, too.' "
the butcher"'The butcher costume is excessive, don't you think?' you say. [pb]Frankie looks you over and taps the sock-wrapped paper towel tube poking from your forehead. 'It's not so unusual.' [pb]'I mean . . . I guess he's making a statement.' [pb]'Yeah. I love eating meat!' [pb]'No.' You shake your head. 'Forget it.' "
cat"[if location contains cat]You gesture to the cat. 'I don't think he trusts you.' [pb]'Feeling's mutual,' Frankie says. 'What's he doing here anyway? They don't let animals in this place.' [otherwise]'I think you offended the cat,' you say. [pb]Frankie shrugs. 'I don't trust [']em anyway. I'm more of a dog . . . ' He turns to you and smiles. 'Dog person, I mean.'[end if] "
Cleopatra"'Do you know our hostess, Cleopatra?' you say. [pb]Frankie nods. 'That's Fay Clarkson. She's usually such a nice girl, but tonight . . . I don't know what's gotten into her. Maybe it's her time of the [if the location contains cat][mdash]' [pb]The cat hisses, leaps from your lap, and scrambles out the door. Frankie just smiles. [otherwise]month.' [pb]You shake your head. [pb]Frankie is momentarily mesmerized by your wobbling antenna, then he continues. [end if]'Fay's father was Arthur Clarkson. An archaeologist. He would have been another Indiana Jones. But he and his wife and his son died in a boating accident while excavating a temple in the Amazon. Fay survived. Another archaeologist was supposed to be on that boat too. Greg's father, in fact[unless Frankie has spoken of Rasputin or Frankie has spoken of Medicine Man]. You know Greg, right? Rasputin[end unless]. But Dr. Hoblett claimed to be sick that day. He finishes the excavation. Finds a tomb. He Comes home with a bunch of stuff. Becomes famous. Fay comes back with nothing. An orphan. Over the years, other people who were there have died.'

Frankie makes spooky noises. 'Some say it's a curse. Such nonsense.' "
devil"'Have you met the devil?' you say. [pb]'The hockey gear he's trying to pass off as a devil's costume tells me one thing,' Frankie says. 'He's had one-too-many concussions.' "
Frankie"'Have you been a member of the society for long?' you say. [pb]Frankie turns to you. He narrows his bleary eyes. 'Who wants to know?' [pb]'It's just that I've been to a lot of these things, and I haven't met you.' [pb]Frankie's head wobbles. 'I just joined. Normally I like to keep a low profile, but every now and then you gotta surface and sniff [']em out.' He sniffs at you and smiles. "
Gray"'The gray and the man in black never stray far from one another, do they?' you say. 'I guess that makes sense.' [pb]Frankie's head bobs. 'Yep. Those costumes don't fool me. They're hiding in plain sight. You can never know whether it is them.' He pauses. 'Well, I can tell. Did you see the way they signal each other? That's not sign language. At least none that we know.' "
Goldie"'How do you like my costume?' you say. 'At least you recognize it.' [pb]Frankie turns and looks you over. He reaches for a wing. You block his arm. 'They're fragile,' you say. [pb]'I can be gentle,' Frankie says. He grins. "
leprechaun"'It looks like we need to keep an eye on the leprechaun,' you say. [if Goldie is following greed storyline]'He's already spooked Rasputin.'[end if][pb]'I wouldn't trust Lucky Charms as far as I could toss [if the location contains cat][mdash]' [pb]The cat hisses, leaps from your lap, and scrambles out the door. [pb][otherwise][mdash]' Frankie attempts a swing of his arms and teeters on his feet.

[end if]'He's trying to scare us with that stupid doll, but I'm too smart for that.' "
museum"'So, have you seen anything unusual tonight?' you say. [pb]'You mean besides the fact that Bigfoot is wandering the halls?' [if the location contains cat]Frankie regards the cat. 'And there's a giant skunk sitting on a fly's lap?' [pb]The cat hisses, jumps to the floor, and runs out the door. [pb]'Sorry, pussy,' Frankie says. 'You don't smell as bad!' His voice booms in the small room. 'What was your question again?'[end if] [pb]'Have you seen anything creepy tonight. Supernatural.' [pb]'Like ghosts? That's crap. It never hurts to be careful, though. We're all targets thanks to the Greada Treaty that Eisenhower signed with the grays. Human experiments for alien technology. I've seen them all. The Nordics. Arcturians. Reptilians.' [pb]'How do you know I'm not one of them?' [pb]He smiles. 'They're cold blooded. You're hot.' "
Medicine Man"'Do you know our medicine man?' you say. [if Goldie is following greed storyline]'He's had a couple of run-ins with [friend Greg].' [end if] [pb]Frankie shrugs. 'I ran into him in the exhibit on Meso-American culture. Lots of good stuff in there. Even blowguns and darts and poisonous plants.' [pb]'Curare,' you say. 'The stuff they put on the darts.' [pb]Frankie's head bobs. 'Dangerous, huh? Well, they've got it all locked up, but there's some smart people here tonight. Don't trust anyone. Especially with those trinkets and totems. You know they're auctioning all that stuff off? I bet it will make someone . . . ,' he winks at you. 'A pretty penny.'[if the location contains cat] [pb]Frankie attempts to pet the cat, but it hisses, leaps from your lap, and runs out the door.[end if] "
nun"'Do you think that nun is really pregnant?' you say. Frankie squints into monitor 1. He shrugs. 'Could be. Maybe the priests have tired of little boys.' "
pied piper"'Did you like the music the Pied Piper was playing?' you say. 'I don't like music. It can hide subliminal messages, you know.' Frankie taps his head. 'Ole Frankie won't be turned into a brainless zombie.' "
pirate"'Where's your pal, the pirate?' you say. [pb]Frankie frowns. 'He wandered off after I took a swipe at that dumb bird on his shoulder. I should've kept his sword. Coward.' "
Rasputin"'How do you think Rasputin is holding up?' you say. 'Greg's a bit of the nervous type, and in a place like this . . . ' [pb]Frankie scowls. 'He's a wimp. All this stuff about ghost kids. Silly.' "
sasquatch"'Do you know the sasquatch?' you say. [pb]Frankie shrugs. 'He seems like a good guy. Not like the leprechaun he hangs around with.' "
scientist"'Have you met the scientist?' you say. 'He doesn't seem to say much.' [pb]'Didn't say much to you either, huh?' Frankie says. 'They won't tell you what they do and, when they do, it's all scientific mumbo-jumbo designed to hide what is really going on.' "
the zombie"'We even have the walking dead here tonight,' you say. [pb]'A cold, brainless, relentless gal who eats too much,' Frankie says. 'I thought it was my ex.' "

To say friend Greg:

say "[unless Frankie has spoken of Cleopatra or Frankie has spoken of Rasputin]my friend Greg. [end unless]Rasputin".

Understand "blowgun", "curare", "dart", "darts", "mesoamerica", "meso-america", "totem", and "totems" as "[blowgun]".

Table of Frankie's Conversation Threads

TopicTopic ProxyConversationSpoken Status (a dialogue status)
"[blowgun]""'You don't think anyone would steal the curare and use it to kill someone,' you say. [pb]Frankie rubs his head. 'Not normally, no. But tonight . . . it would be convenient for them to turn us against one another.' [pb]You decide that encouraging Frankie to expand on his theories about 'them' and their motives is probably a waste of time right now."--
"curse/expedition/temple""curse""'So why do you think Cleopatra is acting weird then?' you say. 'If you don't believe that it's a curse.' [pb]Frankie adjusts a battery on his neck. 'She's angry at something. Or somebody.'"--

Understand "lucky charms", "irish", "irishman", "irish man", "green/irish/little/short man", "joker", and "trickster" as the leprechaun.

The leprechaun can be trailer-spotted.

The leprechaun wears a disguise called the trickster's-disguise.

Understand "leprechaun's costume/disguise" and "beard", "buckle/buckles", "black pants/shoes", "bulge", "bulging pockets/pocket", "clover", "green/shamrock/clover hat", "hat", "green jacket/suit", "pocket/pockets", "ruddy", "red beard", "ruddy complexion/face", "suit", and "shamrock" as the trickster's-disguise.

The description of the trickster's-disguise is "[if examining the leprechaun]He[otherwise]The leprechaun[end if] is so short that he may just fit the definition of 'little person[if the leprechaun carries the red-haired doll],' the doll deceptively large under his arm. [otherwise].' [end if]He wears black pants and buckled shoes, and the pockets of his green jacket are bulging. A giant shamrock dangles from his green hat like Halloween's version of a mistletoe. You can't imagine the trick inspiring many kisses, though, not with that full red beard, ruddy complexion, and mischievous grin.".

Understand "doctor", "indian", "meso/native american", "priest", "shaman", and "witch doctor" as the medicine man.

Understand "carving", "figure", "figurine", "head", "totem", "wooden carving", and "wood carving" as "[totem]".

The medicine man incorporates the frog, the owl, the raven, the totems, and the wolf.

The frog, the owl, the raven, and the wolf are spirit animals.

Understand "frog [totem]" and "head of frog" as the frog.

The significance of the frog is "The frog is associated with the water element and cleansing. As such, it symbolizes rebirth, fertility, and abundance"

The description of the frog is "It looks like a lime green frog's head with an exagerrated mouth and large eyes. It rests [if screentime has been 2]at the top of the staff, above the other totems[otherwise]just below the wolf, which is at the top of the staff[end if].".

Understand "owl [totem]" and "head of owl" as the owl.

The significance of the owl is "Traditionally, the owl is the announcer of death, of change. It also represents wisdom and great insight, especially to see what others don't"

The description of the owl is "It's the feathery head of a brown owl. It lies atop the raven, which is at the bottom of the staff.".

Understand "raven [totem]" and "head of raven" as the raven.

The significance of the raven is "The raven represents magic, and it carries messages in its wings from the cosmos. It is also associated with change and transformation and, therefore, sometimes considered a trickster"

The description of the raven is "The raven has large eyes and beak. It rests at the bottom of the staff.".

Understand "head of wolf" and "wolf [totem]" as the wolf.

The significance of the wolf is "The wolf represents intelligence and instinct but also mistrust, in either yourself or others"

The description of the wolf is "The wolf's head is grey and white with black eyes. It's [if screentime has been 2]just below the frog at the top of the staff[otherwise]at the top of the staff, above the frog[end if].".

The totems are plural-named.

Understand "animal carving/carvings", "animal spirits/representatives", "cane", "staff", and "[totem]s" as the totems.

The description of the totems is "They are painted wood carvings of the heads of the animals they represent: [if screentime is less than 2]wolf[otherwise]frog[end if], [if screentime is less than 2]frog[otherwise]wolf[end if], owl, and raven. They hang in that order from top to bottom of the staff.".

Medicine man can be trailer-spotted.

The medicine man wears a disguise called the medicine-man's disguise.

Understand "medicine man's costume/disguise" and "shaman's costume/disguise" as medicine-man's disguise.

Understand "black markings/marking", "belt", "cheek/cheeks", "bead/beads/bone/bones", "jewelry", "makeup", "small bones", "smear", "necklace", and "pouch/pouches/purse/purses" as the medicine-man's disguise.

The description of the medicine-man's disguise is "[if medicine man is examined and screentime is greater than 2][one of]His appearance hasn't changed since the last time you saw him, but his staff has. Now the frog is at the top, followed by the wolf, the owl, and the raven[or]His costume and the totems haven't changed. The figurines are aligned with [totem thoughts][stopping]. [end if]At odds with the medicine man's contemporary shirt and pants are the mystical nature of his work. His cheeks are smeared with black markings, and he wears a necklace of beads and small bones. Pouches are strung along his belt. [unless medicine man is examined and screentime is greater than 2]He holds a staff from which four totems swing as it moves. The animal figures are aligned vertically with [totem thoughts]. [end unless]".

To say totem thoughts:

say "[if screentime is less than 2]a wolf[otherwise]a frog[end if] on top, followed by [if screentime is less than 2]a frog[otherwise]a wolf[end if], an owl, and a raven".

Understand "ange", "holy", "whorey sister", "holy sister", "Jeanne des Ange", "Jeanne", "des Ange", "mother superior", "pregnant nun", and "sister" as the nun.

Understand "black widow's sister" and "spider's/widow's sister" as the nun when the nun has spoken about Black Widow.

The nun can be distracted.

The nun has a list of things called pieces discussed.

The nun has a table name called Conversation Pieces. The nun has a table name called Conversation Threads.

The Conversation Pieces of the nun is the Table of Nun's Conversation Pieces. The Conversation Threads of the nun is the Table of Nun's Conversation Threads.

The nun can be trailer-spotted.

The nun wears a disguise called the nun's disguise. Understand "sister's costume/disguise" as nun's disguise.

Understand "habit", "apostolnik", "scarf", and "shawl" as the nun's disguise.

The hunched back is part of the nun. Understand "nun's curvature/hump/hunchback/scoliosis/spine", "curvature/hump/hunchback/scoliosis/spine", "nun's hunched back", and "hunch back" as the hunched back. The printed name of the hunched back is "nun's hunchback".

The pregnancy is part of the nun. Understand "baby/belly/conception/fetus/tummy/stomach/womb" and "nun's baby/belly/conception/fetus/tummy/stomach/womb" as the pregnancy.

The description of the nun's disguise is "[if Preparation is happening]She stands head-and-shoulders taller than you, and s[otherwise]S[end if]he wears the customary apostolnik and habit, which sits atop red hair. A shawl covers her shoulders and hump, which [if screentime is greater than 5]seems to have spread out over her shoulders, giving her an NFL linebacker look[otherwise]has slid down her spine to relocate more toward the center of her back. [nun alcohol][end if].".

To say nun alcohol:

say "The veracity of the scoliosis is questionable, but the pregnancy may very well be real. [if Nun is not distracted and Preparation is happening]She is, indeed, drinking non-alcoholic punch[otherwise]She indeed moves as if a solid mass were weighing down her belly[end if]".

Table of Nun's Conversation Pieces

Conversation PieceConversation
Black Widow"You gesture to Black Widow. 'Are you afraid of spiders?' [pb]'Spiders?' the nun says. 'No. But living with her for 18 years is really scary.' [pb]'You know her well, then.' [pb]The nun nods. 'She's my sister.' "
Cleopatra"'Cleopatra needs to mellow out, huh,' you say. [pb]The nun scowls. 'She said I was uglier than that guy in Notre Dame. Can you believe it? I'm no Vanessa Redgrave, but . . . ' She frowns at Cleopatra. 'What a [mdash] ' Her voice lowers, and you only hear 'itch.' It could have been 'witch.' "
devil"'Everyone [mdash] and every thing [mdash] seems to be here tonight,' you say. 'Even the devil . . . ' [pb]'Lots of innocent girls have gotten in trouble because of him. Life-changing trouble.' "
Fly Eye"[if the punch is carried and the punch was not carried]You pour yourself some punch and nod to the nun. [otherwise if the punch is carried and the punch was carried]You sip the punch. [end if]'So, did you see anything good on your watch?'[if the punch is not carried] you say to the nun.[end if] [pb]She rests her cup on her belly. 'I did hear some odd sounds out in the hall, but that's about it. But there's always something going on with this bunch.' She gestures her cup at the guests. 'I'd keep an eye on them, if I were you.' She laughs. "
Frankie"'So what's the Church's position on abominations like Frankenstein's monster?' you say. [pb]'Sometimes science just doesn't know when to quit,' the nun says. "
the gray"'We even have a visitor from another world here tonight,' you say. 'And her handler.' [pb]'Aren't they cute?' the nun says. 'I wonder if he is over-protective, though. None of my business, I guess.' "
guests"'What do you think about the turnout?' you say. [pb]'It looks like it is a success,' the nun says. 'Everyone sure has gotten in the spirit.' She winks.' "
leprechaun"'You just missed the leprechaun and his hairy friend,' you say. 'They just left before you arrived.' [pb]'He bumped into me in the hall,' the nun says. 'The little guy. He should really be more careful.' "
museum"'There's lots of interesting stuff here,' you say. 'You're going to check it out?' [pb]The nun nods. 'I'll make my way around eventually, I hope.' "
nun"'You must be . . . Sister . . . Jean . . . Jeanne des Anges,' you say. 'Am I right?' [pb]'Just got in from Loudun,' the nun says and grins. "
pirate"'The pirate seems to get around okay on his wooden leg,' you say. [pb]'He sure does,' the nun says. "
Rasputin"You look around. 'I don't see Rasputin. I guess he has decided to explore.' [pb]'He asked for me to pray for him,' the nun says then frowns. 'I'm not sure he was joking. Maybe he believes all this haunted house stuff after all.' "
scientist"'Do you know the guy in the lab coat?' you say[if Goldie carries the punch], sipping your drink[end if]. [pb]'Just met him tonight,' the nun says. 'We had a nice chat over dinner.' She looks over to the man with the spiked white hair. 'I'm not finished my mission with him, though. You know those scientist-types.' She rolls her eyes. "
pregnancy"'So,' you say, gesturing at the nun's large belly. 'Congratulations?'[pb]The nun smiles. 'It is a good disguise, isn't it? One could say even divine.' She winks and rubs her belly. [if Goldie carries the punch][pb]You raise your cup. 'I'll drink to that.' "
punch"'Do you want to try some of the punch with alcohol?' you say. 'They got the combination just right.' [pb]'I had to give up alcohol a long time ago,' the nun says. 'It got me in a lot of trouble.' She pats her belly then clarifies, 'No, no. Tummy troubles. Not that.' "

Understand "noise/noises/sound/sounds" as "[noises]".

Table of Nun's Conversation Threads

TopicTopic ProxyConversationSpoken Status (a dialogue status)
"mission""mission""'What is your mission?' you say. [pb]'To spread the glory of our Lord, of course,' the nun says. "--
"[noises]""noises""'Do you think anything you heard could be a genuine haunting?' you say. [pb]'Don't know. We're there to watch the monitors. I didn't really pay attention to anything else.' "--

Understand "enchantment" and "enchantments" as the music when Preparation is happening.

Understand "deejay", "dj", "flutist", and "musician" as the pied piper.

The pied piper wears a disguise called the pied piper's disguise. Understand "piper's costume/disguise" as the piper's disguise.

Understand "piper's bag", "bag of candy", "candy bag/wrappers/wrapper", "candy", "cap", "pointy cap/hat", "feather", "feather cap", "flute", "hat", "instrument", "pipe", and "wrapper/wrappers" as the Pied Piper's disguise.

Understand "bluebeard", "buccaneer", and "blackbeard" as the pirate.

The pirate wears a disguise called the pirate's disguise. Understand "buccaneer's costume/disguise" as pirate's disguise.

Understand "artificial leg/limb", "baggy pants", "bird", "baseball/pirates/pirate cap", "eyepatch", "eye patch", "leg", "wood/wooden/peg leg", "prostheses/prosthesis", and "toucan" as the pirate's disguise.

The description of the pirate's disguise is "Except for the stuffed toucan on his shoulder, this pirate could have stepped out of a Pixar cartoon, with that eye patch and wooden leg. The gleam off that cutlass, though, makes you wonder if the blade isn't for children.".

Rasputin can be recognized.

Understand "Gregory/greg Hoblett", "Gregory/greg", "grigori rasputin", "grigori", "Hoblett", "monk", "mad monk", "mystic", "russian", and "russian mystic" as Rasputin.

Understand "wimp" as Rasputin when Flyeye-rm contains Frankie.

Rasputin wears a disguise called Rasputin's disguise. Understand "greg's/mystic's costume/disguise" as Rasputin's disguise.

Understand "arcane", "arcane/silver/silvery symbols", "silvery/silver arcand symbols", "beard", "black/bushy beard", "bushy", "cape", "ring/rings", and "symbols" as Rasputin's disguise.

Understand "white hair", "whitehair", "whitehaired guy/man/male", "white-haired guy/man/male", and "guy/man/male" as Rasputin when screentime is 6 and Rasputin is on-screen.

Should the game choose doing something with Rasputin when screentime is 6 and Rasputin is on-screen:

it is a good choice.

The description of Rasputin's disguise is "[if screentime is 6 and Rasputin is on-screen]You study the fallen man. His fingers are covered in something. Rings. Like those that Greg wore tonight. This is Greg, but his Rasputin-black hair is now white and spiked. You don't remember his cape having two red holes in it, but they could have been hidden within the fabric's folds[otherwise]Greg is well-disguised in his uncharacteristic long black hair and bushy beard. His shirt is plastered with silvery arcane symbols, and his cape falls in thick folds down to his knees. Most of his fingers sport rings[end if].".

Understand "ape", "beast", "big foot", "bigfoot", "hairy beast/ape/man/human", and "yeti" as the sasquatch.

The sasquatch can be trailer-spotted.

The sasquatch wears a disguise called the bigfoot's-disguise. Understand "bigfoot's/sasquatch's/yeti's costume/disguise" as the bigfoot's disguise.

Understand "feet/foot", "fur", "hair", and "small feet" as the bigfoot's disguise.

The description of the bigfoot's disguise is "If this sasquatch were photographed in a forest, the image could fool more people than did the Patterson footage. Casts of his feet, though, would be unconvincing; they wouldn't justify the moniker Bigfoot. At least he's unashamedly barefoot.".

Understand "einstein", "genius", "mad scientist", "white-haired man/scientist", and "white haired man/scientist" as the scientist.

The scientist can be spotted.

The scientist wears a disguise called the brainiac's-disguise. Understand "einstein's/scientist's costume/disguise" as the brainiac's-disguise.

Understand "coat", "labcoat", "lab/white coat", "pens/pen", "pocket protector", "white/frizzy/spikey/spiky hair", "spikey/spiky/frizzy white hair", and "white lab coat" as the brainiac's-disguise.

Understand "bottle" and "liquor/wine" as the brainiac's-disguise when screentime is greater than 3 and (entry 4 in realizations is Communications or (the number of entries in realizations is at least 5 and entry 5 in realizations is Communications)).

The description of the brainiac's-disguise is "[if examining the item described]The scientist[otherwise]He[end if] isn't doing anything to dispel the nerd cliche. His white lab coat is clean, and it even has a pocket protector full of pens. His hair is white and spiked, as if electrically-charged from the sparking of overworked neurons.".

The printed name of the darkened area is "dark corner".

Understand "beside/behind the stage" and "behind/beside Cleopatra/stage/speaker/speakers" as the darkened area.

The description of the darkened area is "[if Preparation is happening]Cleopatra has chosen to plant herself in the darkest part of the room, and you can't make out anything behind her[otherwise]The shadow obscures anything that may lie within[end if].".

The soul dancers are plural-named. Understand "ballroom dancers", "ethereal dancers", "dancing", "ghost/ghosts", "ghost dancers", "holograms", "holographic images/dancers", "souls", "spirit/spirits", and "spirit ddancers" as the soul dancers.

The description of the soul dancers is "The Forteans share the dance floor with flickering holograms of dancers dressed in 19th century garments. This is odd because the house wasn't built until early in the next century[first time]. Maybe the design of the clothes was meant to clash with that of the spirits who supposedly really do haunt this mansion, you think[only].".

Understand "zombie gal/girl/woman/lady" as the zombie.

Understand "stage", "stacks", and "stacked speaker/speakers" as the stage.

Understand "speaker/speakers" as the stage when screentime is less than 5 or (screentime is 5 and event stage is not Communications).

The description of the stage is "The place where the Pied Piper prepares his enchantments, which have little effect on the guests, as they prefer to talk over them rather than dance.".

Understand "alcohol", "alcoholic drink/punch", "beer/booze", "beverage/beverages", and "drink" as the punch.

The description of the punch is "A yellow fruity substance. The alcoholic version probably has vodka. A lot of it. Ginger Ale is its substitute in the sover concoction.".

Understand "berries", "broccoli", "carrots", "cheese", "cold cuts/meat", "drinks", "food", "food table", "fruit", "hors d'oevres", "meat/meats", "pickle/pickles", "punch bowl", "refreshments", and "vegetables" as the refreshment table. The description of the refreshment table is "On offer to the guests is a variety of fruits and vegetables, cold cuts, and both alcoholic and non-alcoholic punch.".

Understand "bulky sac/sack/bag" and "cleopatra's/queen's/princess's/pharaoh's bag/sac/sack" as the large bag. Understand "shadow" and "shadows"as the large bag when Preparation is happening.

The description of the large bag is "[if screentime is greater than 2]It lies largely hidden behind the chest in a corner of the room. [end if]You saw Cleopatra carry [if screentime is greater than 3]it[otherwise]this bag[end if] into the mansion when everyone arrived after dinner. [if screentime is greater than 2 and entry 3 in realizations is Laboratory]It contained[otherwise]You think it contains[end if] the candles, figurines, bloody body parts, and other ghastly theme pieces that decorated the restaurant's dining room.".

Chapter - Places

Check looking when screentime is 0 and Goldie is not aware of characters during Observation:

say "You study the monitors: [lb]".

Carry out looking when location is Flyeye-rm:

unless Techno-Celebration was current begin;

carry out the teasing activity;

end unless;

if screentime is 6, rule succeeds;

if location contains Frankie begin;

if screentime is 4, say "Frankie bobs his head, although you aren't sure that he's keeping time with '[a random current song]' playing on";

if screentime is 5, say "Next to Frankie, '[a random current song]' plays on";

otherwise;

say "Below the pentagon of screens, [Comment corresponding to a Song of a random current song in the Table of Halloween Songs]";

end if;

say " [one of]a[or]the[stopping] laptop[if laptop is unexamined], which shows an open web browser[end if]";

if location contains the cat begin;

if location does not contain Frankie begin;

say ", and the cat purrs on your lap";

otherwise;

say ". The cat lying on your lap [if screentime is 4]has turned its head to keep an eye on him[otherwise]continues to stare at Frankie[end if] as he ";

end if;

end if;

if location contains Frankie begin;

if the location does not contain cat, say ". ";

if Goldie is following curse storyline begin;

if location does not contain the cat, say "He continues to [if Cleopatra is on-screen]watch[otherwise]search the ballroom for[end if] ";

if location contains the cat, say "[if Cleopatra is on-screen]watches[otherwise]searches the ballroom for[end if] ";

say "Cleopatra";

otherwise;

if the location does not contain cat, say "He ";

if Goldie is following fright storyline or Goldie is following greed storyline begin;

say "rubs his chin, [if Rasputin is on-screen]staring at Rasputin on monitor 2[otherwise]presumably searching for Rasputin[end if]";

otherwise;

say "tries to follow the peripatetic Fortean members on the monitors";

end if;

end if;

end if;

say ".";

rule succeeds.

Flyeye-rm contains the laptop, the monitors, the orb, and the voices.

The monitors are plural-named.

Understand "all the monitors/screens/rooms", "all screens/monitors/rooms", "pentagon", "cameras", "monitors", "screens", and "tvs/televisions" as the monitors.

The camera is scenery in Flyeye-rm. Understand "[watchables]" as the camera.

Understand "browser", "web browser", "web", "website", and "computer" as laptop.

The laptop incorporates Facebook and the internet.

Understand "Google", "search engine", "wikipedia", and "yahoo" as the internet.

Facebook, The internet, the laptop, and mobile phone are electronic devices.

The description of laptop is "You read through the website: The Harrison Museum is the former home of the archaeologist Wayne Harrison, whose work was pivotal in our understanding of Meso-American culture. His personal life, however, was marked by tragedy. First, his wife, Gabrielle, died while reading to their twin daughters. The girls, along with many of their friends, died years later in the same room as did their mother, with their deaths deemed mysterious by some. Conflicted and distraught, Wayne converted the mansion into a museum filled with collections of the bizarre and occult, daring you to believe. [pb]Guests be wary. Ghoulish monsters roam the halls, and ghostly dancers have been spotted in the ballroom. And just maybe you'll encounter Wayne's daughters and their friends as they continue to play in the house long after their deaths."

Understand "ghostly/ghost light/orb" as the orb.

Understand "voice" as the voices.

Understand "pussycat", "black cat" and "striped cat" as the cat.

The description of the cat is "[if screentime is 5]The cat has stopped purring and instead fixes Frankie with a distrustful stare. You pet it gently. [end if]The [if we have touched the cat]paint [end if]stripe runs from the cat's neck to the base of its tail. It's a straight line, and the intensity of the white color is uniform all along the cat's back[if we have touched the cat], so it doesn't look like the cat struggled when it was being marked [mdash] or disguised [mdash] for Halloween[end if].".

Understand "blood/bone/bones", "dead mouse/rat/rodent", "lump/mouse/prey", "body/rodent", and "rib/ribs/skeleton" as the rat.

The description of the rat is "The jagged white bits poking from the bloody lump must be bone. The head, distinctly rat, hasn't been mauled.".

An event description rule for Ballroom:

if screentime is 5, now indefinite article of zombie is "the";

if screentime is either 2 or 3 or 5 begin;

say "The monitor shows about a third of the room, including downstage, which is flanked by stacked speakers. Most of the guests have drifted toward the refreshment table lining the far wall. [one of]A couple of spirited dancers materializes in front of the stage. The woman, dressed in a purple ball gown, twirls as her partner holds her hand over her head. They embrace then disappear[or]A monocled, mustachioed man appears at the periphery of the corporeal guests. Motionless, he watches, nods, and disappears[or]A man in a white tuxedo waltzes a few steps with his elegant partner before they dip into oblivion[or]None of the souls, otherworldly or otherwise, are dancing[purely at random]. [pb]";

if screentime is 2, say "[vegetarian] [one of]makes his way to the refreshment table. He glances at the selection of cold cuts and sausage on a tray and places some fruit and vegetables on the paper plate in his hand[or]munches on [one of]a carrot[or]some broccoli[or]a pickle[or]some berries[purely at random] as he watches the guests. He is standing with his considerable bulk blocking the meats behind him[stopping].";

if screentime is greater than 2, say "[if screentime is 5]A zombie lurches toward a dish on the refreshment table. She reaches for a slice of meat. Suddenly, she stops. She swats her hand in the air over the dish. She turns away and ambles out of view. On the other side of the screen, the pirate dances and pounds his wooden leg into the floor as the nun, smiling, watches the bobbing toucan on his shoulder[first time]. Maybe he's explaining how he got his cutlass back[only][otherwise][vegetarian] munches on [one of]some kind of fruit[or]a carrot[or]something green[purely at random] as he watches the colorful guests[end if][if screentime is 5]. [pb]A white orb appears at the bottom of the screen. It rises slowly then disappears[first time]. [tick a box][only][end if].";

end if;

if screentime is 1 begin;

now Goldie is following curse storyline;

say "Cleopatra slaps the headdress onto her head and, noticing Black Widow, strides over to the crouching woman. Jerking her head up, Black Widow teeters on her feet and almost falls over. She rises and backs away from the other woman. [pb]Several of the guests watch as the spider and queen exchange words. Black widow shakes her head and holds up her empty hands. Cleopatra's shoulders lower, and her hands fall to her sides. Black Widow walks away, shaking her head. [pb]Cleopatra pulls a bulky bag from the shadow beside the stage. She looks inside the bag, hefts it over her shoulder, and leaves the room.";

end if;

if screentime is 4, say "Rasputin rushes past [if event played out is true and not replaying]her[otherwise]Cleopatra[end if]. He grabs a drink [mdash] from the alcoholic punch bowl [mdash] just as Cleopatra catches up to him. He gulps down his drink as Cleopatra talks. [pb]Black Widow emerges from a crowd and approaches Rasputin. Smiling, she places a hand on his shoulder. She speaks, silencing Cleopatra. Rasputin replies to Black Widow, who nods. Arms crossed, Cleopatra gets in a few words, but Rasputin only shrugs and finishes his drink. He hands the cup to Cleopatra then allows himself to be lead out of the room arm-in-arm with Black Widow. [pb]Cleopatra crushes the cup, tosses it onto the table. Staring at the doors, she taps her foot. She walks to the exit and disappears off-screen.";

if screentime is 6, say "Cleopatra appears beside the doors and rushes over to Black Widow, interrupting her conversation[if event played out is false] with the nun[end if]. Cleopatra speaks to Black Widow, who responds with a few words and a pat on the woman's arm. Cleopatra heads to the exit, and Black Widow shrugs at the nun. [pb]Cleopatra stops at the doors and stares out into the hall.";

if screentime is 7, say "Cleopatra steps back[if Rasputin is recognized], and guests gather around Greg, who lies prone with the cape flattened on his back[otherwise]. The arms of the fallen man spasm, fingers covered in rings. It's Greg in his Rasputin costume. Except for that spiked white hair. He lies prone with his cape flat on his back. Two red holes are punched into the black fabric[end if]. [pb][if Rasputin is not recognized]Guests gather around your fallen friend. [end if]Several [if Rasputin is recognized]guests[otherwise]of them[end if] grab their cell phones. Some take pictures while others make calls. The nun bends down and touches the holes in Greg's cape. She rubs her fingers together and shakes her head. Black Widow helps Frankie turn Greg onto his back. His face is almost as white as his hair. The nun starts the chest compressions for cardiopulmonary resuscitation. Cleopatra watches with a concerned look. [pb]A tall woman wearing a white dress and tiara takes the hand of a suited man in a top hat. They swirl and step around the crowd.".

To say vegetarian:

say "[if the butcher is examined]The butcher[otherwise][one of]A fat, bald man, wearing a bloody apron and carrying a cleaver,[or]The bald man[stopping][end if]".

An event interpretation rule for Ballroom when screentime is 1:

say "[if Goldie is thinking of previous event]that [end if]Cleopatra [if Goldie is thinking of previous event]protected her bag from Black Widow[otherwise]didn't want Black Widow snooping around in that bag,[roman type] you think[end if].".

An event interpretation rule for Ballroom when screentime is 4:

if Goldie is thinking of previous event, say "Cleopatra didn't want Rasputin to leave the ballroom with Black Widow.";

otherwise say "It looks like Cleopatra had her own plans for Rasputin,[roman type] you think. [italic type]She certainly didn't want him going off with Black Widow[if entry 3 in realizations is Laboratory]. Was she setting up something for him in the lab first?[otherwise].[end if]".

An event interpretation rule for Ballroom when screentime is 6:

say "Cleopatra [if Goldie is thinking of previous event]searching for someone in the ballroom. [otherwise]must be searching for someone,[roman type] you think. [italic type][end if]";

if entry 4 in realizations is ballroom or entry 5 in realizations is communications begin;

if entry 4 in realizations is Ballroom, say "[if Goldie is thinking of previous event]Maybe Rasputin. [otherwise]Rasputin? What's holding him up? [end if]";

if entry 5 in realizations is Communications, say "[if entry 4 in realizations is Ballroom]He[otherwise]Rasputin[end if] and Black Widow [unless Goldie is thinking of previous event]must have [end unless]split up after leaving Communications[if (Goldie is following fright storyline or Goldie is following greed storyline) and Goldie is not thinking of previous event]. Greg is so shaken up, I wouldn't want to leave him alone[otherwise if Goldie is not thinking of previous event]. Greg was really distressed; I hope the widow left him with someone[end if]. ";

end if;

say lb.

An event interpretation rule for Ballroom when screentime is 7:

say "[if entry 2 in realizations is playroom]That scream sounded like Greg. [otherwise]Was that scream from Greg? [end if]What happened . . . [lb]".

Communications-rm contains the ceiling, the chandelier, the mirror, the trade and the tricks.

The tricks are plural-named. The printed name of the tricks is "mediums['] tricks".

The trade is plural-named. The printed name of the trade is "mediums['] tools".

There is a thing called the stereo equipment. Understand "cable/cables/knot/wire/wires", "cd/dvd player", and "radio" as the stereo equipment.

There is a thing called the shadowy corners. Understand "area/corner/corners", "dark/darkness", "dark/darkened areas/area/corner/corners/spot/spots", "dark/dim/shadowed corner/spot/spots", "shadow/shadows", and "shadowed/shadowy area/areas/corner/corners/region/regions" as "[shadows]".

The shadowy corners are plural-named.

Understand "[shadows]" as the darkened area.

Should the game choose doing something with the darkened area when comparing the darkened area against the stereo equipment:

if screentime is less than 3, it is a good choice;

never.

Understand "[shadows]" as the shadowy corners when screentime is greater than 2 and screentime is less than 5.

Understand "[shadows]" and "speaker/speakers" as the stereo equipment when screentime is greater than 4 and entry 5 in realizations is communications.

The description of the shadowy corners is "Communications isn't dark enough for a proper seance, but the positioning of equipment casts the room's corners in strategic shadows.".

The description of the stereo equipment is "[if screentime is 5]You scrutinize the speakers where Rasputin had attempted to revive the stereo. Nothing but a tangle of cables and shadow. You guess the setup [otherwise]You guess the stereo [end if]provides ambient sounds, whether they be stormy weather, discordant music, or the whisperings of the deceased.".

Understand "light/lights" as the chandelier.

The description of the chandelier is "It's a fixture with lots of dangly glass bits for maximum jangling and clattering.".

Understand "bumps/glass", "distorted/bumpy mirror/mirrors", and "reflecting glass" as the mirror.

Understand "face/impression", "contorted/distorted/bumpy face/imprression/reflection", "doctor's/man's/shaman's face/reflection", and "medicine man's face/reflection" as the mirror when screentime is 2.

The description of the mirror is "Bumps distort the mirror's glass; it looks as if a head had tried to emerge from the Other Side and left an impression. The surface bends, compresses, and exagerates the facial features of anyone gazing upon it.".

Understand "apports/apport/rock/rocks", "automatic writing", "ouija boards/board", "psychographic text", "mediums/mediums'/medium's tools/trade/tool", "psychography", "shelf/shelves", "spirit trumpet/trumpets", "trumpet/trumpets", "tools", "tools of the trade", "trade trools", "trade tool", and "writing/messages/message/communication" as the trade.

Understand "tool" as the trade when Communications is event stage.

The description of the trade is "On exhibit are several versions of Hasbro's Ouija boards, which were intended only as a parlor game before they became associated with the psychography initiated by spirits. Whether or not a planchette and lettered board is used, messages for loved ones and the curious are recorded using some kind of writing implement and paper or slate, and the psychographic texts gathered here are protected in glass displays. Some spirits announce their presence audibly, and these are amplified with spirit trumpets like those along the back wall. You guess the rocks on the shelf above are apports, gifts teleported from the spirit world.".

Understand "cheesecloth", "compartment/compartments", "curtain/curtains", "ectoplasm", "ectoplasmic cheesecloth", "wardrobe", "hidden compartment/compartments", "mirrors", "tricks of the trade", "trade tricks", and "wobbly table/furniture" as the tricks.

The description of tricks is "Hanging from the walls is cheesecloth which, to the undiscerning eye and in the gloom of a poorly-lighted room, can pass as the ectoplasm secreted from a medium, and which is often interpreted as a manifestation from the spirit world. One table has been upturned to show hidden compartments. The wardrobe, curtains, and most of the mirrors are unremarkable by themselves, but you know that with strategically-placed conspirators and candlelight, a medium can create a credible illusion for the credulous and disillusioned.".

The description of Communications is "[unless screentime is 6][first time]You recall what you learned about this room from a speech Cleopatra gave at dinner earlier this evening. Wayne Harrison found his wife, Gabrielle, slumped in a chair with an open book at her feet, an aneurysm ending her life after twenty-something years, when her twin daughters were just a year old. Enter Zelda Rubinstein. The medium facilitated spiritual communication between the distraught and the deceased for almost a year, ending when Wayne remarried, apparently with Gabrielle's blessing. Zelda returned, however, a few years later when Wayne's twins died. Sessions between her, Wayne, and the children were unconvincing, and Wayne moved out of the mansion months later. [pb][only][end unless][if screentime is 7]The exhibit seems to be undisturbed, and nothing, living or dead, lurks within the shadowed corners or among the mediums['] tools. [lb][otherwise if screentime is not 6][one of]Since Wayne's departure, t[or]T[stopping]he museum's curator has filled the room with[otherwise]Beneath, the room is filled with[end if][unless screentime is 7] not only the tools of transcommunication, such as ouija boards and sound trumpets, but also the tricks of the trade, such as ectoplasmic cheesecloth and wobbly furniture.[end unless]".

An event description rule for Communications:

if screentime is either 1 or 2 or 7 begin;

if screentime is 2, say "[if event played out is true and not replaying]It[otherwise]The bag over Cleopatra's shoulder[end if] swings as Cleopatra finds a switch and dims the lighting. Before leaving, she smiles at the far corner, which is now hidden by shadow. [pb]";

say "[description of Communications] [lb]";

end if;

if screentime is 3, say "[if event played out is true and not replaying]He[otherwise]The medicine man[end if] touches [if text follows from event stage]its[otherwise]the[end if] bumpy surface[unless text follows from event stage] of the mirror[end unless], tracing the contours of a visage that distorts his own. The chandelier above him begins to shake[first time]. [tick a box][only]. [pb]Staring at the fixture, the medicine man backpedals toward the door and collides with Rasputin, who has just backed into the room. The staff falls from the medicine man's hand, spilling the frog totem onto the floor. [pb]Rasputin spins around, sees the totem, and picks it up. Frowning, he rolls the frog over in his hands. The medicine man snatches it away and hangs it back onto his staff. Rasputin looks at the collection of totems then at the medicine man, who scowls back at him. He retreats out the door. [pb]The medicine man studies the chandelier, which remains motionless.";

if screentime is 4 begin;

now player is aware of the doll;

say "[if event played out was false or replaying]The sasquatch and leprechaun turn to [otherwise]The two look at [end if]each other, and the sasquatch shrugs. The leprechaun speaks to the medicine man, who glances at the red-haired doll as he listens. He points at the door. Smiling, the leprechaun leads the sasquatch out of the room. [pb]The medicine man touches his staff to the bottom of the chandelier as the white-haired scientist arrives. The scientist smiles and speaks. The medicine man nods then lowers his staff. He speaks. The scientist nods then begins to pull a liquor bottle with a ribbon around its neck out of his pocket, but the medicine man stops him. The scientist glances at the camera, and the medicine man gestures at the door with his staff. They leave together.";

end if;

if screentime is 5 begin;

now Communications-rm contains the stereo equipment;

say "[if event played out is true and not replaying]She[otherwise]Black Widow[end if] notices a curtained off area at the far end of the room. Passing between tables, she approaches it and pulls back the curtains, revealing a set of audio equipment. Fiddling with the stereo, she says something and gestures for Rasputin to join her. [pb]Rasputin takes a deep breath, rubs his palms on his pants, and makes his way over to Black Widow. She points at a knot of cables snaking from the equipment to a dark corner behind some speakers. Rasputin hesitates then reaches into the darkness. Suddenly, he flings his arm back and stumbles backward. With wide eyes, he rubs his hand and speaks. [pb]Black Widow frowns and inspects Rasputin's hand. She shrugs. She attempts to look behind the speaker, but Rasputin stops her with a hand to her shoulder. Smiling, she shakes her head then bends over into the darkness. [pb]The leprechaun[if player is aware of the doll], without the doll,[end if] steps through the doorway, the sasquatch following behind him. They move aside as Black Widow, head shaking, leads the trembling Rasputin out the door. As she exits, the scientist appears in the doorway with a bottle. Rasputin snatches it from his hand and takes a swig. He pauses and does it again. Nodding, he returns the bottle, and the two men leave. [pb]The sasquatch follows the grinning leprechaun to the doorway where they stop and look into the hall.";

end if;

if screentime is 6, say "The grin falters on the leprechaun's face[if event played out was false] as he peers out the door[end if]. He scowls and leaves the room, the sasquatch trailing. [pb]The chandelier shakes. [unless entry 3 in realizations is Communications][first time][tick a box]. [pb][only][end if][description of Communications] [lb]".

An event interpretation rule for Communications when screentime is 2:

if Goldie is thinking of previous event, say "that Cleopatra dimmed the lighting in Communications.";

otherwise say "Is Cleopatra trying to hide something by dimming the lights?[roman type] you wonder.".

An event interpretation rule for Communications when screentime is 3:

if Goldie is thinking of previous event, say "Rasputin inspecting the medicine man's totems, especially the frog[if entry 1 in realizations is Laboratory]. He may have thought it had changed from when he saw it in the lab[end if].";

otherwise say "[italic type][if entry 2 in realizations is playroom]It's a good thing Greg didn't see that,[roman type] you think.[italic type] He's already freaked out. [end if]Those totems really got Greg's attention[if entry 2 in realizations is playroom], though. [otherwise], [roman type]you think. [italic type][end if] Especially the frog. [if entry 1 in realizations is Laboratory]Maybe he thinks it is somehow different than the one he picked up in the lab earlier. [end if] [lb]";

say roman type.

An event interpretation rule for Communications when screentime is 4:

if Goldie is thinking of previous event, say "[if entry 2 in realizations is Playroom]the medicine man telling the leprechaun where to find Rasputin after he left Communications[otherwise]the leprechaun searching for someone in Communications[end if]. The medicine man also wanted to talk privately to the scientist, who was carrying a liquor bottle.";

otherwise say "[if entry 2 in realizations is Playroom]The medicine man probably told the leprechaun where to find Rasputin[otherwise]The leprechaun is searching for someone[end if],[roman type] you think. [italic type]And the medicine man wants to talk to the scientist privately about the liquor bottle in his pocket. [if entry 1 in realizations is Laboratory and entry 3 in realizations is Communications]And maybe Rasputin and the totems as well. [end if] [lb]";

An event interpretation rule for Communications when screentime is 5:

if Goldie is thinking of previous event begin;

say "Rasputin reaching behind a speaker in Communications then recoiling as if something happened to his hand. ";

if entry 3 in realizations is Laboratory, say "Cleopatra may have dropped something into the room when she was in the lab. ";

if entry 4 in realizations is Ballroom, say "Maybe Cleopatra had intended to take Rasputin to Communications herself. ";

if entry 4 in realizations is Communications, say "Rasputin drank from the same bottle that the scientist had shown the medicine man. ";

if entry 2 in realizations is Playroom and entry 3 in realizations is Zoo begin;

say "The leprechaun finally caught up to Rasputin, too. ";

otherwise;

if following threads, say "It also looked as if the leprechaun and sasquatch were scheming against Rasputin or Black Widow. ";

end if;

otherwise;

say "Something stung Rasputin when he reached behind the speakers, [roman type] You think.[italic type] A shock? Bite? Black Widow doesn't seem concerned, but Greg sure is, drawing fortitude from the scientist's liquor bottle. [if entry 4 in realizations is Communications]Is it just a coincidence the scientist showed up to offer it to him after talking with the medicine man? [end if]";

if entry 3 in realizations is Laboratory, say "Cleopatra could have dropped something [if entry 1 in realizations is Ballroom]from that suspicious bag [end if]through a hole in the Laboratory floor, and it would have landed behind the speaker. ";

if entry 4 in realizations is Ballroom, say "Is this why Cleopatra was so upset in the ballroom? She has to get Greg here, but Black Widow whisks him away instead, and he ends up here anyway. ";

if entry 2 in realizations is Playroom begin;

say "[if entry 3 in realizations is Zoo]The leprechaun has finally found Rasputin, too[otherwise]The leprechaun is still trying to scare Rasputin with that doll, too[end if]. As if the guy hasn't been through enough already. ";

otherwise;

say "[roman type]You consider the pair in the doorway: Are they scheming against Rasputin or Black Widow? ";

end if;

end if;

say lb.

An event interpretation rule for Communications when screentime is 6:

if Goldie is thinking of previous event begin;

say "[if Goldie is following fright storyline]that Rasputin didn't see the doll the leprechaun left outside Communications, but the leprechaun didn't look like he was going to give up[otherwise if entry 5 in realizations is Communications]that the leprechaun seemed frustrated before leaving Communications[end if].";

otherwise;

say italic type;

if Goldie is following fright storyline begin;

say "So Rasputin didn't see that doll,[roman type] you think. [italic type]but the leprechaun isn't giving up.";

otherwise;

say "[if entry 5 in realizations is Communications]The leprechaun's plans didn't work out[otherwise]Whatever their plan was, it doesn't seem to have worked[end if], [roman type]you think. [italic type]I doubt they will give up, though.";

end if;

end if;

say roman type.

Laboratory-rm contains the floor, the lab-furniture, and the props.

The props can be opened. The props can be closed.

Understand "ax/axe", "bloody ax/axe", "trunk", "drawer/drawers", "prop chest/trunk/box", "prop", "small table", "table", and "weapon/weapons" as the props.

Understand "chest" as the props when the event stage is not playroom.

The printed name of the props is "chest".

Understand "candle/candles" as the props when screentime has been 3.

The props can be open or closed. The props are open.

The description of the props is "The [if the item described is open]open[otherwise]closed[end if] chest sits in a dark corner of the room, next to a small table[if screentime has been 3] with a few candles on its top[end if]. You imagine two pirates hefting the ornate chest up the stairs but, instead of ill-gotten spoils, this booty consists of ghoulish decorations and grisly props[unless screentime has been 3 or screentime is 0], like the axe lying on the floor. It's a cartoonish plastic exaggeration, the blood bright red[end unless][if screentime is 0]. Rasputin holds one of these, the ax, aloft with little effort; the weapon is likely plastic[end if].".

The printed name of the lab-furniture is "lab furniture".

Understand "bulb/bulbs", "light bulb/bulbs", "lights", "lit/lighted/small mirror", "closet/dresser/wardrobe", "costume closet/wardrobe/rack/racks", "clothes wardrobe/rack/racks/dresser/closet", "mirror/mirrors", "vanity/vanity's mirror", "full length mirror", "full-length mirror", "makeup/make-up/vanity table", and "rack/racks" as the Lab-furniture.

Understand "lab furniture" as the lab-furniture.

Should the game choose doing something to the mirror when comparing the mirror against the lab-furniture:

if event stage is laboratory and event played out is true, never;

it is an excellent choice.

The description of the lab-furniture is "You guess the closets are empty now but that they once held myriad frightful costumes. Similarly, you can imagine the vanity table cramped with makeup trays and heads with wigs. Not all of the light bulbs encircling the vanity's mirror shine; perhaps the actors and employees became apathetic with the museum's imminent closure. The full-length mirror facing the camera reflects [if Laboratory-rm contains medicine man]the scowling medicine man staring out the door[otherwise]an empty clothes rack on the other side of the room[end if].".

An event description rule for Laboratory:

unless screentime is either 1 or 3 or 7, say "The lab is usually off-limits to guests, but the society has been granted access tonight because the staff has reported strange goings-on that were not of their own creation. [if screentime is less than 3]An axe lies next to a chest[otherwise]A chest, probably full of props, sits[end if] in the far dark corner of the room[if screentime is greater than 2]. You remember the macabre candles on the small table beside the chest as those lighting the society's dinner party held at a restaurant a couple of hours ago[end if]. Grills are embedded in the floor at various spots, and a tilted pole protrudes from a hole in the floorboards beside the door. [pb][if screentime is 6]The devil enters and circles the room, passing the mirror, vanity table, wardrobe, and chest. He shakes the pole before leaving[otherwise]You imagine a perfectly-ordinary someone grabbing an outfit from the wardrobe, sitting at the vanity table, applying makeup, and finally checking the results in the full-length mirror before heading back out as a werewolf, zombie, vampire, or some other ungodly creation[end if].";

if screentime is 1 begin;

now Goldie is following greed storyline;

say "Axe in hand, Rasputin continues to root around in the chest at a dark corner of the room. The medicine man leans his totem-laden staff onto the wall between the two of them. He taps a couple of dark bulbs surrounding the vanity's mirror. When they don't light, he tries tightening them into their sockets, but that doesn't work either. He gives up and studies himself in the mirror's reflection. He reaches into a pouch on his belt and applies more black makeup to his face. [pb]Rasputin stands, turns, and kicks over the staff. Animal figurines spill onto the floor. He drops the axe and begins to gather them up. [pb]Watching Rasputin, the medicine man retrieves his staff. He scowls as Rasputin, on his knees and talking constantly, polishes each totem before looping them onto their former holder. A raven settles down the staff first, followed by an owl, frog, and wolf. [pb]Rasputin stands, and the medicine man glares at him as the mystic slinks out of the room.";

end if;

if screentime is 3, say "[if event played out is true and not replaying]She[otherwise]Cleopatra[end if] bends over her bag in the dark corner of the room. Her back faces the camera, and she needs to contort her body as she places a skull and knife in the chest next to her. She bolts upright and spins around as you glimpse someone enter from the opposite side of the room. [pb]The scientist walks toward Cleopatra but stops when she speaks. She points at the vanity table, full-length mirror, and wardrobe. The scientist glances at them, but he seems more interested in the grills set into the floor. Cleopatra watches him as he inspects one then pulls it free. He drops to his knees and stares into the hole. He replaces the grill and steps over to the pole sticking from the floor beside the door. He shakes it vigorously and looks back at Cleopatra, who smiles . She nods in response to something the scientist says and waves goodbye as he leaves. [pb]Cleopatra puts the ax into the chest before turning back to her bag. She is moving her arms and shifting around. You wait. And wait. Finally she begins to fill the chest again with an odd assortment of weapons and limbs. She knocks the chest's lid closed with her elbows and places the candles in her hands on the table next to the chest. Empty-handed, she leaves the room.";

if screentime is 7, say "You wait, but nobody appears, and you don't see anything unexpected.".

An event interpretation rule for Laboratory when screentime is 1:

if Goldie is thinking of previous event, say "the medicine man over-reacting to Rasputin picking up the totems from the lab's floor.";

otherwise say "No harm done,[roman type] you think. [italic type]Or maybe you're just-plain ornery anyway?[roman type] You study the medicine man's staff and its animal figures aligned as wolf, frog, owl, and raven from the top to bottom. [italic type]They look like wood carvings. They don't look fragile.".

An event interpretation rule for Laboratory when screentime is 3:

if Goldie is thinking of previous event, say "Cleopatra distracting the scientist in the lab and keeping him away from the chest behind her. She hid her bag behind it, and she took a while to unpack[if entry 1 in realizations is Ballroom] from a bag she didn't want anyone searching inside[end if].";

otherwise say "Cleopatra seemed to want the scientist to stay away from her side of the room,[roman type] you think. [italic type]Did she put her bag there to hide it from the camera? She seemed to be doing something more than just returning props[if entry 1 in realizations is Ballroom]. Maybe Black Widow was right to be curious about the bag[end if].".

Some holes are a door. Holes is down from Laboratory-rm and up from Communications-rm. Understand "hole" as the holes.

Understand "grill/grills/vent/vents/grate/grates", "floor", "floorboard/floorboards", "ground", "laboratory/attic floor", and "dressing room floor" as the holes.

The description of the holes is "[if event played out is false or (event played out is true and event stage is Laboratory)]Grills protect visitors from twisting an ankle in any of the holes spotted about the attic floor. One of them has been removed, exposing a hole from which a tall pole protrudes[otherwise]You can't see any holes in the walls or ceiling, and the angle of the camera doesn't allow a good shot of the ceiling[end if].".

Laboratory-rm contains the pole.

The description of the pole is "The shoulder-height pole leans against the side of a hole and disappears within. It's the only one in the attic.".

Alien-Zoo-rm contains the barrier, the mutants, the natural variations, the specimens, and the tentacles.

The mutants, natural variations, specimens, and tentacles are plural-named.

Understand "barriers" and "post/posts/stanchion/stanchions/poles" as the barrier. Understand "poles", "rope", and "ropes" as the barrier when event stage is Zoo.

The description of the barrier is "Usually rope barriers protect the more delicate exhibits from visitors, but the society has been granted full access tonight. You're guessing those that needed the greatest protection, though, have already been carted away anyway[if screentime is 3]. The devil holds a free end of one of these ropes as he stares out the door of the room[end if].".

Understand "case/cases/creature/creatures", "cyclops", "display case/cases", "detail/details", "drosophila", "drosophila melanogaster", "face/forehead", "fetus", "fish", "formaldehyde/fluid/water/fluid/water", "fruit fly/flies", "giant/large fruit fly", "giant/large fly", "head", "jar/jars", "leg/legs", "mermaid", "mouth/mouths", "model/models", "murk/murky fluid/liquid/water", "mutant/mutation/mutations", "mutant cat/goat/fish/fly/shark/sharks", "stuffed mutants/mutant/monster/monsters/fly/goat/cat", "two-faced/mutant cat", "two faced cat", "goat", "odd exhibit/exhibits/specimen/specimens", "tank/tanks", "two-headed shark", "two headed shark", "two-headed/mutant goat", "two headed goat", "white eye/eyes", and "wing/wings" as the mutants.

Understand "cat" as the mutants when the mutants are examined and screentime is less than 3.

The description of the mutants is "Some of the mutants in the glass display cases, jars, and tanks are sufficiently lighted by spotlight that macabre details resolve through the murky preservation fluid. In one tank, you can discern a shark with two large heads and a shriveled body. In another, a fish with two mouths. The fetus in one of the jars appears to have one leg, but it &mdash; her? &mdash; may be a mermaid. The head in another jar is so malformed that you can't determine a species, but one single detail is glaring: a large eye centered in its forehead.".

Understand "arachnid/spider", "badger/bear/weasel/terrier", "bizarre/species//weird", "bizarre/weird animal/animals/specimen/specimens", "blade/horn", "blood", "blue spider", "blue wolf spider", "crab", "crustacean", "goblin shark", "goblin", "hair/hairy arms", "honey badger", "pink shark", "pink", "pink skin", "skin", "semitransparent skin", "snout", "transparent skin", "white head", "wolf arachnid/spider", and "yeti crab" as the natural variations.

The description of the natural variations is "You recognize the terrier-sized thing that looks part weasel and part bear as the ferocious Honey badger, although this one has a white head, which you've never seen on them before. The crustacean with the hairy front arms is the Yeti crab, and that blue arachnid is almost certainly a variation of the wolf spider. The poster on the far wall shows a Goblin shark with its blade-like horn protruding from its snout. It glows distinctly pink because its blood circulates under semitransparent skin.".

Understand "animal/animals", "collection", "displays", "freak/freaks", "monster/monsters", "oddities", "shark/sharks", and "specimen" as the specimens.

The description of the specimens is "[description of the mutants] [pb] [description of the natural variations] [lb]".

Understand "mass of tentacles" as the tentacles.

The description of the tentacles is "Whatever monstrosity these tentacles belong to waits out of sight.".

An event description rule for Zoo:

if screentime is 3, say "The leprechaun stops in front of some rope hanging between two stanchions, which have been pushed up against the far wall to allow greater access to the collections. He unhinges one end of the rope and begins to wrap it around the doll's neck. [pb]The sasquatch steps back from the door, nodding at [unidentified name for devil] entering the room. The two speak. The sasquatch addresses the leprechaun. Scowling, the leprechaun unwinds the rope from the doll. He slaps the freed end into the devil's hand then rushes out the door, his hairy friend following behind.";

if screentime is 4 begin;

now player is aware of jacketed MIB;

say "As [unidentified name for MIB] watches, [unidentified name for devil] hooks the rope [unless text follows from Zoo]in his hand [end if]onto a stanchion. The MIB signals at the door. [cap-it][unidentified name for gray] enters and walks to a two-headed goat as the devil scurries around her and out the door. [pb]The gray begins to pet the goat then shivers. She makes several hand gestures to the MIB. He removes his jacket and drapes it over her shoulders[first time]. [pb][tick a box][only]. [pb]The gray wanders away to look at the other oddities while her black-suited partner checks a brochure. Having finished reading, he watches the gray standing before a mass of tentacles. When she turns to him, he gestures with his hands. She nods, and he leaves.";

end if;

if screentime is 7, say "The scientist steps into the room. You recognize him from the lab coat he wears; his white hair is gone, replaced by a horseshoe of thinning brown strands. He speaks and gestures at the bottle in his pocket. The medicine man nods before the two men split up, each attracted to a different display. [pb]Nothing seems out of place among the strange species and mutants in the collection[one of]. [or].[stopping]";

unless screentime is either 3 or 7, say "[if screentime is 4][lb]Surrounding the alien are[otherwise]Track lighting spotlights[end if] creatures that would make even Barnum and Bailey shudder. Specimens have been collected from the land and sea, and others have been torn from the womb. Some are mutants, but others are just bizarre common variations[if screentime is 5][one of]. [or].[stopping][otherwise].[end if]".

[Because the After rules insert a spurious line during screentime 5 and 7, we need to prevent the line break.]

An event interpretation rule for Zoo when screentime is 3:

if Goldie is thinking of previous event, say "[if entry 2 in realizations is playroom]the sasquatch telling the leprechaun that Rasputin wasn't headed for the zoo, so the two left[otherwise]the leprechaun wanting to scare someone in the zoo, but the person didn't show up[end if].";

otherwise say "[if entry 2 in realizations is playroom]The sasquatch must have told the leprechaun that Greg is going elsewhere, so the leprechaun will need to set up his scare tactic somewhere else[otherwise]The leprechaun is out to try to scare someone who isn't headed to the zoo[end if], [roman type]you think.".

Playroom-rm contains the clown, the dolls, the dinner table, the red-haired doll, and the toybox.

The dolls are plural-named.

The description of the clown is "[unless screentime has been 1]The toy clown sits upright against the far wall with its long striped legs spread out on the floor before him. His head is tilted back, and he stares at you through huge black-rimmed eyes[otherwise]The clown rests his head face-down on his spindly outstretched legs[end unless]. He is the only doll of its kind in the collection, his singular presence targeting coulrophobic and stalwart visitors alike, an outcast turned menace.".

The dolls are plural-named. The printed name of the dolls is "toys".

Understand "antique toy/toys", "ball/balls", "bar/bars", "jumping/skipping rope/ropes", "mannequin/mannequins", "puppet/puppets", "puppetmaster/puppetmasters/puppet", "rack/racks/shelf/shelves", "rope/ropes", "stuffed/plush animal/animals/toy/toys", "top/tops", and "toy" as the dolls.

The description of the dolls is "Many of these toys belonged to Wayne Harrison's daughters, Sarah and Jessica, but others have been collected from around the world. Some of the dolls are as small as your hand and others as tall as their 4-year-old owners had been. The imported dolls are generally more crudely-crafted than their mass-produced counterparts. You remember reports from the mansion staff that the deceased sisters are still playing with their dolls and not putting them back where they belong. You can also imagine the multi-jointed puppets poking people as they pass and dancing with delight to their invisible puppetmasters. A colorful collection of stuffed animals and other toys, such as balls and jumping ropes, have also been collected.".

Understand "chair/chairs/seat/seats", "cup/cups/glass/glasses", "dome", "glass dome", "gold/gold-colored/gold-coloured plate/plates/dish/dishes", "plate/plates/dish/dishes", "playtable", "play/supper/doll/toy/kid/kids'/kids/childrens/children's table", and "utensil/utensils" as the dinner table.

Should the game choose doing something to the refreshment table when comparing the refreshment table against the dinner table:

if event stage is playroom, never;

it is a passable choice.

The description of the dinner table is "A small table with chairs must have been where Sarah and Jessica held their dinner parties for their dolls and stuffed animals. The glasses, cups, bowls, and plates are not a matching set, and many are likely plastic. The centerpiece is a small collection of ornate dinnerware within a glass dome, shielded from the carefree hands of children and sticky fingers of visitors.".

Understand "freckles", "freckled/red haired girl/doll/puppet", "redhead girl/doll/puppet", "redhead", "red head", and "speaking/talking doll/puppet/girl" as the red-haired doll.

The description of the red-haired doll is "[if leprechaun carries the item described]She dangles at the leprechaun's side, her legs dragging along the floor. The only feature of her white dress is the lacy neckline[otherwise]There is only one red-haired doll, a girl about two feet tall with a freckled face and green eyes. She wears a simple white dress[end if].".

Understand "toy/toys box/chest" and "toychest" as the toybox.

Understand "box" as the toybox. Understand "chest" as the toybox when the event stage is playroom.

The toybox is a closed container.

The description of the toybox is "Animals and children play and dance together in the cartoons painted on the toybox in the far corner of the room. It is open, but you can't see inside. You assume it has been emptied of any valuables.".

An event description rule for Playroom:

if screentime is 1 begin;

now Goldie is following fright storyline;

say "The leprechaun releases the gold plate and tries to lift a cup from the table. [pb]'It's pretty creepy in here,' the sasquatch says, 'All these dolls staring at us.' [pb]The leprechaun looks around the room and shrugs. '[sequence 1 dialogue 1].' He walks over to a toybox and peers inside. He turns away then waves his hand in front of his face. '[sequence 1 dialogue 2].' [pb]The sasquatch chuckles. '[sequence 1 dialogue 3].' [first time][tick a box]. [only] [pb]The leprechaun turns to the door. '[sequence 1 dialogue 4].' He leaps into the giant toybox and disappears from view. [pb]The sasquatch shakes his head then goes out the door.";

end if;

if screentime is 2 begin;

now player is aware of the doll;

say "[one of]Suddenly, a [or]A [stopping]black-and-white blur darts [if text follows from playroom]out from behind it[otherwise]from behind the clown[end if] and out the door. [pb]Rasputin pulls away from the sasquatch. He takes in the shelves of staring dolls and puppets. He chokes, and his face blanches. [pb]The sasquatch doesn't seem to notice Rasputin's distress. 'Pretty impressive collection, huh? You should see what's in that toybox.' [pb]Rasputin glances at the chest just as the leprechaun pops out of it. Rasputin screams and falls back into the sasquatch's arms[first time].

[pb]You're surprised the shriek didn't shatter the monitor's screen[only]. [pb]The leprechaun climbs out of the toybox. 'You seem a bit on edge.' He laughs. [pb]'Do you guys know what happened in here?' Rasputin says. [pb]'Why don't you tell us what you've heard,' the sasquatch says as he steadies Rasputin's wobbly stance. [pb]Rasputin watches the dolls as he speaks. '[sequence 2 dialogue 1]. [pb]'[sequence 2 dialogue 2],' the sasquatch says. [pb]The leprechaun picks up a child-sized doll with red hair and a white dress. Wailing like a ghost, he shakes it at Rasputin. The mystic rushes out the door. The leprechaun grins broadly. '[sequence 2 dialogue 3].' He carries the doll out of the room with him, and the sasquatch follows, shaking his head.";

end if;

if screentime is either 3 or 4 or 5, say "Dolls and puppets sit upon and dangle from shelves lining all four walls. Those with the sturdiest legs and largest sizes stand on the floor. The clown rests alone near the door. Across from it, more toys are positioned around the single toybox. A table with chairs suitable for pint-sized hostesses have been set for dinner.";

if screentime is 6, say "[if event played out was true]The MIB[otherwise][cap-it][unidentified name for MIB][end if] checks inside the toybox then makes a hand signal at the door. [unidentified name for gray] enters with [if entry 4 in realizations is Zoo]her partner's[otherwise]a[end if] black jacket wrapped around her shoulders. While the MIB watches the dolls, the gray wanders across the room to the table, where she tries to sit on a small chair. [pb]The picture distorts. Stabilizes. [pb]The gray bolts from the chair and rushes over to join the MIB in the center of the room. The image begins to break up, but [first time]you can just [only]make out the pair holding hands as they look around, fixed to the spot.";

if screentime is 7, say "You see short humanoid figures in the distortion. A tall figure pulls a shorter one toward the door before the feed goes black. The static from the speaker persists, scrambling what may be giggling. [tick a box].".

Last event description rule for something (called sequence) when not replaying:

now event played out is true;

now watched trailer is false;

now Goldie is not thinking of previous event;

if screentime is 1 begin;

now Cleopatra carries the large bag;

now the pirate carries the cutlass;

end if;

if screentime is 2, now the Leprechaun carries the red-haired doll;

if screentime is 3 begin;

now the props are closed;

now Laboratory-rm contains the bag;

now Communications-rm contains the shadowy corners;

end if;

if screentime is 4, now the gray wears the jacket;

if screentime is 5 begin;

move the red-haired doll to ballroom-rm;

now the red-haired doll is off-stage; [We can't just do this because the leprechaun is also off-stage, and the doll is still considered carried.]

end if;

if thought mode is toggled on begin;

say roman type;

end if.

An event interpretation rule for Playroom when screentime is 1:

unless Goldie is thinking of previous event and number of entries in realizations is 2 and entry 2 in realizations is Playroom, say "[if Goldie is thinking of previous event]that the leprechaun hid in the chest to scare someone[otherwise][italic type]I'm sure the staff haunting this place uses the chest to hide as well[end if].".

An event interpretation rule for Playroom when screentime is 2:

say "[if Goldie is thinking of previous event]that Greg was really spooked by the playroom, and he had a high-pitched scream after being scared by the leprechaun[otherwise]Greg sure seems to think this place is haunted,[roman type] you think. [italic type]I never would have guessed he'd have such sensitive nerves, though, or such a high-pitched scream[end if].".