gwelks: Nigel Jayne's Interactive Fiction Site

Source Text for A Fly on the Wall, or An Appositional Eye

Volume -World Descriptors and Mechanics

Book - Classifying, Populating, and Describing the World

Chapter - Things, Values, Variables

A thing can be examined or unexamined. A thing is usually unexamined.

Understand the printed name property as describing a thing.

A room-proxy is a kind of backdrop. [These are used to represent rooms so that we can do more actions to them without needing to consider both rooms and things in rules. Besides, the Numbered Disambiguation extension is set up for things, not rooms, so we need to give room-proxies the number-name property too disambiguate rooms. This may not be practical for games with a lot of rooms.]

A room-proxy has a number called number-name.

Understand the number-name property as describing a room-proxy.

A room-proxy has a table name called transition events.

Event stage is a room-proxy that varies. [The event stage is the room-proxy, or room, that the player is watching.]

A room has a room-proxy.

Rule for printing the name of a room (called target):

say "[unless target is Communications-rm]the[end unless] [printed name of the room-proxy of the target]".

The museum is a backdrop. It is everywhere. Understand "attraction/funhouse", "harrison manor/museum/mansion/house", "haunted house", "haunting/hauntings/ house", "manor", and "mansion" as the museum.

The music is a backdrop. The music is everywhere. Understand "radio", "song", "songs", and "soundtrack" as the music.

The guests are a backdrop that is plural-named. The guests are everywhere. Understand "costumes", "crowd", "crowds", "forteans", "fortean society", "fortean members", "people", and "members" as the guests.

The guys are a backdrop that is plural-named. The guys are everywhere. Understand "men" as the guys. The printed name of the guys is "men".

The gals are a backdrop that is plural-named. The gals are everywhere. Understand "ladies" and "women" as the gals. The printed name of the gals is "women".

[An alternative to the above would be to use "understand 'women' as a woman" and the same for a man. However, this prompts a disambiguation message, and we want to treat the genders as a collective.]

Understand "guy" and "man" as a man.

Understand "gal", "lady", and "woman" as a woman.

The furniture is a backdrop that is everywhere. Understand "furnishings" as the furniture.

A disguise is a kind of thing. Understand "costume" and "disguise" as a disguise.

Understand "[something related by reversed wearing] costume/disguise" as a disguise.

Rule for printing the name of a disguise (called costume):

say "[holder of costume]'s costume".

An electronic device is a kind of thing.

A spirit animal is a kind of thing. A spirit animal has some text called significance.

A game mode is a kind of value. audio mode and thought mode are game modes. A game mode can be toggled on or toggled off. A game mode is usually toggled off. Audio mode is toggled on.

Understand "audio", "music", "sound", and "sound effects" as audio mode.

Dialogue status is a kind of value. spoken-of is a dialogue status. [We use this to register when the PC talks to someone about a topic. We can add values such as "spoken-once" to register how many times a particular topic is spoken about.]

The conversationalist is a thing that varies.

Realizations is a list of room-proxies that varies.

Contemplative mood is initially false.

Haunted manifestations is initially 0.

Screentime is initially zero. [This records which segment (1 to 7) of the narrative we're watching.]

Capitalization is initially false.

watched trailer is initially false.

Dropped book is initially false.

Creaky Door is initially false.

Event played out is initially false.

Section - The Manual

table of help contents

title (text)subtable (table name)description (text)used (number)bookpage (number)localpage (number)
"How to watch (for novice and experienced interactive fiction players)"--"In [story title], you're represented by Goldie, a Fortean Society member tasked with watching five (very high-definition) monitors that receive feeds from five paranormal hotspots in the Harrison Mansion. You begin in the Soul Dancers Ballroom where music is playing, and you're likely to hear other sounds throughout your vigil[unless glulx sound is supported]. However, this interpreter can't play the audio files[end unless]. [if glulx sound is supported]You can adjust the audio settings from the 'set audio' option in these help topics. [end if] Only a small number of commands are needed to complete the game. Typical commands include X (or EXAMINE) [bracket]someone or something[close bracket] (e.g., x nun) and L (or LOOK), which describes your surroundings. Conversation is handled with ASK [bracket]someone[close bracket] ABOUT [bracket]someone or something[close bracket] or TALK TO [bracket]someone[close bracket]. Sometimes the text will suggest actions that you can try. For example, you could try LISTEN TO MUSIC or LISTEN when music is playing. [pb]Unconventional commands are needed once Goldie settles in the Fly Eye. You can watch a room by typing its monitor number[if glulx hyperlinks are supported], or you can click on the room's name, as they are links as well[end if]. Use LOOK (or L) [if glulx hyperlinks are supported]or click ALL MONITORS [end if]to turn your attention to all the views, which will help you to decide what to watch next. To replay an event after it has played, type REPLAY. When you watch an event for the first time, ostensibly important events continue to play out in the other rooms, and you won't be able to see them. Fortunately, nothing of interest occurs on the monitors when you do something other than selecting a feed, such as examining or talking. COMMANDS shows many actions recognized by the game, and you should check them if you're unfamiliar with commands such as SAVE and UNDO. A hypertext version of [story title] is available at [fixed letter spacing]http://www.nigeljayne.ca/njgames.html,[variable letter spacing] as is the original zcode version, <i>A Fly on the Wall.</i> [pb]Goldie won't usually offer comments about the on-screen events, but you can follow this thought process with THOUGHTS ON (they are off by default). Goldie will comment when an event is witnessed that is part of one of the storylines. THINK shows Goldie's current thought regardless of whether or not thoughts are activated and, if you're watching all of the monitors, it will hint at which monitor you might want to watch next. REMEMBER shows all the important events you've witnessed, and REMEMBER [bracket]a room[close bracket] shows significant events for a specific room (or person, if you specify one instead). [pb]The HELP command always displays this menu. Check out the Help Desk for general tips or the combinations to all three storylines. The staff here at the mansion wishes you a frightfully good evening."
"Set Audio and Goldie's Thoughts"table of Game Modes--
"Help Desk"Table of Help Options--
"Acknowledgements"--"[story title] was staged by Nigel Jayne, with scripts provided by Wade Clarke, Mike Ciul, Eric Eve, Stephen Granade, Jon Ingold, Felix Larsson, Aaron Reed, Massimo Stella (with input from Wade Clarke), and Emily Short. I applaud my assistant directors Hanon Ondricek, Andrew Schultz, Daniel Stelzer, and XanMag. Comments and transcripts of your experience are welcome. Send them to nigelsjayne@gmail.com. The latest versions of all of Nigel's interactive fiction, along with source codes, are available at [fixed letter spacing]http://www.nigeljayne.ca[variable letter spacing] or the Interactive Fiction Database, [fixed letter spacing]http://ifdb.tads.org[variable letter spacing]. COVER shows the cover art, with text description, by Buster Hudson. 'Techno Celebration,' heard in the ballroom, was created by Eric Matyas at Sound Image, [fixed letter spacing]www.soundimage.org[variable letter spacing]. Sound effects were provided by AlucardsBride, g_lowing, Percy Duke, Robinhood76, SoundMunger, and tmc_zach, all downloaded from Freesound.org ([fixed letter spacing]http://www.freesound.org[variable letter spacing]). Your visit was designed using Inform 7 ([fixed letter spacing]http://inform7.com/[variable letter spacing]), created by Graham Nelson with help from Emily Short and many others."
"About the Author"--"Nigel Jayne, or more correctly the guy using that pseudonym, has a PhD in Pharmacology and Toxicology, earned after five years of getting pregnant guinea pigs drunk. Losing his eyesight shortly after graduation forced a change in his career plan, and he now occasionally writes scientific and medical literature. Nigel

enjoyed graphical-text hybrids such as the Space Quest and King's Quest series more than the strictly text-based games in his youth, but he was totally absorbed into the worlds of Choose-Your-Own-Adventure books. [i]Gaia's Web[/i] and [i]Sequitur[/i] are His other works of interactive fiction."

Include Menus by Wade Clarke. [We need this here because it needs to be included after defining the Table of Help Contents.]

table of Game Modes

title (text)subtable (table name)description (text)used (number)bookpage (number)localpage (number)
"Turn [if audio mode is toggled off]on[otherwise]off[end if] audio"--"[toggle audio]"------
"Turn [if thought mode is toggled on]off [otherwise]on [end if]Goldie's thoughts"--"[toggle thoughts]"------

To say toggle audio:

if glulx sound is supported begin;

say "The audio effects are now [if audio mode is toggled off]on[otherwise]off[end if].";

if audio mode is toggled on begin;

now audio mode is toggled off;

otherwise;

now audio mode is toggled on;

end if;

set all the volumes;

otherwise;

say "This interpreter doesn't support sound.";

end if.

.

To say toggle thoughts:

if thought mode is toggled on begin;

now thought mode is toggled off;

say "Goldie's thoughts are now hidden.";

otherwise;

now thought mode is toggled on;

say "Goldie's thoughts will now be shown.";

end if.

Table of Help Options

title (text)subtable (table name)description (text)used (number)bookpage (number)localpage (number)
"Command list"--"These are all the important commands for the game. Other actions are recognized but aren't necessary to play successfully. [pb]

ASK [bracket]someone[close bracket] about [bracket]something[close bracket][lb]

EXAMINE (or X) [bracket]something[close bracket] (you can just type the number of a monitor to watch it, or click the room name) [lb]

EXIT [lb]

FOLLOW [bracket]someone[close bracket]

G (repeats the last command)[lb]

LISTEN or LISTEN TO [bracket]something[close bracket][lb]

LOOK or L (if you're focused on a monitor, this will turn your attention back to all the screens and the Fly Eye)[lb]

PET [bracket]something[close bracket] [lb]

REMEMBER (summarizes all the significant events you've witnessed) [lb]

REMEMBER [bracket]a room[close bracket] (same as REMEMBER, for specific rooms; works for people as well)[lb]

replay (replays the events on the monitor you're watching)[lb]

T ON (or OFF) AUDIO or THOUGHTS (toggles audio effects and Goldie's interpretations on and off)[lb]

TALK TO [bracket]someone[close bracket] [lb]

THINK (shows Goldie's comments or suggests what to watch when you're looking at the monitors)[lb]

THINK ABOUT [bracket]something[close bracket] [lb]

SWING [bracket]something[close bracket] [lb]

WAIT or Z [pb]

Game State Options [pb]

RESTART [lb]

RESTORE (loads a saved game) [lb]

SAVE (saves the game state)[lb]

TRANSCRIPT (prints the game's output to a text file) [lb]

UNDO (restores the game state to what it was before you typed the last command) [lb]"
------
"Hints"--"You should try to follow a character as he or she moves from room to room. If the person you're following doesn't appear on-screen, you should temporarily switch your attention to another person who has recently interacted with the one you're interested in. Remember to LOOK; studying all the monitors will help guide your decisions. As you follow a character successfully, one of three distinct perspectives on the climax should develop. Goldie's commentary may help you interpret these stories, even if you haven't been following all the events of each one. At the end of the night, Goldie will indicate if you have followed a storyline successfully. You choose which, if any, you want to believe."------
"The 3 Perspectives"--"Each of these sequences should suggest a different killer and motive. If you've been following a story successfully, talking to Frankie in the Fly Eye will yield some useful information. The numbers represent the monitors you should select to follow each perspective, although you can watch any monitor as the last. [pb][b]Curse[/b] [lb]1 / listen / 2 / listen / 3 / 1 / 2 / talk to Frankie / 1 / 1 [pb][b]Fright[/b] [lb]5 / 5 / 4 / 2 / 2 / 2 / 1.

[pb][b]Greed[/b] [lb]3 / listen / 5 / 2 / 2 / 2 / 1 / 1 (4 to discover why Greg's hair is white). [pb]To find all the haunting phenomena: [lb]5 / any room / 2 / 4 / 1 / 2 / 5 [lb] Note that the same phenomenon occurs in Communications (monitor 2) twice."
------

Section - Characters and Rooms

Goldie is a person. The printed name of the player is "". understand "goldy", "fly", "goldblum", "goldblum", and "jeff" as Goldie.

The conversationalist is Goldie.

Goldie can be following curse storyline, following fright storyline, following greed storyline, or following threads. Goldie is following threads.

Goldie can be aware of characters.

Goldie can be thinking of previous event.

Goldie can be aware of the doll.

Goldie can be aware of jacketed MIB.

Goldie can be aware of playroom audio.

Goldie can be aware of the last teasers. [So we know if the player has seen Rasputin stumble into the ballroom and can print the appropriate message when the game ends.]

Goldie can be thinking about the conclusions. [Used to signify the end of the game when the player could choose to read a suggested storyline, i.e., one that we planned as a possible interpretation.]

Flyeye-rm and Ballroom-rm are rooms.

Static is a backdrop in Flyeye-rm. Understand "distortion/evp/giggling/giggles/laughter/laughing", "girls/boys/girl/boy giggling/laughing/giggles/laughter", "electronic voice/voices/giggling/laughter", and "electronic voice phenomenon/phenomena" as static.

Every room-proxy is in Flyeye-rm.

The Fly Eye is a room-proxy in Ballroom-rm. The room-proxy of Flyeye-rm is Fly Eye.

Understand "office" as fly eye.

Event stage is Fly Eye.

The Soul Dancers Ballroom is a room-proxy in Ballroom-rm. Understand "[watchables]" as Ballroom when item described is event stage and screentime is greater than 0.

The room-proxy of Ballroom-rm is Ballroom. Ballroom is in Ballroom-rm.

The number-name of Ballroom is one. The printed name of Ballroom is "Soul Dancers Ballroom".

Understand "dancefloor" and "dance floor" as the ballroom.

Understand "soul dancers ballroom", "soul ballroom", "dancers ballroom", "souls", and "soul dancers" as Ballroom when location is Flyeye-rm.

Preparation is a scene. Preparation begins when play begins. Preparation ends when Flyeye-rm contains the player.

Observation is a scene. Observation begins when Flyeye-rm contains the player.

After deciding the scope of the player during Observation:

repeat with selection running through things begin;

place selection in scope;

end repeat;

[repeat with ghost running through persons begin;

unless ghost is in a room, place ghost in scope;

repeat with component running through things enclosed by ghost begin;

place component in scope;

end repeat;

end repeat.]

Understand "camera", "event", "feed", "footage", "monitor", "room", "screen", "television", and "tv" as "[watchables]".

A song is a kind of thing. An Artist is a kind of thing. America, Atlanta Rhythm Section, Bobby Pickett, The Carpenters, Electric Light Orchestra, Edgar Winter Group, The Guess Who, Harlequin, Heart, Jim Stafford, Norman Greenbaum, Santana, Olivia Newton-John, the Steve Miller Band, Stevie Wonder, and Warren Zevon are artists.

Some songs are defined by the Table of Halloween Songs. A song can be current, played or unplayed. A song is usually unplayed. A song can be lyrically important. Spiders and Snakes is lyrically important.

Techno-Celebration is a song.

Table of Halloween Songs

SongArtistComment
AbracadabraSteve Miller Band"'Abracadabra' plays on"
Black Magic WomanSantana"'Black Magic Woman' plays from"
Clap for the WolfmanThe Guess Who"'Clap for the Wolfman' plays on"
FrankensteinEdgar Winter Group"That instrumental 'Frankenstein' song plays from"
Magic-ONJOlivia Newton-John"the song 'Magic' by Olivia Newton-John plays on"
Spirit in the SkyNorman Greenbaum"'Spirit in the Sky' plays from"
Magic ManHeart"'Magic Man' plays on"
Monster MashBobby Pickett"'Monster Mash' plays on"
Superstitious-FeelingHarlequin"Harlequin's 'Superstitious Feeling' spooking you as it plays on"
You Can Do MagicAmerica"America is playing 'You Can Do Magic' on"
Strange MagicElectric Light Orchestra"'Strange Magic' plays on"
Spiders and SnakesJim Stafford"[one of]I don't like spiders and snakes, and that ain't what it takes to love me[or]'Spiders and Snakes' plays on[stopping]"
SpookyAtlanta Rhythm Section"'Spooky' plays from"
SuperstitiousStevie Wonder"'Superstitious' sounds from"
Calling Occupants of Interplanetary CraftThe Carpenters"the song 'Calling Occupants of Interplanetary Craft' plays from"
Werewolves of LondonWarren Zevon"Zevon sings 'Werewolves of London' from"

The printed name of superstitious-feeling is "Superstitious Feeling".

The printed name of Magic-ONJ is "Magic". Understand "magic" as Magic-ONJ.

Understand "newton john" and "olivia newton john" as Olivia Newton-John.

Understand "elo" as electric light orchestra.

The double-duty door is a door. It is west of Ballroom-rm and east of Flyeye-rm.

Understand "double door/doors" as the double-duty door when Preparation is happening.

The printed name of the double-duty door is "door".

The double-duty door has a number called creakiness. The creakiness of the double-duty door is 0.

The description of the double-duty door is "[if Observation is happening]The door behind you is open to all that is going on outside the Fly Eye[otherwise]One of the double doors has been propped open to the dark hall outside[end if].".

To say open door explanation:

say "If you hear something out there, you want to be ready to record it on your phone, and a closed door would only get in the way.".

Ballroom-rm contains the darkened area, the large bag, the punch, the refreshment table and the stage.

The description of Ballroom-rm is "[one of][or]From the stage, the Pied Piper sways on his chair, his fingers tapping next to the laptop on the table before him. [stopping]Most of the guests have congregated into small groups in which someone [mdash] or something [mdash] tries to talk over the music. Holographic dancers materialize momentarily to dip, spin, and swing their partners next to the corporeal partygoers before disappearing to continue their dance in the ethereal[first time]. You thought that Robin Hood was up on the stage, but the flute hanging from his neck suggests that instead he is the Pied Piper of Hamelin, playing his enchantment[only]. Black Widow watches Cleopatra stand guard over a shadowed area next to the stage and uncomfortably close to a pair of stacked speakers. Cutlass in one wobbly hand, Frankie spars with an invisible foe as the pirate tries to get his weapon back. [nun state].".

To say nun state:

unless the nun is distracted begin;

say "The nun smiles at you[unless the nun has not spoken] from the refreshment table along one wall[end unless]";

otherwise;

say "The nun preaches to the scientist whose glances at the double doors suggest he is planning an escape";

end unless;

say "[first time]. You suppose it may be time to make your exit [if the nun is distracted]as well, [end if]and take your shift in the Fly Eye[only]".

communications-rm is a room. Communications is a room-proxy in Communications-rm. Understand "[watchables]" as Communications when item described is event stage and screentime is greater than 0.

The number-name of Communications is two. The room-proxy of Communications-rm is Communications. Communications-rm contains Communications.

Laboratory-rm is a room. The Laboratory is a room-proxy in Laboratory-rm. Understand "[watchables]" as laboratory when item described is event stage and screentime is greater than 0.

The number-name of Laboratory is three. The room-proxy of Laboratory-rm is Laboratory. Laboratory-rm contains yourself.[We start the player off in the Laboratory so we can determine when the player has made a selection in the introductory options. We could have also used a truth state or a property, but I didn't want to create one just to do this.]

Understand "attic", "dressing room", and "lab" as the laboratory.

Alien-Zoo-rm is a room. The Zoo is a room-proxy in Alien-Zoo-rm. The room-proxy of Alien-Zoo-rm is Zoo. The printed name of Zoo is "Alien Zoo".

The number-name of Zoo is four.

Understand "alien zoo" as zoo.

Understand "[watchables]" as Zoo when item described is event stage and screentime is greater than 0.

Playroom-rm is a room. The Children's Possessions Playroom is a room-proxy in Playroom-rm. The room-proxy of Playroom-rm is the Children's Possessions Playroom.

Understand "[watchables]" as Playroom when item described is event stage and screentime is greater than 0.

The number-name of Playroom is five.

The playroom can be beginning to static.

To say sequence 1 dialogue 1:

say "I'd be more scared if you showed up in my house".

To say sequence 1 dialogue 2:

say "Guess you should have taken it easy on the cabbage and beans at dinner".

To say sequence 1 dialogue 3:

say "No way, man. Didn't you smell that when we came in? It's all over this room".

To say sequence 1 dialogue 4:

say "Someone's coming. Go out there and bring our friend in".

To say sequence 2 dialogue 1:

say "Wayne Harrison was having a birthday party for his twin daughters in this room. They had cake and drinks.' His voice lowers. 'Most of the kids died. Right here. The twins, too. Poisoned. People suspected Wayne's chauffeur, who was never charged. He was going to be fired for gambling and . . . doing inappropriate things in front of the kids. His son didn't get sick. That's why . . . '".

To say sequence 2 dialogue 2:

say "This place is haunted".

To say sequence 2 dialogue 3:

say "We can have some fun with this".

Curse events is a list of things variable. Curse events is {Ballroom, Communications, Laboratory, Ballroom, Communications, Ballroom, Ballroom}.

Fright events is a list of things variable. Fright events is {Playroom, Playroom, Zoo, Communications, Communications, Communications, Ballroom}.

Greed events is a list of things variable. Greed events is {Laboratory, Playroom, Communications, Communications, Communications, Ballroom, Ballroom}.

Table of Hyperlink Glulx Replacement Commands (continued)

linknum replacement
1"ballroom"
2"communications"
3"laboratory"
4"zoo"
5"playroom"
6"look"

The cat and the rat are animals.

Some women are defined by the Table of Female Guests.

[Characters are "in" the Fly Eye when they are not on screen because we need a placeholder room-proxy for these lists.]

Table of Female Guests

WomanHangouts
Black Widow{Ballroom, Eye, Eye, Ballroom, Communications, Ballroom, Ballroom}
Cleopatra{Ballroom, Communications, Laboratory, Ballroom, Eye, Ballroom, Ballroom}
the gray{Eye, Eye, Eye, Zoo, Eye, Playroom, Playroom}
The nun{Eye, Eye, Eye, Eye, Ballroom, Ballroom, Ballroom}
a zombie{Eye, Eye, Eye, Eye, Ballroom, Eye, Eye}

Some men are defined by the Table of Male Guests.

Table of Male Guests

ManHangouts
the butcher{Eye, Ballroom, Ballroom, Eye, Eye, Eye, Eye}
the devil{Eye, Eye, Zoo, Zoo, Eye, Laboratory, Eye}
Frankie{Eye, Eye, Eye, Eye, Eye, Eye, Ballroom}
the leprechaun{Playroom, Playroom, Zoo, Communications, Communications, Communications, Eye}
the medicine man{Laboratory, Eye, Communications, Communications, Eye, Eye, Zoo}
the MIB{Eye, Eye, Eye, Zoo, Eye, Playroom, Playroom}
the pied piper{Eye, Eye, Eye, Eye, Eye, Eye, Ballroom}
the pirate{Eye, Eye, Eye, Eye, Ballroom, Eye, Ballroom}
Rasputin{Laboratory, Playroom, Communications, Ballroom, Communications, Eye, Ballroom}
the sasquatch{Playroom, Playroom, Zoo, Communications, Communications, Communications, Eye}
the scientist{Eye, Eye, Laboratory, Communications, Communications, Eye, Zoo}

ballroom-rm contains Goldie, Black Widow, Cleopatra, Frankie, the nun, the Pied Piper, the pirate, the scientist, and the soul dancers.

Section - Remembering Characters

A character recall rule for the butcher:

say " where he was hanging out at the refreshment table.".

A character recall rule for the devil:

if screentime is 3, say " where he was holding a rope in his hand.";

if screentime is 4, say " where he was being intimidated by the MIB.";

if screentime is 6, say " where he shook the pole.".

A character recall rule for the leprechaun:

if screentime is 1, say ", scheming with the sasquatch.";

if screentime is 2, say " where he scared Rasputin and left carrying the red-haired doll.";

if screentime is 3, say ", preparing a noose for the doll.";

if screentime is 4, say ", talking to the medicine man then leaving with the doll.";

if screentime is 5, say " where he[if Goldie is aware of the doll], without the doll,[end if] watched Black Widow and Rasputin leave before taking position just inside the door, looking out.";

if screentime is 6, say " where he was staring out the door, [if Goldie is aware of the doll and entry 5 in realizations is not Communications]without the doll, [end if]getting upset, and leaving.".

A character recall rule for the medicine man:

if screentime is 1, say " where he was upset after Rasputin spilled the totems onto the floor.";

if screentime is 3, say " where he was upset at Rasputin for knocking over the staff and spilling the totems onto the floor[if entry 1 in realizations is Laboratory] again[end if].";

if screentime is 4, say ", talking to the leprechaun and sasquatch before suggesting he and the scientist should talk outside the room.".

A character recall rule for MIB:

if screentime is 4, say " where he scared away the devil and placed his jacket on the gray.";

if screentime is 6, say ", looking around without his jacket.".

A character recall rule for the pirate:

if screentime is 5, say ", enchanting the nun with a story.";

if screentime is 6, say ", mingling.".

A character recall rule for Rasputin:

if screentime is 1, say " where he knocked over the medicine man's staff, spilling the totems onto the floor. Apologetic, he picked them up and handed them back to the medicine man.";

if screentime is 2, say " where he explained the history of the Harrison family, after being scared by the leprechaun.";

if screentime is 3, say " where he bumped into the medicine man, knocking the frog totem onto the floor. Rasputin thought something appeared odd about it but returned it to the man anyway.";

if screentime is 4, say " where he gulped down an alcoholic drink before being escorted out of the room by Black Widow, to the displeasure of Cleopatra.";

if screentime is 5, say " where something happened to his hand when he reached behind the speakers. Shaken, he drank from the scientist's bottle before leaving with Black Widow, the leprechaun and sasquatch trailing behind them and stopping in the doorway.".

A character recall rule for the sasquatch:

if screentime is 1, say ", scheming with the leprechaun.";

if screentime is 2, say " where he helped the leprechaun to scare Rasputin.";

if screentime is 3, say ", being a lookout for the leprechaun, who was preparing a noose for a doll.";

if screentime is 4, say ", talking to the medicine man.";

if screentime is 5, say " where he and the leprechaun watched Black Widow and Rasputin leave before taking position just inside the door, looking out.";

if screentime is 6, say " where he stared out the door before leaving with an upset leprechaun.".

A character recall rule for the scientist:

if screentime is 3, say " where he shook the pole in the floor.";

if screentime is 4, say " where the medicine man seemed interested in talking to him but not in front of the camera.";

if screentime is 5, say "where he offered a shaken Rasputin a drink from a bottle.".

A character recall rule for Black Widow:

if screentime is 1, say " where she tried to look into Cleopatra's bag, which upset Cleopatra.";

if screentime is 4, say " where she convinced Rasputin to leave with her, to Cleopatra's displeasure.";

if screentime is 5, say " where she asked Rasputin to check the speakers. Something happened to his hand, but Black Widow seemed unconcerned.";

if screentime is 6, say " where her conversation with the nun was interrupted by Cleopatra.".

A character recall rule for Cleopatra:

if screentime is 1, say ", scowling after Black Widow had tried to look in her bag.";

if screentime is 2, say " where she dimmed the lights.";

if screentime is 3, say " where she dropped her bag behind the chest. She pointed out the furnishings to the scientist and waited for him to leave before she continued to unpack her bag, hidden by the chest.";

if screentime is 4, say " where she spoke to Rasputin before he was escorted out of the room by Black Widow.";

if screentime is 6, say " where she spoke to Black Widow, who had just entered the room and begun a conversation with the nun. Upset, Cleopatra walked to the door and stood looking out into the hall.".

A character recall rule for the gray:

if screentime is 4, say " where the MIB gave her his jacket, and she studied the exhibits.";

if screentime is 5, say " where she waited for a signal from the MIB before leaving the room.";

if screentime is 6, say ", attempting to sit at a small table, a large black jacket wrapped around her.".

A character recall rule for the nun:

if screentime is 5, say ", smiling at the pirate's toucan.";

if screentime is 6, say ", talking to Black Widow and being interrupted by Cleopatra.".

A character recall rule for the zombie:

if screentime is 5, say ", deciding against eating the cold meats on the refreshment table.".

Section - Transition Events

The transition events of Ballroom is the Table of Ballroom Transition Events.

[These tables are important because we also use them to register which events trigger the event interpretation rules. That is, Goldie comments on these.]

Table of Ballroom Transition Events

Trigger TimeEvent
0"[if watched trailer is false]Cleopatra stomps over to where her headdress had lain, picks something up, and tries to re-affix it to her headgear. Black Widow rushes over to the side of the stage and bends into the shadows. [otherwise]Cleopatra fiddles with her headdress as Black Widow crouches beside the stage. [end if][first time][i]Was Cleopatra hiding something?[/i] you wonder. [only]"
3 "[if entry one in realizations is Ballroom and entry 3 in realizations is not the Laboratory]Without her bag, [end if] Cleopatra [if watched trailer is false]enters[end if][if watched trailer is false], stops near the stage, and searches the crowd[otherwise]continues to study the guests[end if]."
5"Black Widow [if watched trailer is false]strolls into the room and begins to chat with the nun in front of the stage[otherwise]continues her chat with the nun[end if]."
6"Cleopatra [if watched trailer is false]rushes out. She returns holding up a man with white hair and a cape. The two stumble forward, and the man slumps to the floor[otherwise]shakes [white-haired Greg] as he lies slumped on the floor[end if]."

To say white-haired Greg:

say "[if Rasputin is recognized]Greg, his hair now white,[otherwise]a white-haired man[end if]".

The transition events of Communications is Table of Communications Transition Events.

Table of Communications Transition Events

Trigger TimeEvent
1"Cleopatra [if watched trailer is false]appears in the doorway with a bag over one shoulder[otherwise]stares at the far dark corner[end if]."
2"The medicine man [if watched trailer is false]enters, stops at a mirror, and stares into his contorted reflection[otherwise]makes faces at his distorted reflection in the mirror[end if]."
3"The medicine man pokes at [if entry 3 in realizations is Communications]the[otherwise]a[end if] chandelier with his staff. The leprechaun, doll in hand, and sasquatch [if watched trailer is false]arrive. They look at the witch doctor then up at the fixture[otherwise]watch him[end if]."
4"Black Widow [if watched trailer is false]appears and pulls Rasputin through the doorway to join her[otherwise] talks to Rasputin as he warily looks around[end if]."
5"The leprechaun and sasquatch look out the door and into the hall."

The transition events of Laboratory is Table of Laboratory Transition Events.

Table of Laboratory Transition Events

Trigger TimeEvent
0"Rasputin, bloody axe in one hand, rummages through a chest as [one of]someone you don't know, a medicine man, [or]the medicine man [stopping]studies his face in a mirror."
1"The medicine man [if watched trailer is false]leaves[otherwise]has left[end if][if watched trailer is true], the room now vacant[end if]."
2"Cleopatra [if watched trailer is false]enters, drops her bag next to a chest, and unpacks some whips[otherwise]continues to transfer weapons from her bag to the chest[end if]."

The transition events of Zoo is the Table of Zoo Transition Events.

Table of Zoo Transition Events

Trigger TimeEvent
2"The sasquatch [if watched trailer is true]is standing in the [otherwise]appears and positions himself in the [end if]doorway, while the leprechaun [if watched trailer is false]passes him and [end if]searches the exhibits with [if entry 2 in realizations is playroom]the[otherwise]a[end if] red-haired doll tucked under his arm."
3"[if watched trailer is false][cap-it][unidentified name for MIB] enters[end if][if watched trailer is false]. The MIB stares down through sunglasses at [unidentified name for devil], who steps back, rope dangling from his hand[otherwise]The devil tries to look beyond the MIB and out the door[end if]."
4"[if watched trailer is false][cap-it][unidentified name for gray] waits inside the doorway then steps out[otherwise]Vacant[end if]."
6"The medicine man talks to someone through the doorway."

The transition events of Playroom is Table of Playroom Transition Events.

Table of Playroom Transition Events

Trigger TimeEvent
0"The sasquatch smiles as the leprechaun tries to lift a gold dinner plate from a small table.[first time] You wonder whether the leprechaun will play any tricks tonight. [only]"
1 "[if watched trailer is false]The sasquatch enters with one hairy arm wrapped around Rasputin's shoulders. A toy clown sitting near the door behind them leans over[otherwise]Wide-eyed and in the clutches of a smiling sasquatch, Rasputin looks around, the clown behind them now bent over[end if]."
5"[one of][if Goldie is aware of jacketed MIB]Without his jacket, [otherwise][Cap-it][end if][unidentified name for MIB][or][The MIB][stopping] [if watched trailer is false]steps into the room, a hand at the device on his belt[otherwise]scans the shelves[end if]."
6"The footage is a blur of color. Children seem to giggle in the static of the monitor's tiny speaker."

Chapter - Definitions

Definition: a thing is personable if it is a person and it is not an animal.

Definition: a person is accounted for:

if it is an animal and screentime is less than 3, no;

if it is either Black Widow or Cleopatra or Leprechaun, yes;

if it is either sasquatch or medicine man or Rasputin, yes;

if screentime is not 0 and it provides the property trailer-spotted and it is trailer-spotted, yes;

repeat with counter running from 1 to screentime begin;

if entry counter in hangouts of it is entry counter in realizations, yes;

end repeat;

no.

Definition: a thing (called target) is center-stage:

if target is enclosed by a person, now target is the holder of target;

if target is an animal or target is the player or target is yourself or (target is Frankie and location contains frankie), no;

if event played out was true and event played out is false, no;

if event played out is false and target is on-screen, yes;

if event played out is true begin;

if target is a room-proxy and target is the event stage, yes;

if target is in a room and target is not a room-proxy and target is not a person and the room-proxy of the location of target is the event stage, yes;

if target is a person and entry screentime in the hangouts of target is entry screentime in realizations, yes;

end if;

if target is the monitors, yes;

no.

Definition: a thing (called target) is on-screen rather than off-screen:

if target is enclosed by a person, now target is the holder of target;

if target is an animal or target is the player or target is yourself, no;

if Preparation is happening, no;

if target is a room-proxy and target is not Fly Eye, yes;

if target is a song or target is music, no;

if target is not a person and a room contains target and location does not enclose target, yes;

if target is a person begin;

if screentime is 0 begin;

if entry 1 in hangouts of target is not Fly Eye, yes;

no;

end if;

let hangout be entry screentime in the hangouts of target;

let future hangout be entry (screentime plus 1) in the hangouts of target;

if event played out is true begin;

if event stage is hangout and future hangout is hangout, yes;

otherwise;

if screentime is 1 and (target is medicine man or (target is the leprechaun and entry 1 in realizations is not Playroom)), no;

if target is butcher and screentime is 2, no;

if target is either Cleopatra or devil and screentime is 5, no;

if target is gray and screentime is either 3 or 5, no;

if screentime is 6 and target is either gray or MIB and entry 6 in realizations is not playroom, no;

if future hangout is not Fly Eye, yes;

end if;

end if;

no.

Definition: a thing is involved if the current action involves it and it is not the player.